Office: Dropdown "LinkedCell" mit Bedingung versehen? (ComboBox)

Liebes Forum,

ich habe eine ganz dringende Frage: Wie kann man bei einer ComboBox ("ActiveX-Steuerelemente Kombinationsfeld") die verknüpfte Zelle ("LinkedCell") mit einer Bedingung versehen? Ich möchte, dass die verknüpfte Zelle davon abhängt, was in einer anderen Zelle steht.

Zum Beispiel: Die Bedingung soll in Zelle A1 stehen (dort wähle ich ein Datum aus, bspw. also 1.4.2014). In der ComboBox soll dann etwas ausgewählt werden können (mache ich über eine Liste), z. B. "Projekt X". LinkedCell soll dann beim 1.4.2014 zu B1 führen und z. B. beim 1.5.2014 zu B2, beim 1.6.2014 zu B3.

Ich habe versucht, bei LinkedCell "=WENN(A1="1.4.2014";B1;WENN(A1="1.5.2014";B2 usw. einzutragen. Hat aber nicht geklappt.

Wenn es nur mit VBA gehen sollte, könnt Ihr mir dann bitte den Code geben und beschreiben, wo genau ich den eintragen soll?

DANKE!!!

LG
Finley

 

Hi Finley,

das geht nur per VBA. Einge hochgeladene Beispielmapper wäre allerdings sehr hilfreich.

Bis später,
Karin

 

Danke für Deine schnelle Antwort, Karin.

Meine Beispielsmappe habe ich hochgeladen. Im Kern geht es mir darum, dass ich eine Datenerfassungsmaske habe, die Daten dann abhängig von einer bestimmten Zelle (im Beispiel Zelle E7) in andere Zellen verteilt.

Hoffe, das ist verständlich...

Gruß
Fin

 

Hi Finley,

die Zellen E7:H7 enthalten Gültigkeitslisten - es sind keine ComboBoxen aus den ActiveX-Steuerelementen, aber mit den Gültigkeitslisten lässt sich dein Vorhaben genau so realisieren, wenn nicht sogar noch besser (auf jeden Fall aber einfacher). Deshalb habe ich den Code auch erst einmal für den jetzigen Zustand deiner Mappe geschrieben. Teste einfach mal, ob das so nicht schon deinen Vorstellungen entspricht.

Rechtsklick auf den Tabellenreiter von Tabelle2 -> Code anzeigen. Kopiere dann folgenden Code ins rechte (obere) Codefenster:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim rngZelle As Range
   Dim lngLetzte As Long
   Dim lngZeile As Long
   If Target.Count = 1 Then
      If Target.Address = "$F$7" Or Target.Address = "$G$7" Or Target.Address = "$H$7" Then
         lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 5)), Cells(Rows.Count, 5).End(xlUp).Row, Rows.Count)
         Set rngZelle = Range(Cells(19, 5), Cells(lngLetzte, 5)).Find(Range("E7").Value, lookat:=xlWhole, LookIn:=xlValues)
         If Not rngZelle Is Nothing Then
            Select Case Target.Address
               Case "$F$7"
                  rngZelle.Offset(0, 1) = Target
               Case "$G$7"
                  rngZelle.Offset(0, 2) = Target
               Case "$H$7"
                  rngZelle.Offset(0, 3) = Target
            End Select
         End If
      End If
   End If
   Set rngZelle = Nothing
End Sub

Hinweis: du musst deine Mappe anschließend im Dateiformat XLSM abspeichern, damit der Code beim Schließen erhalten bleibt - andernfalls wird er von Excel wieder gelöscht.

Bis später,
Karin

 

Karin, das funktioniert super. Danke.

Ich hätte aber doch lieber so eine ComboBox, weil man damit Auto-Vorschläge bekommt, wenn man in die Dropdown-Liste etwas eintippt. Meine wirkliche Liste, auf die dann die ComboBox zugreift, ist nämlich 5000 Einträge lang. Wenn man die scrollen müsste, wäre das kaum mehr machbar.

Das müsste doch recht einfach auf eine ComboBox umzuprogrammieren sein oder? Kannst Du da helfen?

LG
Fin

 

Hi Finley,

siehe angehängtes Beispiel.

---

 

Hi Karin,

das klappt auch - vielen Dank. Leider hatte ich mich darin überschätzt, Deinen Code nun einfach auf meinen Fall zu übertragen. Ich habe ein paar mehr Felder und es klappt einfach nicht, dass sich alles einträgt.

Angehängt findest Du meine Mappe. Ich wäre Dir wirklich sehr, sehr dankbar, wenn Du mir die ComboBoxen oben auf dem Blatt Fin B. so machst, wie in dem Beispiel. Es soll sich dann jeweils unten drunter in die Tabelle eintragen...

Ganz lieben Dank und viele Grüße
Fin

 

Hi Finley,

also mal ehrlich - meinst du nicht, dass es besser gewesen wäre, bereits zu Beginn das Original der Arbeitsmappe hochzuladen? Da hätte ich mir viel Zeit sparen können und bereits von Beginn an alles ohne Umwege an die konkreten Bedingungen anpassen zu können. Beachte das bitte für die Zukunft.

---

 

Ja, Du hast recht. Nächstes Mal werde ich gleich die Zieldatei hochladen.

Danke für die Überarbeitung. Jetzt klappt es bis auf einen Fehler:

Private Sub ComboBox2_Change()
lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 3)), Cells(Rows.Count, 3).End(xlUp).Row, Rows.Count)
Set rngZelle = Range(Cells(3, 3), Cells(lngLetzte, 3)).Find(DateValue(cbbDatum), lookat:=xlWhole, LookIn:=xlValues)
If Not rngZelle Is Nothing Then rngZelle.Offset(0, 1) = ComboBox2
Set rngZelle = Nothing
End Sub


Wenn kein Datum ausgewählt ist, sondern "Please select...", dann kommt immer eine Fehlermeldung, wenn man die ComboBox ändert (beim Makro soll man dann die Zeile oben debuggen ("Set rngZelle = Range..."). Kann man da nicht so einen Befehl einbauen wie "bei Änderung der ComboBox nichts machen, wenn in der Referenzbox 'Please selct Monday...' drinsteht"?

Könntest Du mir vielleicht auch kurz bitte erklären, was die Sub oben überhaupt macht?

Danke und Gruß
Fin

 

Hi Finley,

hier der geänderte Code mit Kommentaren, was vor sich geht:

Code:

Private Sub ComboBox2_Change()
   ' letzte belegte Zelle in Spalte C ermitteln
   lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 3)), Cells(Rows.Count, 3).End(xlUp).Row, Rows.Count)
   ' cbbDatum enthält ein Datum
   If IsDate(cbbDatum) Then
      ' finde das Datum aus cbbDatum in Spalte C im Bereich ab Zeile 3 bis letzte belegte Zeile
      Set rngZelle = Range(Cells(3, 3), Cells(lngLetzte, 3)).Find(DateValue(cbbDatum), lookat:=xlWhole, LookIn:=xlValues)
      ' wenn Datum gefunden dann in Zelle rechts davon ComboBox2-Inhalt eintragen
      If Not rngZelle Is Nothing Then rngZelle.Offset(0, 1) = ComboBox2
      ' Variable leeren
      Set rngZelle = Nothing
   Else
      MsgBox "Bitte Datum auswählen"
   End If
End Sub

Bis später,
Karin