Office: Drop Down Auswahl mit einem Link versehen

Moin Moin EXCEL GURUS
Ich habe da mal ein kleines Problemchen, wonach ich mir schon die Fingerkuppen "WUNDGEGOOGELT" habe ...

Hier mein Problem:
Excel 2007
Arbeitsmappe erstellt mit folgenden Tabellen:
DATEN - INPUT - DATEN_A - DATEN_B - fortlaufend

In Tabellenblatt "DATEN" habe ich zwei Drop Down Menüs erstellt:
1.) =Buchstaben
2.) =WENN(A1="A";Buchstabe_A;WENN(A1="B";Buchstabe_B))

Diese beiden Drop Down Menüs arbeiten einwandfrei. Wenn ich den Buchstaben "A" auswähle, listet er im zweiten Drop Down alle Wörter beginnend mit "A" z.B. "APACHE".

In Tabelle "INPUT" liegen die Daten für die Buchstaben, also für A = Apache - Ad-Hoc - Admin C und fortlaufend ... B = alle Begriffe die mit B beginnen ... C bis Z wird noch folgen.

In "DATEN_A" liegen dann die Daten, in diesen Falle die Beschreibung für Apache - fortlaufend...

Mein Problem ist folgendes:

Im ersten Drop Down wähle ich den Buchstaben, z.B.: "A" und im zweiten Drop Down den Begriff "APACHE". Wie kann ich das jetzt anstellen, das wenn ich "APACHE" ausgewählt habe, Excel automatisch in das Tabellenblatt "DATEN_A" zum Begriff "APACHE" springt, und bei allen anderen ausgewählten Begriffen ebenfalls.
Die Formel " =WENN .. " würde bei ca. 500 Datensätzen, ziemlich schnell unübersichtlich und würde glaube ich, bei dieser Datenmengen schnell kapitulieren ...
Wie erfolgt der Reset wenn ein Suche und Anzeige der Daten erfolgreich war?

Wie könnte man das Anders realisieren ...

Ein Dankeschön schon mal vorab

Sailor

 

Hallo!

Mal angenommen:
Das erste DropDown (A, B, C, usw.) liegt in H1
Das zweite DropDown (APACHE, usw.) liegt in H2
Der Begriff soll gesucht werden im Blatt "DATEN_XY" in Spalte A

Dann erzeugt diese Formel einen Hyperlink auf das gesuchte Blatt in die gesuchte Zeile:

=HYPERLINK("#DATEN_"&H1&"!A"&VERGLEICH(H2;INDIREKT("DATEN_"&H1&"!A:A"););"gehe zu")

 

Moin Moin Schatzi

Erstmal Danke für deine Antwort auf mein kleines Problemchen.

Ein paar Anmerkungen meinerseits:
Das erste Drop Down mit der Buchstabenauswahl liegt in der Zelle "A1".
Das zweite Drop Down mit den Begriffen die dem jeweiligen Buchstaben zugeordnet sind liegt gleich rechts davon in "B1".
Wie schon erwähnt arbeiten diese beiden Drop's einwandfrei.
In A1 erfolgt die Buchstabenauswahl und in B1 dann der entsprechende Begriff, z.B.: "A1" der Buchstabe A und in "B1" z.B.: Apache.

Ich habe deine Formel entsprechend angepasst und diese erstmal in "C1" gepackt. Die dann funktionierende Formel wollte ich einem Button zuweisen, z.B.: "LOS".

Deine Formel:
=HYPERLINK("#DATEN_"&H1&"!A"&VERGLEICH(H2;INDIREKT("DATEN_"&H1&"!A:A"););"gehe zu")

habe ich folgendermaßen abgewandelt:
1. Variante
=HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!B:B"););"gehe zu")
Ergebnis: Ein Blauunterlegtes "#NV" erscheint.

2. Variante
=HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&B1&"!B:B"););"gehe zu")
Ergebnis: Ein Blauunterlegtes "#Bezug" erscheint.

Vielleicht kannst du bitte nochmal über meine Änderungen in der Formel schaun und mir sagen wo ich die Kurve nicht sauber bekommen habe.

Noch eine Zusatzfrage.
Wenn die Formel funktioniert, müsste ich sie dann insgesamt 26 mal (Anzahl der Buchstaben im Alphabet) kopieren und nur entsprechend den Buchstaben ändern bzw. anpassen. das ist doch dann so richtig ... oder ??

Vorab schonmal ein Dankeschön für deine Bemühungen

Sailor

 

hi SAILOR, versuch mal..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	1	2	gehe zu

Zelle	Formel
C1	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!B:B");B1);HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!B:B"););"gehe zu");"Eintrag überprüfen!")

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

bzw..: bei mit fehlerabfrage..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	2	2	Eintrag überprüfen!

Zelle	Formel
C1	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!B:B");B1);HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!B:B"););"gehe zu");"Eintrag überprüfen!")

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

 

