Office: Dreiecksberechnung von Intervallen mit bestimmten Werten

Hallo zusammen,

ich habe ein Problem, bei welchem ich nicht weiter komme. Ich habe eine Reihe an Datenpaaren (siehe Anhang), welche mithilfe eines Makros analysiert werden soll. Die Datenpaare bestehen dabei aus einer aufsteigenden Nummer und einem Wert zwischen 0 und 1. Die Daten sollen nun so analysiert werden, dass sobald der Wert das erste Mal unter 1 fällt, dieser abgespeichert wird. Dann sollen alle weiteren Werte auch abgespeichert werden, bis der Wert 1 wieder erreicht wurde. Erreichen möchte ich damit, dass ich die blau eingezeichneten Dreiecke berechnen kann (siehe Grafik im Anhang).
Hat jemand einen Ansatz, mit ich diese Logik in einem Makro implementieren kann? Ich stehe leider echt auf dem Schlauch.

Vielen Dank und Liebe Grüße!

 

Hallo,

Was meinst du mit "Dreiecke berechnen"? Soll die Fläche berechnet werden oder der Umfang oder die Koordinaten der Ecken? Die Fläche kann berechnet werden, jedoch nicht der Umfang oder die Koordinaten.

Welche Excel-Version hast du? Falls du Version Excel365 oder Excel2021 hast, kann man das relativ einfach auch ohne VBA lösen, sofern es sich um die Flächenberechnung der Dreiecke handelt.

1) Ich habe deine Tabelle in eine strukturierte Tabelle namens "tbWerte" umgewandelt
2) Im Bereich D2:H25 habe ich dir eine Lösung mit Arbeitsblattformeln eingefügt (Excel365 oder Excel2021 wird vorausgesetzt).
3) In einem allgemeinen Codemodul habe ich dir die benutzerdefinierte Funktion Dreiecksflächen(Tabellenbereich) eingefügt.
Sie kann denkbar einfach angewandt werden, wie in Zelle H29 zu sehen ist. Die Funktion ist im Folgenden aufgelistet:

Code:

Public Function Dreiecksflächen(rgTabelle As Range) As Double
  Dim rgZeile As Range                             'Tabellenzeile
  Dim Tag As Integer, Wert As Double               'Tabellenzeile
 
  Dim lztTag1Wert As Integer, minWert As Double    'Zwischenwerte
 
  Dim GrdLinie As Double, Höhe As Double           'Dreieck
  Dim Fläche As Double, FlächeGesamt As Double     'Dreieck
 
  'Startwerte speichern
  FlächeGesamt = 0
  lztTag1Wert = 0: minWert = 1
 
  'Durch die Range-Zeilen iterieren:
  For Each rgZeile In rgTabelle.Rows
    With rgZeile
       Tag = .Cells(1).Value: Wert = .Cells(2).Value
       If Wert = 1 Then
          If lztTag1Wert Then
             'Es liegt ein neuer Tag mit 1-Wert vor -> Dreieck berechnen
             GrdLinie = Tag - lztTag1Wert
             Höhe = 1# - minWert
             Fläche = GrdLinie * Höhe / 2#
             FlächeGesamt = FlächeGesamt + Fläche
          End If
          'Startwerte für nächstes Dreieck speichern
          lztTag1Wert = Tag: minWert = 1#
       Else
          minWert = IIf(minWert > Wert, Wert, minWert)
       End If
    End With
  Next rgZeile
 
  Dreiecksflächen = FlächeGesamt

End Function

Datei liegt bei.

 

Es geht, wie du schon richtig vermutet hast, um die Fläche der Dreiecke.

Die Lösung ist exakt das, wonach ich gesucht habe. Tausend Dank dir! Und ich habe Excel 365, also kann ich das problemlos nachvollziehen.