Office: Ein Arbeitsblatt aus Datei als txt speichern

Hi Leutz,

ich möchte gerne aus einer Excel-Datei ein bestimmtes (also fixes) Arbeitsblatt als txt-Datei speichern. Bei der Datei handelt es sich um ein Programm, das mitlerweile recht groß geworden ist. Wenn ich damit nun einen Kunden bearbeite, dann möchte ich die Daten, die ich ja Kundenspezifisch eingegeben habe, speichern könnnen. Hierfür werden diese Daten in ein bestimmtes Arbeitsblatt kopiert, damit dieses dann als txt-Datei platzsparend gespeichert werden kann.

Bisher habe ich zwei Varianten hinbekommen... zum einen das Speichern des einen Arbeitsblatts als txt-Datei unter fest vorgegebenem Pfad und zum anderen das Öffnen des "Speichern Unter" -Fensters (aber dann nur als xls-Datei und dann auch nur die gesamte Arbeitsmappe). Den Namen lasse ich mir bereits aus den vorhanden Daten generieren...

Nochmal kurz zusammengefasst... ich will ein bestimmtes Arbeitsblatt als eigenständige txt-Datei speichern und mit dem "Speichern Unter"-Fenster den Pfad manuell einstellen können.

Bin für jede Hilfe und Vorschläge dankbar.

Gruß

 

Hallo Dr.Eck,

1) Du rufst, wie gewünscht, das "Speichern-Unter"-Dialogfenster auf
2) In diesem Fenster gibt es in der untersten Zeile die Combobox "Dateityp". In diese klickst Du, sodass eine Liste unterschiedlicher Dateitypen zu sehen ist.
In dieser scrollst Du hinunter, bis der Listeneintrag "Text (Tabstopp-getrennt) (*.txt)" erscheint; auf diesen Listeneintrag bitte klicken.
3) Im Feld darüber (Combobox "Dateiname") ist daraufhin ein Dateiname zu sehen, der bereits die Dateierweiterung ".txt" am Schluss des Namens besitzt. Diesen Namen (vor dem ".txt") an die eigenen Wünsche anpassen.
4) In der Combobox ganz oben im Fenster (Combobox "Speichern in:") muss natürlich das richtige Verzeichnis eingestellt sein.
5) Auf den Button "Speichern" in der rechten unteren Ecke des Dialogfenster klicken.
Das war alles.

 

Hallo Exl121150,

danke für deine schnelle Antwort. Ich fürchte nur, dass wir da leicht aneinander vorbei geredet haben :D

Ich will das im VBA programmieren... wie ich das manuell hinbekomme ist mir schon klar... aber ich kriege es eben im VBA nicht hin.

Gruß

 

Hallo Dr.Eck,

nachfolgend eine Version des gewünschten Makros, am besten in einem allgem. Codemodul zu speichern.

Anzupassen ist eventuell die Konstante cFilterInd=11, da ich nicht weiß, der wievielte Eintrag in der Combobox "Dateityp" des Speichern-Unter-Dialogfensters das bei Dir ist. Bei mir war es der 11. Eintrag. Sobald diese Nr. korrekt ist, wird dieser Dateityp beim Aufruf des Dialoges automatisch vorgewählt in der Combobox.
Für das Speichern-Unter muss zwingend die FilterIndex-Eigenschaft verwendet werden (und nicht die Filter.Add-Methode), denn Excel kann nur aus der vorgegebenen Liste eine Speichermethode auswählen.

Ferner kann bei Speicherung als TXT-Datei nur das aktive Arbeitsblatt aus der Arbeitsmappe gespeichert werden. Meine Vorgabe "Tabelle2" muss natürlich auch angepasst werden.

Der Vorgabepfad für das Dialogfenster steht in der Eigenschaft "InitialFileName". Er ist in meinem Beispiel so eingestellt, dass ins selbe Verzeichnis, in dem auch die Excel-Datei steht, gespeichert wird - eventuell auch anzupassen.

Code:

'Folgende Konstante dient
'1) zur Auswahl des Tabellenblattes und
'2) zur Vorgabe des Dateinamens (der Pfad ist der der Excel-Datei)
Const cBlatt$ = "Tabelle2"

