Office: Drehfelder / SpinButtons incl. Zellverknüpfung kopieren

Helfe beim Thema Drehfelder / SpinButtons incl. Zellverknüpfung kopieren in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo liebes Forum, bin neu hier und habe gleich ein - für mich - unlösbares Problem: Ich möchte mehrere Drehfelder in einer Excel-Liste anlegen und... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von cassiopeius, 26. Februar 2021.

  1. Drehfelder / SpinButtons incl. Zellverknüpfung kopieren


    Hallo liebes Forum,

    bin neu hier und habe gleich ein - für mich - unlösbares Problem:
    Ich möchte mehrere Drehfelder in einer Excel-Liste anlegen und diese jeweils mit den Feldern verknüpfen, auf welchen die Drehfelder liegen. Am besten noch mit Min- und Max-Wert-Definition.

    Bei der Suche hier bin ich auf ein ähnliches Problem nur mit Kontrollkästchen gestoßen. Das klappt auch perfekt:

    Code:
    Private Sub CommandButton1_Click()
    
     Dim lngZeile As Long
       Dim intSpalte As Integer
       For lngZeile = 2 To 4 '<== Zeilenanzahl anpassen
          For intSpalte = 2 To 7 '<== Spaltenanzahl anpassen
             With ActiveSheet.CheckBoxes.Add(Cells(lngZeile, intSpalte).Left, _
                Cells(lngZeile, intSpalte).Top, Columns(intSpalte).Width, _
                Rows(lngZeile).Height - 0.05)
                .Text = lngZeile & " - " & intSpalte
                .LinkedCell = Cells(lngZeile, intSpalte).Address
             End With
          Next intSpalte
       Next lngZeile
    
    
    End Sub
    (Vielen lieben Dank an den Beitrag von Karin / Beverly)

    Allerdings bekomme ich das Beispiel nicht auf Drehfelder umgestrickt. Wenn ich an Stelle von "CheckBoxes" den Begriff "SpinButtons" einfüge, bekomme ich einen Objekt-Fehler.

    Kann hier jemand helfen, bzw. ist es möglich, dass es nur mit Kontrollkästchen geht, aber nicht mit Drehfeldern?
    Vielen Dank schonmal im Voraus und

    viele Grüße
    Christian
     
    cassiopeius, 26. Februar 2021
    #1
  2. Beverly
    Beverly Erfahrener User
    Hi Christian,

    die Formular-Drehfelder (oder SpinButton) heißen in VBA nicht "SpinButton" sondern "Spinners":

    Code:
    Private Sub CommandButton1_Click()
       Dim lngZeile As Long
       Dim intSpalte As Integer
       For lngZeile = 2 To 4 '<== Zeilenanzahl anpassen
          For intSpalte = 2 To 7 '<== Spaltenanzahl anpassen
             With ActiveSheet.Spinners.Add(Cells(lngZeile, intSpalte).Left, _
                Cells(lngZeile, intSpalte).Top, Columns(intSpalte).Width, _
                Rows(lngZeile).Height - 0.05)
                .LinkedCell = Cells(lngZeile, intSpalte).Address
                .Min = 1
                .Max = 100
             End With
          Next intSpalte
       Next lngZeile
    End Sub
    

    Drehfelder / SpinButtons incl. Zellverknüpfung kopieren GrußformelDrehfelder / SpinButtons incl. Zellverknüpfung kopieren Beverly's Excel - Inn
     
    Beverly, 26. Februar 2021
    #2
  3. Hey Karin,

    AAHHH, vielen Dank für den entscheidenden Hinweis. Das mit den Spinners muss man erstmal wissen... Drehfelder / SpinButtons incl. Zellverknüpfung kopieren *:)*

    Gibt es auch die Möglichkeit, alle SpinButtons eines Tabellenblattes mit der Zelle zu verknüpfen, in der sie liegen?

    Ich bin in VBA leider noch nicht wirklich bewandert. Habe mich bisher nur ziemlich exzessiv mit Excel-Formeln beschäftigt.

    Viele Grüße
    Christian
     
    cassiopeius, 26. Februar 2021
    #3
  4. Beverly
    Beverly Erfahrener User

    Drehfelder / SpinButtons incl. Zellverknüpfung kopieren

    Hi Christian,

    das geht auf diesem Weg:

    Code:
    Sub Zellzuweisung()
        Dim spSpin As Spinner
        For Each spSpin In ActiveSheet.Spinners
            spSpin.LinkedCell = spSpin.TopLeftCell.Address
        Next spSpin
    End Sub
    

    Drehfelder / SpinButtons incl. Zellverknüpfung kopieren GrußformelDrehfelder / SpinButtons incl. Zellverknüpfung kopieren Beverly's Excel - Inn
     
    Beverly, 26. Februar 2021
    #4
  5. Hallo Karin,

    vielen lieben Dank für den Code. Hat alles super geklappt und funktioniert :-).
    Habe den Code noch um ein paar Zeilen ergänzt, was Vorbelegung der MIN- / MAX-Werte angeht. Außerdem noch eine Abfrage, ob ein Drehfeld bereits mit der entsprechenden Zelle verknüpft ist. Dann wird der Zellwert als Wert in das Drehfeld geschrieben. Andernfalls wird die Zelle mit dem Drehfeld verknüpft und der Zellinhalt auf "Leer" gesetzt. Sonst stehen dort lauter hässliche Nullen.

    Falls es sonst noch jemand interessiert bzw. brauchen kann, hier noch der ergänzte Code:

    Code:
    Dim spSpin As Spinner
        For Each spSpin In ActiveSheet.Spinners
        
            spSpin.Min = 0
            spSpin.Max = 20
            spSpin.SmallChange = 1
            If spSpin.TopLeftCell.Value > 0 Then
                spSpin.LinkedCell = spSpin.TopLeftCell.Address
                spSpin.Value = spSpin.TopLeftCell.Value
            Else
                spSpin.LinkedCell = spSpin.TopLeftCell.Address
                spSpin.TopLeftCell.Value = ""
            End If
            
        Next spSpin
    Den Code natürlich noch in die entsprechende SUB packen.
    Dank nochmal an Karin für die "Basisarbeit" und Aufklärung für mich als blutiger Anfänger und

    viele Grüße
    Christian
     
    cassiopeius, 1. März 2021
    #5
  6. Beverly
    Beverly Erfahrener User
    Hi Christian,

    wenn ich dein Anliegen richtig verstanden habe, dann sollte dieses ausreichend sein:

    Code:
        Dim spSpin As Spinner
        For Each spSpin In ActiveSheet.Spinners
            spSpin.Min = 0
            spSpin.Max = 20
            spSpin.LinkedCell = spSpin.TopLeftCell.Address
            spSpin.Value = spSpin.TopLeftCell.Value
        Next spSpin
    
    smallChange = 1 ist Standard.



    Drehfelder / SpinButtons incl. Zellverknüpfung kopieren GrußformelDrehfelder / SpinButtons incl. Zellverknüpfung kopieren Beverly's Excel - Inn
     
    Beverly, 1. März 2021
    #6
