Office: (Office 365) Doppelte Werte mit 2 Bedingungen finden

Hi zusammen,

ich beiße mir gerade die Zähne an einer wahrscheinlich einfachen Lösung aus.
Ich habe 2 Tabellen mit Kundendaten. Beide Tabellen sind identisch aufgebaut.

In Spalte A stehen in beiden Tabellen Partnernummern die einem Kunden zugeordnet sind. In Spalte B stehen Vertragsnummern. Ein Kunde kann in Spalte B mehrere unterschiedliche Vertragsnummern haben. In Spalte A ist dann jeweils seine Partnernummern zugeordnet, d.h. pro Vertrag taucht hier seine Partnernummer auf. In Spalte C ist ein Wert 001 oder 002 zugeordnet. In den übrigen Spalten stehen Kundendaten.

Nun meine Aufgabe: Finde aus beiden Tabellen die Kunden mit mehreren Verträgen heraus, die in Spalte C sowohl 001 als auch 002 haben.

Danke schon mal für Euer feedback.

Gruß

 

Hallo Jilly,

wenn das alles auf einem Tabellenblatt stehen würde, so wie es richtig wäre, hättest du weniger Probleme bei der Auswertung.

 

Hallo Klaus-Dieter,

das war mein zweiter Ansatz. WENN Partnernummer in Spalte A mehrfach vorhanden und in Spalte C 001 UND 002 dann zeige mir Dublette an.

Ich hänge trotzdem, Sorry.

 

Moin Jilly Bean

Und was wäre dann das Wunschergebnis?

 

Hallo DL_,

Ziel ist es, den Kunden nur einmal anzuschreiben. Wenn die Partnernummer mit der Kombi 001 und der Kombi 002 in Spalte vorkommt, soll dieser Kunde nur einmal angeschrieben werden, da es sich hier jeweils um eine Dublette handelt. Das muss irgendwie mit einer Formel kenntlich gemacht werden. Also Partner in Spalte A mit Wert 001 oder 002 in Spalte C ist okay.

Ich habe die beiden Tabellen mal zusammengeführt und markiert was ich meine.

 

Z.B. so:

Code:

=SUMME(--(ZÄHLENWENNS($A$2:$A$6;A2;$C$2:$C$6;{"001"."002"})>0))=2

^

Oder so:

Code:

=UND(ZÄHLENWENNS($A$2:$A$6;A2;$C$2:$C$6;{"001"."002"})>0)

 

Jau, das passt.

Tag gerettet.

Vielen Dank.

 

Hallo,

ich habe deine beiden Tabellen in strukturierte Tabellen (namens "Tabelle1" und "Tabelle2") umgewandelt.
Da du keine Dublette in deinen Beispieldaten eingefügt hast, habe ich eine solche dazu modifiziert: Partner=12 und VertrNr=50088

Im Arbeitsblatt "001" habe ich in Zelle B10 meine Formel eingefügt:
=LET(PaVt; LAMBDA(t; NACHZEILE(SPALTENWAHL(t; {1;2}); LAMBDA(zl; INDEX(zl; ; 1) & "|" & INDEX(zl; ; 2))));
PV; VSTAPELN(PaVt(Tabelle1); PaVt(Tabelle2)); PVE; EINDEUTIG(PV);
Anz; NACHZEILE(PVE; LAMBDA(zl; ZEILEN(FILTER(PV; PV = zl)))); VSTAPELN({"PA|VNR"."Anz"}; HSTAPELN(PVE; Anz)))
Folgendes Resultat ergibt sich:

In Spalte "Anz" ist die Partner/Vertragsnr.-Anzahl abzulesen. Dubletten erscheinen dort mit Anz=2.

Datei liegt bei.

 

Hallo Exl121150,

mit der ZÄHLENWENNS-Funktion bin ich schon komplett zufrieden. Ich schaue mir Deine Lösung aber auf jeden Fall noch mal an.
Danke für Eure Zeit.
Gruß Jilly