'Ist eventuell an die Comboboxliste anzupassen
'(Nr des Eintrags in der Combobox "Dateityp")
Const cFilterInd = 11

'In Excel2007 vordefinierte Konstanten; um keine Probleme mit Excel2003
'zu bekommen, habe ich sie hier explizit definiert.
Const msoFileDialogSaveAs = 2
Const msoFileDialogViewDetails = 2

Public Sub TextDatei_Speichern()
  
  'Es kann nur das aktive Blatt als TXT-Datei gespeichert werden
  ActiveWorkbook.Sheets(cBlatt$).Activate
  
  'Ruft temporär das FileDialog-Objekt auf: davon gibt es mehrere Varianten,
  'wovon im Folgenden die Speichern-Unter-Variante ausgewählt wird:
  With Application.FileDialog(msoFileDialogSaveAs)
  
    'Zeigt den Titel in der Kopfleiste des Dialogfensters an
    .Title = "Speichern unter als TXT-Datei"

    'InitialView enthält die Art der Dateinamensauflistung im Dialogfenster
    '(Icons, Thumbnail, Voransicht, Liste, Details, etc.)
    .InitialView = msoFileDialogViewDetails
    
    'Erlaubt (Mehrfach)/Einfachauswahl aus vorgenannter Dateinamensliste
    .AllowMultiSelect = False
    
    'InitialFileName enthält den Vorgabepfad+Dateinamen des Dialogfensters:
    'Ist momentan so eingestellt, dass er das Verzeichnis der Excel-Datei enthält
    'plus dem zu speichernden Arbeitsblatt als Vorgabedateinamen.
    'Die fehlende Extension wird automatisch ermittelt durch die FilterIndex-Eigenschaft.
    .InitialFileName = ActiveWorkbook.Path & "\" & cBlatt$
    
    'FilterIndex enthält die Nr. des Listeneintrags der Combobox "Dateityp"
    .FilterIndex = cFilterInd
    
    'Die Methode Show zeigt dann das Dialogfenster an:
    If .Show Then
      'Gibt die Show-Methode True zurück, wurde Button "Speichern" gedrückt
      'Mit der Execute-Methode wird dann das Speichern-Unter tatsächlich ausgeführt
      .Execute
    Else
      'Gibt die Show-Methode False zurück, wurde Button "Abbrechen" gedrückt
      MsgBox "Abbruch"
      Exit Sub 'Beenden, falls 'Abbrechen' gewählt wurde
    End If
  End With
  '
  'Eventuell weiterer Code
  '
End Sub

Oder aber man kann ein Arbeitsblatt auch ohne Dateidialog als Windows-Text-Datei (Tabstopp-Getrennt) speichern, zB.:

Code:

Public Sub Blatt_ohneDialog_Speichern()
  Dim Fn$, Blatt$
  Const xlTextWindows=20
  Blatt$ = "Tabelle1"
  Fn$ = ActiveWorkbook.Path & "\" & Blatt$
  Worksheets(Blatt$).SaveAs Filename:=Fn$, FileFormat:=xlTextWindows
End Sub

 

Hey Super,

werde das direkt mal ausprobieren. Melde mich, wenn es läuft oder auch nicht ;)^

Gruß

 

Also...

ich hab den Code ausprobiert... allerdings hab ich immernoch das Problem, dass er die gesamte Datei als txt speichern will... ich möchte über einen Button "Speichern" eine txt-Datei generieren, die ich mit Hilfe des Speichern Unter-Fensters in einen beliebigen Ornder speichern kann. Dabei soll er mir aber die vorhandene Programmdatei nicht zu einem txt machen, sondern diese als normale xls-Datei belassen. Ich bekomme sowas auch schon hin... aber eben nur mit einem fest vorgegebenen Pfad... der Speichern unter Dialog fehlt mir also... hier der Code, der das einzelne Speichern der Daten als txt-Datei ermöglicht, aber kein Speichern Unter-Fenster aufruft:

Code:

Sub ein_Tab_als_Datei()
Dim neuname As String
neuname = Sheets("Speichern").Range("A25") & " " & Sheets("Speichern").Range("A3") & ".txt"