Thema:

Drehfelder / SpinButtons incl. Zellverknüpfung kopieren

Die Seite wird geladen...
  1. Drehfelder / SpinButtons incl. Zellverknüpfung kopieren - Similar Threads - Drehfelder SpinButtons incl

  2. Drehfeld Eigenschaften

    in Microsoft Excel Hilfe
    Drehfeld Eigenschaften: Hallo erstmal... also immer wenn ich ein drehfeld oder eine Bildlaufleiste in EXCEL erstelle, damit eine Zelle sich verändert, funktionieren die zahlen über Null einwandtfrei... aber wenn ich...
  3. Hinzufügen einer Bildlaufleiste oder eines Drehfelds zu einem Arbeitsblatt

    in Microsoft Excel Tutorials
    Hinzufügen einer Bildlaufleiste oder eines Drehfelds zu einem Arbeitsblatt: Hinzufügen einer Bildlaufleiste oder eines Drehfelds zu einem Arbeitsblatt Excel 2019 Excel 2016 Excel 2013 Excel 2010 Excel 2007 Mehr......
  4. Drehfeld mit 0,01 Schritten

    in Microsoft Excel Hilfe
    Drehfeld mit 0,01 Schritten: Hi, gibt es irgendeine Möglichkeit ein Drehfeld mit Min 0 und Max 30 in Schrittweiten von 1Cent (0,01) zählen zu lassen? Vielen Dank für Lösungen im Voraus! Gruß Sonnenlicht*Sun 349776
  5. Kombinationsfeld, Drehfeld setzen und Matrixfunktion

    in Microsoft Excel Hilfe
    Kombinationsfeld, Drehfeld setzen und Matrixfunktion: Hallo Experten, habe einige Probleme mit der Erstellung eines Kombinationsfeldes, Drehfeldes und das Verknüpfen einer Tabelle mit Hilfe einer Matrixfunktion. Dazu hängt eine Datei an die...
  6. Drehfeld Formularsteuerelement

    in Microsoft Excel Hilfe
    Drehfeld Formularsteuerelement: einen wunderschönen guten morgen und wiedermal bin ich mit einem neuen Problem hier :) Folgendes, ich wollte in einer Tabelle mehrere Drehfelder einfügen die in verschiedenen Zellen den Wert...
  7. Drehfeld generiert flsches Ergebnis in Prozent

    in Microsoft Excel Hilfe
    Drehfeld generiert flsches Ergebnis in Prozent: Hallo Excel Profies mein heutiges Problem ist das Ergebnis in der Zelle A1. Die Zelle ist Formartiert auf Prozent. Neben der Zelle habe ich ein Drehfeld gesetzt. Minimum Wert vom Drehfeld ist 50...
  8. Ein Drehfeld ausgabe in aktive Zelle

    in Microsoft Excel Hilfe
    Ein Drehfeld ausgabe in aktive Zelle: Hallo, Wie die Überschrift schon sagt, liegt mein Problem darin, die Ausgabe eines Drehfeldes auf die jeweils aktive Zelle zu lenken. In meiner Tabelle sind bereits über 160 Drehfelder und die...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden