Office: (Office 2016) Duplikate entfernen, Zellen zählen, Werte hinzufügen

Hi,
Ui, Danke. Hab heut meine Datei von gestern auf mein Arbeitsrechner getestet und bekamm auch gleich nen Fehler im Code wo ich die Formel direkt in die Zelle schreibe wie bei deinem zweiten Bsp.Code.
Der erste Code finde ich super. und er funktioniert auch super. Werde es moirgen gleich auf auf mein Workrechner testen.
Ich werde werde den C87 Bezug noch automatisch ermitteln lassen da sich die Einträge nach unten hin immer ändern.
Mal schaun. Ich geb morgen mal RM ob es auf mein anderen Rechner auch läuft.
Gruß CX

 

Hallo,

wenn du mit dem Fehler meinst, dass sich ein falsches Resultat ergibt, dann hast du recht. Ich habe bemerkt, dass der Filterstring für den 1. Funktionsaufruf in der Formel falsch ist (weil doppelt, d.h. gleich dem 3. Funktionsaufruf). Es gehört statt "SW" in Wahrheit "MN" in die Formel.
Die korrekte Sub lautet wie folgt:

Code:

Sub Formel_In_C1()
 
'1) Folgende Formel soll in C1 gespeichert werden:
'
'        ="Pos.(" & ZaehlenEindeutig(C2:C87,"MN")+ZaehlenEindeutig(C2:C87,"AN")+ZaehlenEindeutig(C2:C87,"SW") & ") SW"
'
'2) Da diese Formel ihrerseits in einer Zeichenkette gespeichert werden soll/muss,
'      muss jedes enthaltene Anführungszeichen durch 2 Anführungszeichen ersetzt werden.
'3) Da die Formel in Range("C1") gespeichert werden soll mit Hilfe der Eigenschaft ".FormulaR1C1",
'      müssen die enthaltenen Bereichsadressen in relative Adressen bezüglich C1 umgewandelt werden:

    Range("C1").Formula2R1C1 = "=""Pos.("" & ZaehlenEindeutig(R[1]C:R[86]C,""MN"")+ZaehlenEindeutig(R[1]C:R[86]C,""AN"")+ZaehlenEindeutig(R[1]C:R[86]C,""SW"") & "") SW"""
 
End Sub

Ich bitte um Entschuldigung für meine Unachtsamkeit.

 

Hi, kein Problem. ich benutze die Variante "erster Sub". Die funktioniert gut.
Wie schauts aus wenn ich die Zeilenangabe dynamisch gestallten will?
Ich hab es jetzt so gemacht. Doch wieder funktioniert es nicht recht.
Info: Ich bezieh mich hier auf Spalte M und nicht mehr auf C

Code:

Sub Wert_In_M1()
Dim Ct As Long
Dim lngZeileMax As Long
    
    With Tabelle1
        lngZeileMax = .UsedRange.Rows.Count
    End With
 
Ct = ZaehlenEindeutig(Range("M2" & lngZeileMax), "SN") + ZaehlenEindeutig(Range("M2" & lngZeileMax), "SF") + ZaehlenEindeutig(Range("M2" & lngZeileMax), "MN") + ZaehlenEindeutig(Range("M2" & lngZeileMax), "AN") + ZaehlenEindeutig(Range("M2" & lngZeileMax), "SW")
   Range("M1").Value = "Pos.  (" & Ct & ") SW"
 
End Sub

 

Hallo,

das was ich auf Anhieb sehe, ist Folgendes: Range("M2" & lngZeileMax)
Müsste es nicht vielmehr heißen: Range("M2:M" & lngZeileMax)
Diese fehlerhafte Passage hast du 5x in der Zeile, die mit Ct = ... beginnt.

Es gibt ein zweites mögliches Problem: Die Zeile, in der du den Wert für lngZeileMax ermittelst:
lngZeileMax = Tabelle1.UsedRange.Rows.Count
Mit UsedRange wird der benützte Zellbereich im Arbeitsblatt Tabelle1 ermittelt und anschließend mit .Rows.Count die darin enthaltenen Zeilen gezählt. Angenommen du hättest ein Arbeitsblatt "Tabelle2" mit 2 Zahlen in B4 und C5, so wie nachfolgend dargestellt:

Wendest du darauf folgende VBA-Formel im Direktfenster des VBA-Editors an:
? Tabelle2.UsedRange.Address erhältst du als Zellbereich $B$4:$C$5
Ferner folgende Formel:
? Tabelle2.UsedRange.Rows.Count erhältst du damit folglich als Resultat die 2.
Vermutlich wolltest du aber als Ergebnis die (Zeile) 5. Die 5 ist wiederum für Spalte C korrekt als letzte Zeile, nicht aber für Spalte B (dort wäre es die 4).
Um die Zeilenummer der letzten benutzten Zeile eines Arbeitsblattes zu erhalten, müsste man so vorgehen:

Code:

With Tabelle2.UsedRange
      lngZeileMax = .Row + .Rows.Count - 1
End With

Das ergibt dann für die Variable lngZeileMax den Wert 5.

Mit folgendem Code erhält man die erwarteten Werte für Spalte B bzw. C:

Code:

   With Tabelle2
      letzteZeileNr_SpalteB = .Cells(.Rows.Count, "B").End(xlUp).Row
      letzteZeileNr_SpalteC = .Cells(.Rows.Count, "C").End(xlUp).Row
   End With

 

Hi,
mercy für die super Erläuterung und den Hinweis auf die möglichen Probleme.
Ich hab es gleich eingearbeitet und nach deinen Vorschlägen umgesetzt. Funktioniert super.
Danke.