Sheets("Speichern").Copy
ChDir "C:\Dokumente und Einstellungen\user\Desktop"
ActiveWorkbook.SaveAs neuname, FileFormat:=xlText, CreateBackup:=False
ActiveWorkbook.Close
End Sub

soweit so gut... wenn du mir jetzt noch sagen kannst, wie ich da ein Speichern Unter-Fenster reinbekomme bin ich schon glücklich :D

 

Hallo Dr.Eck,

folgende Version ermöglicht die Beibehaltung des Dateinamens als .XLS-Datei:
1) (Zwischen)Speicherung der ursprünglichen Excel-Datei an ihrem originären Platz
2) Durchführung der Blattspeicherung als TXT-Datei
3) Öffnen und Aktivieren der ursprüngl.Exceldatei als neue Arbeitsmappe
4) Schließen der TXT-Datei-Excel-Mappe im Hintergrund.

Code:

Option Explicit

'Folgende Konstante dient
'1) zur Auswahl des Tabellenblattes und
'2) zur Vorgabe des Dateinamens (der Pfad ist der der Excel-Datei)
Const cBlatt$ = "Tabelle1"

'Ist eventuell an die Comboboxliste anzupassen
'(Nr des Eintrags in der Combobox "Dateityp")
Const cFilterInd = 11

'In Excel2007 vordefinierte Konstanten; um keine Probleme mit Excel2003
'zu bekommen, habe ich sie hier explizit definiert.
Const msoFileDialogSaveAs = 2
Const msoFileDialogViewDetails = 2

Public Sub TextDatei_Speichern()
  Dim AktMappe$, Wb_alt As Workbook, Wb_neu As Workbook, Wnd As Window
  
  With ActiveWorkbook
    'Ermittelt den Pfad+Dateiname der aktive Mappe
    AktMappe$ = .Path & "\" & .Name
    'Speichert die aktive Mappe unter dem aktuellen Pfad+Dateinamen
    .Save
    'Es kann nur das aktive Blatt als TXT-Datei gespeichert werden
    .Sheets(cBlatt$).Activate
  End With
  'Ruft temporär das FileDialog-Objekt auf: davon gibt es mehrere Varianten,
  'wovon im Folgenden die Speicher-Unter-Variante ausgewählt wird:
  With Application.FileDialog(msoFileDialogSaveAs)
  
    'Zeigt den Titel in der Kopfleiste des Dialogfensters an
    .Title = "Speichern unter als TXT-Datei"
    'InitialView enthält die Art der Dateinamensauflistung im Dialogfenster
    '(Icons, Thumbnail, Voransicht, Liste, Details, etc.)
    .InitialView = msoFileDialogViewDetails
    
    'Erlaubt (Mehrfach)/Einfachauswahl aus vorgenannter Dateinamensliste
    .AllowMultiSelect = False
    
    'InitialFileName enthält den Vorgabepfad+Dateinamen des Dialogfensters:
    'Ist momentan so eingestellt, dass er das Verzeichnis der Excel-Datei enthält
    'plus dem zu speichernden Arbeitsblatt als Vorgabedateinamen
    .InitialFileName = ActiveWorkbook.Path & "\" & cBlatt$
    

    'FilterIndex enthält die Nr. des Listeneintrags der Combobox "Dateityp"
    .FilterIndex = cFilterInd
    
    'Die Methode Show zeigt dann das Dialogfenster an:
    If .Show Then
      'Gibt die Show-Methode True zurück, wurde Button "Speichern" gedrückt
      'Mit der Execute-Methode wird dann eine Aktion tatsächlich ausgeführt
      'und zwar in der Variante msoFileDialogSaveAs und FilterIndex=11
      .Execute
    Else
      'Gibt die Show-Methode False zurück, wurde Button "Abbrechen" gedrückt
      MsgBox "Abbruch"
      Exit Sub 'Beenden, falls 'Abbrechen' gewählt wurde
    End If
  End With
  '
  'Weist der aktiven Mappe einen Mappenobjektzeiger zu
  Set Wb_alt = ActiveWorkbook
  'Öffnet die (zwischen)gespeicherte Mappe unter neuem Mappenobjektzeiger
  Set Wb_neu = Workbooks.Open(AktMappe$)
  'Macht neue Mappe zur aktiven Mappe
  Wb_neu.Activate
  'Schließt alte Mappe ("....txt")
  Wb_alt.Close
  '
  'Eventuell weiterer Code
  '