Moin Moin Hiob

Vielen vielen Dank für die beiden Formeln.

Kleines Problem beim Ausführen beider Formeln:

"Die angegeben Datei konnte nicht geöffnet werden."

Sailor

 

hi, ich habe versucht eine beispieldatei hochzuladen... ... vielleicht klappt's ja jetzt...

 

hier mal eine fehlerkorrigierte datei... ... sorry noch mal...

 

Moin Moin Hiob

Wahrscheinlich habe ich ein Brett vorm Schädel oder im Morgenkaffee war eine schlechte Bohne, jedenfalls ich bekomme dat Ding nicht zum Fliegen.

Anbei sende ich Dir mal das Sheet, denn ich bekomme nach wie vor die oben genannte Fehlermeldung.

Sailor

 

hi Sailor, in meiner signatur steht glaube ich XL2003 - ich kann mit deiner version nix anfangen...

 

Moin Moin Hiob

Tja ... wie sagt man so schön "Wer Lesen kann ist deutlich im Vorteil".
Sorry mein Fehler ... Teer und Asche über mein Haupt ...

Anbei das Sheet als xls

Sailor

 

Bezugsfehler:

Hallo,

so gehts (wenn man die Bezüge ändert, sollte man auch die Formel anpassen, A:A statt B:B):

Arbeitsblatt mit dem Namen 'DATEN'
	A	B	C
1	B	B1	gehe zu
2			gehe zu

Name	Bezug
Buchstabe_A	=INPUT!$A$2:$A$4
Buchstabe_B	=INPUT!$B$2:$B$4
Buchstaben	=INPUT!$A$1:$C$1

Zelle	Formel
C1	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!a:a");B1);HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!a:a"););"gehe zu");"Eintrag überprüfen!")
C2	=HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!a:a"););"gehe zu")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A1	Liste		=Buchstaben
B1	Liste		=WENN(A1="A";Buchstabe_A;WENN(A1="B";Buchstabe_B))

Gruß

Edgar

 

hi Sailor, hier mal mit dynamischem dropdown (erweiterbare listen - gib einfach mal einpaar ein...)

 

Moin Moin Hiob

Also was du da "ZUSAMMENGESCHRAUBT" hast ist einfach GENIAL.
Super ... Einfach nur SUPER ...

Vielen vielen Dank

Ich habe ein neues Datenblatt "Buchstabe_D" angelegt in "INPUT" Testdaten eingepflegt ... Namensvergabe betrieben und es FUNZT ...

Super ...

Ich habe jetzt nur eine WISSENSFRAGE ...

Kann man das Ganze so Steuern, das wenn man eine Auswahl getroffen hat und auf "Gehe zu" drückt, dann erfolgt ja der Sprung zum Datenobjekt.
FRAGE:
Ist eine Anzeige auch möglich wo die beiden Drop's stehen, also das der Sprung nicht erfolgt, sondern sich alles auf dem "Masterblatt" in diesem Falle "DATEN" abspielt, d.h. ich suche mir oben den Begriff aus und darunter wird das Ergebnis, in diesem Falle die Erläuterung zum obeneingegebenen Suchbegriff angzeigt wird?

Wie gesagt es ist nur eine Frage, denn ich komme mit der jetzigen Version wunderbar klar, Dank Hiob.

Nochmals ein ganz großes THANK YOU ...

Sailor

 

Moin Moin Hiob und Kallewirsch

Nochmals vielen Dank für Eure Hilfe.

Super

Ein KLASSE FORUM.

Bin schwer begeistert.

Sailor

 

hi Sailor, meinst du so..?

Arbeitsblatt mit dem Namen 'DATEN'
	A	B	C
1	A	Ad-Hoc	gehe zu
2			gehe zu
3
4		erklärung
5

Name	Bezug
Buchstaben	=INPUT!$A$1:$C$1
test	=BEREICH.VERSCHIEBEN(INPUT!$A$2;;VERGLEICH(DATEN!$A$1;Buchstaben;0)-1;ANZAHL2(BEREICH.VERSCHIEBEN(INPUT!$A$2;;VERGLEICH(DATEN!$A$1;Buchstaben;0)-1;100)))

Zelle	Formel
C1	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!A:A");B1);HYPERLINK("#DATEN_"&A1&"!A"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!A:A"););"gehe zu");"Eintrag überprüfen!")
C2	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!A:A");B1);HYPERLINK("#DATEN_"&A1&"!B"&VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!A:A"););"gehe zu");"Eintrag überprüfen!")
B4	=WENN(ZÄHLENWENN(INDIREKT("DATEN_"&A1&"!A:A");B1);INDEX(INDIREKT("DATEN_"&A1&"!B:B");VERGLEICH(B1;INDIREKT("DATEN_"&A1&"!A:A");));"Eingabewert überprüfen!")

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
A1	Liste		=Buchstaben
B1	Liste		=test

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]