Office: Dropdownliste / Auswahlliste

Hallo,

meine o.g. Liste besteht aus min. 300 Einträgen, und es sind 50 Listen untereinander. Besteht die Möglichkeit, wenn ich an Position 50 einen Eintrag gewählt habe, dieser nicht mehr in den restlichen 49 Listen auftaucht?

Freue mich auf eure Antworten.
Gruß

 

Hallo!

Ja, das geht.
Hier ein Beispiel mit 10 Einträgen und drei DropDowns:
Die DropDowns sind in D1:D3.
Die Quelle dieser DropDowns ist ein dynamischer Bereichsname, der sich auf Spalte B bezieht.
In Spalte A ist die ursprüngliche Liste.
In Spalte B werden die in Spalte D schon gewählten Einträge ausgefiltert.

	A	B	C	D
1	Liste	Liste (Filter)		Eintrag4
2	Eintrag1	Eintrag1		Eintrag7
3	Eintrag2	Eintrag2		Eintrag8
4	Eintrag3	Eintrag3
5	Eintrag4	Eintrag5
6	Eintrag5	Eintrag6
7	Eintrag6	Eintrag9
8	Eintrag7	Eintrag10
9	Eintrag8
10	Eintrag9
11	Eintrag10
12

Name	Bezug
xyz	=BEREICH.VERSCHIEBEN(Tabelle3!$B$2;;;10-ANZAHL2(Tabelle3!$D:$D))

Zelle	Formel
B2	{=WENN(ZEILE(A1)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A1))))}
B3	{=WENN(ZEILE(A2)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A2))))}
B4	{=WENN(ZEILE(A3)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A3))))}
B5	{=WENN(ZEILE(A4)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A4))))}
B6	{=WENN(ZEILE(A5)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A5))))}
B7	{=WENN(ZEILE(A6)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A6))))}
B8	{=WENN(ZEILE(A7)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A7))))}
B9	{=WENN(ZEILE(A8)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A8))))}
B10	{=WENN(ZEILE(A9)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A9))))}
B11	{=WENN(ZEILE(A10)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A10))))}
B12	{=WENN(ZEILE(A11)>10-ANZAHL2(D:D);"";INDEX(A:A;KKLEINSTE(WENN(ZÄHLENWENN(D:D;A$2:A$11)=0;ZEILE($2:$11));ZEILE(A11))))}

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

Zelle	Gültigkeitstyp	Operator	Wert1	Wert2
D1	Liste		=xyz
D2	Liste		=xyz
D3	Liste		=xyz

 

Hallo Schatzi,

danke für die Antwort.
Nur glaube ich, ich stehe auf dem Schlauch. :roll:

In Zeile A1-A50 habe ich jeweils eine Auswahlliste.
Die Liste besteht aus ca. 300 Namen.
Da ich an Position 50 anfange, den Namen einzutragen, sollte der
gewählte Name in den restlichen 49 Dropdowns nicht mehr auswählbar sein.
Ist deine Lösung der richtige Ansatz? Wenn ja, wo muss ich was eintragen?

Ich komme mit deiner Lösung leider nicht zurecht.... (und ich dachte Excel kenn ich)

Danke und Gruß

 

Hallo!

Ja, ich denke, ich habe dich schon richtig verstanden.
Irgendwo wirst du ja deine 300 Einträge hinterlegt haben.
Daneben (oder sonstwo) legst du dir eine Liste an, in der die schon gewählten Einträge weggefiltert werden, so wie oben die Spalte B.
Dieser neuen Liste gibst du nun einen (dynamischen) Bereichsnamen, wie es im Tutorial beschrieben ist.
Nun markierst du A1:A50 und wählst Menü Daten > Gültigkeit > Zulassen:Liste > Quelle:=DeinName
Ob du nun in diesem Bereich oben oder unten anfängst, deine Einträge vorzunehmen, ist völlig egal.