End Sub

 

Hi Exl121150,

ich habs jetzt hinbekommen. Ich hab mir ein Makro aufgenommen und den Teil, in dem er die Speicherfunktion ausführen will mit deiner Variante ersetzt. Das funktioniert auch wunderbar mit automatischer Namensgenerierung usw.

Habe deine Variante auch nochmal ausprobiert... aber da springt ständig der Debugger an... dann springt er in eine vollkommen unbeteiligte Arbeitsmappe und gibt mir einen Fehler aus.

Ich denke es liegt daran, dass du eben die Ursprungsdatei speicherst und diese im nachhinein wieder lädst... meine Variante geht genau den umgekehrten Weg. Ich erstelle eine komplett neue Datei, lasse einen bestimmten Bereich kopieren und speicher diese Datei dann als txt ab. Im anschluss wird diese einfach geschlossen und er springt wieder zurück in meine Ursprungsdatei... das einzige was mich hierbei noch nervt ist, dass er nach erfolgreichem speichern und dann nach dem schließen der neuen Arbeitsmappe extra nochmal fragt, ob ich die Änderungen speichern will... hierbei ist es egal, ob ich ja oder nein anklicke... die gespeicherten Daten sind so wie sie sein sollen... vielleicht kannst du mir dabei noch helfen, wie ich ihm automatisch sagen kann... klick ja oder nein... hier nochmal der Code, der dann letztendlich bei mir zum Erfolg geführt hat:

Code:

Sub Daten_als_txt_speichern()
    Dim neuname As String
    'neuname wird zur automatischen Namensgenerierung genutzt und holt sich seine Informationen direkt aus dem zu speichernden Arbeitsblatt
    neuname = Sheets("Speichern").Range("A25") & " " & Sheets("Speichern").Range("A3") & ".txt"
'
    Sheets("Speichern").Select
    Sheets("Speichern").Range("A1:A25").Select
    Selection.Copy
    Workbooks.Add
    Sheets("Tabelle1").Range("A1:A25").Select
    ActiveSheet.Paste
    Application.CutCopyMode = False
    With Application.FileDialog(msoFileDialogSaveAs)
  
    'Zeigt den Titel in der Kopfleiste des Dialogfensters an
    .Title = "Speichern unter als TXT-Datei"

    'InitialView enthält die Art der Dateinamensauflistung im Dialogfenster
    '(Icons, Thumbnail, Voransicht, Liste, Details, etc.)
    .InitialView = msoFileDialogViewDetails
    
    'Erlaubt (Mehrfach)/Einfachauswahl aus vorgenannter Dateinamensliste
    .AllowMultiSelect = False
    
    'InitialFileName enthält den Vorgabepfad+Dateinamen des Dialogfensters:
    'Ist momentan so eingestellt, dass er das Verzeichnis der Excel-Datei enthält
    'plus dem zu speichernden Arbeitsblatt als Vorgabedateinamen.
    'Die fehlende Extension wird automatisch ermittelt durch die FilterIndex-Eigenschaft.
    .InitialFileName = neuname
    
    'FilterIndex enthält die Nr. des Listeneintrags der Combobox "Dateityp"
    .FilterIndex = 7
    
    'Die Methode Show zeigt dann das Dialogfenster an:
    If .Show Then
      'Gibt die Show-Methode True zurück, wurde Button "Speichern" gedrückt
      'Mit der Execute-Methode wird dann das Speichern-Unter tatsächlich ausgeführt
      .Execute
    Else
      'Gibt die Show-Methode False zurück, wurde Button "Abbrechen" gedrückt
      MsgBox "Abbruch"
      Exit Sub 'Beenden, falls 'Abbrechen' gewählt wurde
    End If
  End With
    ActiveWindow.Close
    Sheets("Ursprung").Select
    Sheets("Ursprung").Range("G42").Select
End Sub

 

Hallo Dr.Eck,

diese lästige Nachfragerei wurde von "ActiveWindow.Close" ausgelöst.
Ich habe den Code etwas angepasst und mit Kommentar versehen, sodass er verständlich sein müsste.

Ich hoffe, es klappt jetzt zur Zufriedenheit.

