Office: (Office 2016) Druckbarer LAufzettel mit variablen Daten

Christian 09111989 · 24. Januar 2021

Hallo zusammen,

ich möchte gerne einen excelbasierten Laufzettel generieren, welcher variable Daten und Standard Daten beinhaltet. Der Laufzettel soll später gedruckt und abgehakt werden.

Kurz zur Erklärung:
Im ersten Tabellenblatt soll der Benutzer in Spalte A eine Anzahl von Identnummern (1- max. 200) eingeben (gelber variabler Bereich). Im rechten Bereich des Tabellenblatts sollen allgemeine Daten eingegeben werden (grüner Bereich).
Der Benutzer kann bis zu 8 Maßnahmen eingeben, wenn eine Maßnahme eingegeben wird, soll eine Checkbox hinter der Maßnahme erscheinen.
Im Falle von einer eingegebenen Maßnahme soll auch nur diese auf dem Laufzettel inklusive der Ckeckbox erscheinen.

Excel hat nun die Aufgabe, einzelne Laufzettel zu generieren, welche auf den eingegebenen Daten aus "Dateneingabe" basieren und dem Layout "Laufzettel" entsprechen.
Die zu generiendenen Laufzettel unterscheiden sich nur durch die ID, welche der Benuter unter "Dateneingabe" Spalte A einliest.

Wenn der Benutzer also 4 ID's in die Spalte A einfügt, würde Excel 4 Laufzettel erstellen, welche die Standard Daten (grüner Bereich) aus "Dateneingabe" beinhalten, sich jedoch durch die ID unterscheiden (siehe angehängte Datei).

Wenn die einzelnen Laufzettel generiert wurden, sollen diese gedruckt werden (immer zwei Laufzettel auf eine A4 Seite im Hochformat).

Der Benutzer hakt dann die einzelnen Maßnahmen ab, sobald diese erledigt wurden.

Für eine Hilfestellung wäre ich euch sehr dankbar. Makros können nat. eingesetzt werden, ohne geht es denke ich eh nicht.

VG Christian

:)

GraFri · 26. Januar 2021

Hallo

Ein Ansatz:

Code:

Option Explicit

' 2 Laufzettel werden untereinander so plaziert, das sie eine DIN A4 Seite
' ergeben. Die Eingabefelder der Vorlage Laufzettel werden gelöscht, neu
' befüllt und dann ans Ende kopiert und umbenannt

Sub Laufzettel_erzeugen()
Dim datEing As Worksheet, laufZtl As Worksheet
Dim arrMa As Variant
Dim rngZ1 As Range, rngZ2 As Range
Dim wh As Long, begZeile As Long, Zähler As Long

' Zeilen bis zur Wiederholung zwischen den 2 Laufzetteln - anpassen
wh = 20

Set datEing = ThisWorkbook.Worksheets("Dateneingabe")
Set laufZtl = ThisWorkbook.Worksheets("Laufzettel")

arrMa = datEing.Range(Cells(5, 4), Cells(12, 4)).Value

begZeile = 2: Zähler = 0
Do While datEing.Cells(begZeile + Zähler, 1).Value vbNullString ' solange ID vorhanden

' 1. Laufzettel
With laufZtl
.Range("C3:G3, C4:G4, A6:F13, B15, F15").ClearContents
.Cells(3, 3).Value = datEing.Cells(2, 4).Value ' Nummer
.Cells(4, 3).Value = datEing.Cells(begZeile + Zähler, 1).Value ' ID
.Range(.Cells(6, 1), .Cells(13, 1)).Value = arrMa ' Maßnahmen
.Cells(15, 2).Value = datEing.Cells(16, 4).Value ' Ersteller
.Cells(15, 6).Value = datEing.Cells(19, 4).Value ' Datum
End With

' 2. Laufzettel
With laufZtl
Range("C23:G23, C24:G24, A26:F33, B35, F35").ClearContents
.Cells(3 + wh, 3).Value = datEing.Cells(2, 4).Value ' Nummer
.Cells(4 + wh, 3).Value = datEing.Cells(begZeile + Zähler, 1).Value ' ID
.Range(.Cells(6 + wh, 1), .Cells(13 + wh, 1)).Value = arrMa ' Maßnahmen
.Cells(15 + wh, 2).Value = datEing.Cells(16, 4).Value ' Ersteller
.Cells(15 + wh, 6).Value = datEing.Cells(19, 4).Value ' Datum
End With

Zähler = Zähler + 1

' Kopieren und Benennen
Sheets("Laufzettel").Copy After:=Sheets(Sheets.Count)
Sheets(Sheets.Count).Name = "LZ_" & CStr(Zähler) ' Tabellenname der Laufzettel anpassen
Loop

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Blätter dann auszudrucken dürfte kein Problem mehr sein.