Code:

Sub Daten_als_txt_speichern()
    Dim NeuName As String, Wb_Txt As Workbook, Wb_Xls As Workbook
    'neuname wird zur automatischen Namensgenerierung genutzt und
    'holt sich seine Informationen direkt aus dem zu speichernden Arbeitsblatt
    'Dabei muss NeuName einen vollständigen/gültigen Pfad enthalten samt Dateiname!!
'---------
    'Dem Mappeninstanzzeiger "Wb_Xls" auf die XLS-Mappe zeigen lassen
    'In dieser Mappe muss es die 2 Blätter "Speichern" und "Ursprung" geben.
    Set Wb_Xls = ActiveWorkbook
    'Inhalte des Blattes "Speichern" in das ClipBoard speichern
    With Wb_Xls.Sheets("Speichern")
      NeuName = .Range("A25") & " " & .Range("A3") & ".txt"
      .Range("A1:A25").Copy
    End With
'---------
    'Neue Arbeitsmappe erzeugen und Mappeninstanzzeiger "Wb_Txt" darauf zeigen lassen
    'In dieser Mappe muss es das Blatt "Tabelle1" geben.
    Set Wb_Txt = Workbooks.Add
    'Auf Wb_Txt-Arbeitsmappe umschalten/aktivieren
    Wb_Txt.Activate
    'Im Blatt "Tabelle1" ab Zelle A1 Inhalt des ClipBoards einfügen
    With Sheets("Tabelle1")
      .Paste Destination:=.Range("A1")
    End With
    Application.CutCopyMode = False
'---------
    'Temporär das Dateidialogobjekt erzeugen
    With Application.FileDialog(msoFileDialogSaveAs)
  
    'Zeigt den Titel in der Kopfleiste des Dialogfensters an
    .Title = "Speichern unter als TXT-Datei"

    'InitialView enthält die Art der Dateinamensauflistung im Dialogfenster
    '(Icons, Thumbnail, Voransicht, Liste, Details, etc.)
    .InitialView = msoFileDialogViewDetails
    
    'Erlaubt (Mehrfach)/Einfachauswahl aus vorgenannter Dateinamensliste
    .AllowMultiSelect = False
    
    'InitialFileName enthält den Vorgabepfad+Dateinamen des Dialogfensters:
    'Ist momentan so eingestellt, dass er das Verzeichnis der Excel-Datei enthält
    'plus dem zu speichernden Arbeitsblatt als Vorgabedateinamen.
    'Die fehlende Extension wird automatisch ermittelt durch die FilterIndex-Eigenschaft.
    .InitialFileName = NeuName
    
    'FilterIndex enthält die Nr. des Listeneintrags der Combobox "Dateityp"
    .FilterIndex = 7 '11
    
    'Die Methode Show zeigt dann das Dialogfenster an:
    If .Show Then
      'Gibt die Show-Methode True zurück, wurde Button "Speichern" gedrückt
      'Mit der Execute-Methode wird dann das Speichern-Unter tatsächlich ausgeführt
      .Execute
    Else
      'Gibt die Show-Methode False zurück, wurde Button "Abbrechen" gedrückt
      MsgBox "Abbruch"
      Exit Sub 'Beenden, falls 'Abbrechen' gewählt wurde
    End If
  End With
'-------
  'Txt-Mappe schließen, ohne lästige Nachfragen zu verursachen,
  'da ohnehin nichts mehr zu speichern ist (Speichern wurde durch .Execute erledigt)
  Wb_Txt.Close SaveChanges:=False
  'Von der Txt-Mappe umschalten auf Xls-Mappe
  Wb_Xls.Activate
  'Blatt "Ursprung" auswählen und darin Zelle G42 markieren
  With Sheets("Ursprung")
    .Activate
    .Range("G42").Select
  End With
End Sub

 

Hi Exl121150,

deine Codeänderung funktioniert super. Echt erste Sahne. Das hätte ich so ohne dich nicht hinbekommen. Ich tüftel schon lange daran... hab aber bisher immer nur nach bereits vorhandenen Lösungen gesucht... aber ich fürchte, dass mein Problem da doch recht speziell war. Auf jeden Fall ein herzliches Danke!!!

Gruß vom Doc ;)