mfg GraFri

Christian 09111989 · 26. Januar 2021

Hallo Grafri,

das sieht schon super aus. Vielen vielen Dank schon mal.
Ein paar Wünsche hätte ich noch:
1. wenn der Makro ausgeführt wird, sollen immer 2 erstellte Laufzettel auf ein A4 Blatt verteilt werden. Wenn es also 5 ID`s eingelesen werden, soll Excel 3 Laufzettel ausgeben. (Laufzettel 1 beinhaltet ID 1 und ID 2, Laufzettel 2 beinhaltet ID 3 + ID 4, Laufzettel 3 beinhaltet ID 5....
Aktuell werden die ID's doppelt untereinander ausgegeben.

2. Gibt es eine Möglichkeit, nur die erzeugten Laufzettel "LZ 1- LZ n" drucken zu lassen?

3. Es wäre super, wenn der Ersteller die Excel nach dem gedruckt wurde, wieder in den Ausgangsstatus setzen könnte (Makro reset)

4. Wenn eine Anpassung (Formatierung) am Layout "Laufzettel" durchegführt werden sollte, wäre es super, wenn sich dies auf alle zu erstellenden Laufzettel auswirken würde.

Viele Grüße
Christian

GraFri · 27. Januar 2021

Hallo Christian

Geänderte Datei. Zellzuordnung bei Layout Änderung eventuell anpassen. Löschen und Rücksetzen in einer eigenen Routine.

Code:

Option Explicit

' 2 Laufzettel werden untereinander so plaziert, das sie eine DIN A4 Seite ergeben.
' wenn Änderungen am Layout "Laufzettel" oder am Layout "Dateneingabe" erfolgen,
' müssen eventuell die Zellverbindungen angepasst werden. 'Zellen verbinden' unbedingt
' vermeiden - geht auch ohne.

Sub Laufzettel_erzeugen()
Dim datEing As Worksheet, laufZtl As Worksheet, Blatt As Worksheet
Dim rngZ1 As Range, rngZ2 As Range, Zelle As Range
Dim arrMa As Variant
Dim txtID As String, namlaufZtl As String
Dim begZeileID As Long, anzID As Long, wh As Long, Zähler As Long

' Zeilen bis zur Wiederholung zwischen den 2 Laufzetteln
wh = 20

Set datEing = ThisWorkbook.Worksheets("Dateneingabe")
Set laufZtl = ThisWorkbook.Worksheets("Laufzettel")

arrMa = datEing.Range("D5:D12").Value

' wie viele verschiedene ID sind vorhanden
begZeileID = 2
For Each Zelle In datEing.Columns(1).Cells
If IsEmpty(Zelle) = True Then anzID = Zelle.Row - begZeileID: Exit For
Next Zelle

Zähler = 0
For Zähler = 1 To anzID ' solange ID vorhanden

With laufZtl
' beide Laufzettel Eingabefelder löschen
.Range("C3, C4, A6:A13, B15, F15").ClearContents
.Range("C23, C24, A26:A33, B35, F35").ClearContents

' 1. Laufzettel
txtID = datEing.Range("A" & CStr(begZeileID + Zähler - 1)).Value
namlaufZtl = "LZ_" & CStr(Zähler)

.Range("C3").Value = datEing.Range("D2").Value ' Nummer
.Range("C4").Value = txtID ' ID
.Range("A6:A13").Value = arrMa ' Maßnahmen
.Range("B15").Value = datEing.Range("D16").Value ' Ersteller
.Range("F15").Value = datEing.Range("D19").Value ' Datum

If Zähler = anzID Then GoTo Tabelle_kopieren
Zähler = Zähler + 1

' 2. Laufzettel
txtID = datEing.Range("A" & CStr(begZeileID + Zähler - 1)).Value
namlaufZtl = namlaufZtl & "_" & CStr(Zähler)

.Range("C23").Value = datEing.Range("D2").Value ' Nummer
.Range("C24").Value = txtID ' ID
.Range("A26:A33").Value = arrMa ' Maßnahmen
.Range("B35").Value = datEing.Range("D16").Value ' Ersteller
.Range("F35").Value = datEing.Range("D19").Value ' Datum
End With

Tabelle_kopieren:
' Kopieren und Benennen
Sheets("Laufzettel").Copy After:=Sheets(Sheets.Count)
Sheets(Sheets.Count).Name = namlaufZtl ' Tabellenname der Laufzettel

Next Zähler

' Ausdruck - aktivieren
For Each Blatt In Worksheets
If Left(Blatt.Name, 3) = "LZ_" Then MsgBox Blatt.Name
'If Left(Blatt.Name, 3) = "LZ_" Then Blatt.PrintOut
Next Blatt

End Sub

' Löschen der erstellten Laufzettel
Sub Laufzettel_löschen()
Dim Blatt As Worksheet

' beide Laufzettel Eingabefelder löschen
With ThisWorkbook.Worksheets("Laufzettel")
.Range("C3, C4, A6:A13, B15, F15").ClearContents
.Range("C23, C24, A26:A33, B35, F35").ClearContents
End With

Application.DisplayAlerts = False ' Warnhinweis ausschalten

For Each Blatt In Worksheets
If Left(Blatt.Name, 3) = "LZ_" Then Blatt.Delete
Next Blatt

Application.DisplayAlerts = True

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

mfg GraFri

Christian 09111989 · 29. Januar 2021

Hallo Grafri,

vielen Dank :-)

Ich hätte noch zwei Fragen an dich.
1. Nachdem die Laufzettel generiert wurden, erscheint für jedes Blatt die Mitteilung "LZ_1_2" welche mit Ok bestätigt werden muss.
Kann diese Mitteiling/Bestätigung auch entfallen?

2. Ich hatte ja angesprochen, dass es gut wäre, wenn nur die generierten Laufzettel gedruckt werden könnten. Wie bekomme ich das hin?
Muss hierzu noch etwas eingestellt werden?

Vielen Dank für deine Zeit

GraFri · 1. Februar 2021

Hallo

Ändere

Code:

' Ausdruck - aktivieren
For Each Blatt In Worksheets
If Left(Blatt.Name, 3) = "LZ_" Then Blatt.PrintOut
Next Blatt
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

dann werden nur die Laufzettel ausgedruckt und die Abfrage ist verschwunden.

mfg GraFri

Christian 09111989 · 4. Februar 2021

Hallo Grafri,

das Programm funktioniert perfekt.
Aktuell werden die Laufzettel ja direkt gedruckt, nachdem diese erzeugt wurden.

Ich würde dem Anwender gerne die Möglichkeit geben, die erstellten Laufzettel zunächst zu prüfen um sie dann per Button Klick auszudrucken.

Hierzu würde ich gerne einen neuen sub "Laufzettel drucken" anlegen und diesen dann mit einem Button verknüpfen. Leider ist mir dies bisher nicht gelungen.

Ein zweiter kleiner Punkt wäre noch der folgende. Wenn eine ungerade Anzahl an ID's eingegeben wird, dann wäre es supwe, wenn auf dem letzten Blatt auch nur der Laufzettel gedruckt werden würde, für den eine ID vorhanden ist.

Auf dem letzten Blatt wäre dementsprechend nur ein Laufzettel vorhanden. -> spart Druckertinte

Vielen Dank für deine Hilfe

GraFri · 4. Februar 2021

Hallo Christian

Anbei geänderte Datei.

Noch ein kleines Problem:

Wenn das Programm zwei mal hintereinander gestartet wird, ohne das man die Laufzettel vorher löscht erhalten diese beim 2. Durchlauf den Namen Laufzettel (2) usw.

Kann man verhindern, indem das Programm vor dem 2. Durchlauf kontrolliert, ob schon Laufzettel vorhanden sind und dann abbricht.
Oder man benennt die bereits bestehenden Laufzettel um.
Oder man sperrt den Button zum neuerlichen Start, bis die Laufzettel gelöscht sind.
Oder man löscht beim 2. Durchlauf vorher alle Laufzettel, egal wie sie heißen (LZ_1_2, Laufzettel (2) ...)

mfg GraFri

Christian 09111989 · 15. Februar 2021

Hallo Grafri,

das Programm funktioniert perfekt.

Vielen vielen Dank für deine Unterstützung.

Viele Grüße Christian

Office: (Office 2016) Druckbarer LAufzettel mit variablen Daten

Druckbarer LAufzettel mit variablen Daten

Druckbarer LAufzettel mit variablen Daten

Druckbarer LAufzettel mit variablen Daten

Druckbarer LAufzettel mit variablen Daten

Druckbarer LAufzettel mit variablen Daten - Similar Threads - Druckbarer LAufzettel variablen

Combobox einbinden

VBA:Laufzeitfehler beim Einlesen in Variable

Adressen in eine Zelle bei Übereinstimmung eindeutiger Werte einer anderen Spalte

Button nur einmal drückbar

TIFF-Bild im Word nicht druckbar...

Nicht druckbare Zeichen in Powerpoint anzeigen

Nicht druckbare Zeichen