Office: (Office 365) Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten

Helfe beim Thema Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo an alle, seit zwei Tagen versuche ich nun ein Problem zu lösen und ich weiß langsam nicht mehr weiter, daher erstellte ich mir einen Account und... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von SY12345, 17. November 2022.

  1. SY12345
    SY12345 Neuer User

    Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten


    Hallo an alle,

    seit zwei Tagen versuche ich nun ein Problem zu lösen und ich weiß langsam nicht mehr weiter, daher erstellte ich mir einen Account und möchte gerne euch fragen. Ich habe eine Datei mit Rohdaten in einer Tabelle mit über 20.000 Zeilen. In der zweiten Spalte stehen Namen, welche nun ohne Dopplung gezählt werden sollen, aber nur, wenn Bedingungen in anderen Spalten erfüllt werden. Da es etwas schwierig ist, zu erklären, habe ich eine Beispiel-Datei erstellt, die nicht sinnhaft ist, aber verdeutlicht, was mein Ziel ist. ZÄHLENWENN würde sehr gut funktionieren, wenn ich als erstes auswählen könnte, was gezählt werden soll und dann eine andere Spalte für das Kriterium auswählen könnte - leider geht das eben nicht. Und da es nicht um Zahlen geht, funktionieren viele Formeln, die ich im Internet gesehen habe, leider auch nicht.
    In der Datei findet ihr auf der zweiten Seite die Kriterien, daneben soll dann eben die Anzahl der Personen ohne Dopplung stehen, die diese Kriterien erfüllen. Ist dies überhaupt durch eine Formel machbar? Evtl. die ZÄHLENWENN-Formel mit WENN o.ä. kombiniert vielleicht? SVERWEIS? Ich weiß, dass es über Pivot-Tabellen problemlos funktioniert, nutze es um meine Formeln zu prüfen. Mir wäre es aufgrund des hohen Filteraufwands allerdings lieber, wenn die Anzahlen von alleine erscheinen. VBA kann ich leider nicht :/

    Ich hoffe, das war soweit verständlich, für Fragen bin ich gerne zu haben!

    Vielen lieben Dank :)



    P.S.: Gerne kann ich auch meine gescheiterten Formeln hier einfügen, aber da sie nur Fehlermeldungen oder "0" hervorbrachten, wird es wohl eher verwirren.
     
  2. lupo1
    lupo1 Tutorial Guru
    =ZEILEN(FILTER(Tabelle1;(ABS(Tabelle1[Alter]-18,5)<6)))

    =ZEILEN(FILTER(Tabelle1;(ABS(Tabelle1[Alter]-18,5)<6)*(Tabelle1[Gehalt]>2500)))

    =ZEILEN(FILTER(Tabelle1;(ABS(Tabelle1[Alter]-18,5)<6)*(Tabelle1[Gehalt]>2500)*
    ISTFEHLER(SUCHEN(Tabelle1[Status];"Single|Verheiratet"))*
    ISTFEHLER(SUCHEN(Tabelle1[Firma];"BASF SE|SAP SE"))))


    Die 4. Frage ist Murks.
     
    1 Person gefällt das.
  3. Beverly
    Beverly Erfahrener User
    Hi,


    Überblick
     BC
    2 Anzahl der Personen
    3Zwischen 13 und 24 sind61
    4Zwischen 13 und 24 sind und mehr als 2500 Euro verdienen43
    5Zwischen 13 und 24 sind und mehr als 2500 Euro verdienen und die nicht verheiratet und nicht single sind und nicht bei "BASF SE" oder "SAP SE" arbeiten20
    6Zwischen 13 und 24 sind und mehr als 2500 Euro verdienen und die nicht verheiratet und nicht single sind und nicht bei "BASF SE" oder "SAP SE" arbeiten und "single" oder "verheiratet" sind 

    verwendete Formeln
    Zelle Formel Bereich N/A
    C3=ZÄHLENWENNS(Tabelle1[Alter];">="&13;Tabelle1[Alter];"<="&24)  
    C4=ZÄHLENWENNS(Tabelle1[Alter];">="&13;Tabelle1[Alter];"<="&24;Tabelle1[Gehalt];">=2500")  
    C5=ZÄHLENWENNS(Tabelle1[Alter];">="&13;Tabelle1[Alter];"<="&24;Tabelle1[Gehalt];">="&2500;Tabelle1[Status];"<>"&"verheiratet";Tabelle1[Status];"<>"&"single";Tabelle1[Firma];"<>"&"BASF SE";Tabelle1[Firma];"<>"&"SAP SE")  
    http://excel-inn.de/dateien/vba_beispiele/tabellenanzeige_in_html_addin.zip
    http://Hajo-Excel.de/tools.htm
    Add-In-Version 25.23 einschl. 64 Bit
    XHTML-Tabelle zur Darstellung in Foren, einschl. Funktion zum Zurücklesen in eine Excel-Tabelle

    Bei Frage 4 gibt es einen Widerspruch bei den Bedingungen, man kann nicht gleichzeitig etwas nicht sein und doch auch sein - lies sie dir bitte noch einmal durch.


    Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten GrußformelEindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten Beverly's Excel - Inn
     
    1 Person gefällt das.
  4. SY12345
    SY12345 Neuer User

    Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten

    Hallo lupo1,

    ups, da hab ich wohl etwas vertauscht, hast recht: Vierte Frage kann ignoriert werden! Wow, vielen Dank für deine sehr aufschlussreiche und schnelle Antwort! Da käme ich wohl nicht drauf... Magst du mir noch erklären, wofür das "-18,5)<6" steht, damit ich es verstehe? Die Befehle ISTFEHLER und SUCHEN werde ich mir gleich mal ergooglen, ebenso die Verbindung "|", war mir nicht bekannt, kenne nur "<>", aber nehme an, die Bedeutung ist ähnlich :) Wenn man etwas "=" haben möchte denke ich, man kann einfach statt "Single|Verheiratet" "=Single" eingeben, oder?

    Auf jeden Fall funktioniert es auch bei mir, vielen vielen dank lupo1 :)


    Update: Auch hier ist es leider so, dass die Zahl mit einer anderen bereits übereinstimmt. Ich werde mal eine neue Datei erstellen in der Hoffnung, dass es dort besser funktioniert!
     
  5. SY12345
    SY12345 Neuer User
    Hey Karin/Beverly,

    vielen Dank auch für deine Antwort! Das funktioniert zwar, allerdings zählt excel damit doch nur die Werte in der Spalte "Alter", oder nicht? Bei genauem Hinsehen ist es vllt auch bei lupo1’s Lösung der Fall, ich versuche es sofort mal im anderen Dokument. Ich habe im Originaldokument nämlich das Problem, dass ich genau diesen „ZÄHLENWENNS“-Befehl bereits benutzt habe, um die Anzahl an Häusern zu bestimmen, wobei mehrere Häuser zum Teil nur einer Person gehören und ich nun eben die Anzahl der Personen benötige. Das hätte ich vielleicht irgendwie in die Beispieldatei mit aufnehmen sollen, dachte es hätte mit der Firmenzugehörigkeit geklappt, aber vielleicht bekomme ich es ja noch anders mit rein und kann es neu hochladen? Oder ich habe einen fatalen Denkfehler...
    Mit dem letzten Punkt hast du recht, da habe ich mich vertan, sorry!

    Danke dir wirklich vielmals für die Antwort!
     
  6. Beverly
    Beverly Erfahrener User
    Hi,

    gezählt wird die Anzahl zwar in Spalte Alter - aber es werden die Bedingungen aus den anderen Spalten ebenfalls berücksichtigt, da man bei ZÄHLENWENNS mehrere Kriterienbereiche und mehrere Kriterien angeben kann.
    Filtere einfach mal deine Tabelle nach den betreffenden Kriterien in den verschiedenen Spalten und ermittle dann durch TEILERGEBNIS die Anzahl - dabei solltest du dieselben Zahlen erhalten.


    Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten GrußformelEindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten Beverly's Excel - Inn
     
    Zuletzt bearbeitet: 17. November 2022
    1 Person gefällt das.
  7. lupo1
    lupo1 Tutorial Guru
    Das mit den Häusern und Personen ist ein ganz anderes Zähl-Gebiet.

    Beverly und ich haben die gleichen Ergebnisse. Weitere ZÄHLENWENNS-Bedingungen sind strikt UND-verknüpft. Will man XODER, summiert man mehrere ZÄHLENWENNS. Bei ODER muss man aufpassen.
     
    1 Person gefällt das.
  8. SY12345
    SY12345 Neuer User

    Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten

    Hallo nochmal,

    da habt ihr beide recht, ich habe das Beispiel wohl etwas ZU vereinfacht und einiges unbeachtet gelassen, sorry dafür. In der Tat ist es wie lupo1 sagt, Häuser kämen dazu, allerdings weiß ich nicht genau, wie es um die UND-Verknüpfung und die XODER steht? Ich habe mal die Datei erneuert und hoffe, dass ich damit ausdrücken kann, wo mein Problem liegt. Jedes Haus gibt es nur einmal, aber Personen können öfter auftauchen und mehrere Häuser besitzen, Zahlen würde ich eben gerne für beides haben. Bin sehr dankbar für jegliche Ideen und Vorschläge!

    Habe auch zur Kontrolle für mich die Pivot-Tabelle drinnen gelassen und eure beiden Formeln auch mal eingefügt, vielen Dank nochmal!

    Übersehe ich weiterhin etwas Offensichtliches? Falls ja, tut es mir leid!
     
  9. lupo1
    lupo1 Tutorial Guru
    Hier: (Für gleiche Namen verschiedener Personen bist Du zuständig)
     
    1 Person gefällt das.
  10. SY12345
    SY12345 Neuer User
    Hallo lupo1,

    vielen Dank! In der Datei war die Spalte "Anzahl der Häuser" nur zum verdeutlichen, dass es unterschiedliche Werte sind, daauch Häuser diese Kriterien erfüllen könnten. Das passt so! Zum Glück gibt es keine Personen mit gleichen Namen, das passt also auch. Da ich die Formel allerdings nicht wirklich verstehe, wärst du so nett und könntest sie mir erklären? Dann kann ich sie zukünftig auch anwenden und ggf. anpassen :)
     
  11. lupo1
    lupo1 Tutorial Guru
    E6:
    =ZEILEN(
    FILTER(Tabelle1;(ABS(Tabelle1[Alter des Hauses]-18,5)<6)*(Tabelle1[Gehalt]>2500)*
    ISTFEHLER(SUCHEN(Tabelle1[Status];"Single|Verheiratet"))*
    ISTFEHLER(SUCHEN(Tabelle1[Firma];"BASF SE|SAP SE"))))


    Ich mag keine Mehrfachbehandlungen. Deshalb habe ich die Mitte von 13 und 24 (18,5) abgezogen (das sind 5,5 zu den Grenzen), und sie positiv und negativ kleiner als 6 erlaubt. Ich weiß: Etwas kryptisch. Beverly zeigt es normal mit Ober- und Untergrenze.

    Das gleiche mache ich mit Status und Firma: Ich verkette das "Unerwünschte" und suche dann darin. Schlägt die Suche fehl (ISTFEHLER), ist die Bedingung erfüllt. Auch hier nimmt Beverly jeweils 2 Bedingungen, statt nur 1 bei mir.

    ZEILEN() gibt die Anzahl der Sätze des Filtrats wieder.

    C6:
    =ZEILEN(EINDEUTIG(INDEX(
    FILTER(Tabelle1;(ABS(Tabelle1[Alter des Hauses]-18,5)<6)*(Tabelle1[Gehalt]>2500)*
    ISTFEHLER(SUCHEN(Tabelle1[Status];"Single|Verheiratet"))*
    ISTFEHLER(SUCHEN(Tabelle1[Firma];"BASF SE|SAP SE")));;1)))


    Hier nehme ich vom Filtrat die 1. Spalte mit INDEX(...;;1). Da stehen die Namen drin, und zwar die, die in E6 auch betroffen sind (der nicht-fette Formelteil ist in E6 und C6 gleich). Die fasse ich mit EINDEUTIG() ohne Doppler zusammen und zähle sie erneut mit ZEILEN().
     
    1 Person gefällt das.
  12. SY12345
    SY12345 Neuer User
    Ahh perfekt vielen vielen Dank, hilft mir sehr! Wie zu erwarten vom "Tutorial Guru" ;)
    Liebe Grüße
     
Thema:

Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten

Die Seite wird geladen...
  1. Eindeutige Textfelder einer Spalte zählen mit mehreren Bedingungen in anderen Spalten - Similar Threads - Eindeutige Textfelder Spalte

  2. Formel "Eindeutig()" in formatierter Tabelle

    in Microsoft Excel Hilfe
    Formel "Eindeutig()" in formatierter Tabelle: Guten Morgen zusammen, kann ich mit der Array-Formel "Eindeutig()" auch irgendwie einen als Tabelle formatierten Bereich füllen? Ich habe eine Liste mit Artikelnummern in einem unformatierten...
  3. Anzahl eindeutiger Werte mit mehreren Bedingungen

    in Microsoft Excel Hilfe
    Anzahl eindeutiger Werte mit mehreren Bedingungen: Hi zusammen Ich habe nur Formeln mit eindeutigen Werten und einer Bedingung gefunden. Nicht mal ChatGPT gibt mir die korrekte Antwort. Aufgabenstellung: Spalte A = Quartal Spalte B = Artikel...
  4. Formel bei Veränderung von dynamischem Array "mitziehen"?

    in Microsoft Excel Hilfe
    Formel bei Veränderung von dynamischem Array "mitziehen"?: Hallo liebes Forum, ich komme bei folgendem Problem nicht weiter und habe mir hier etwas Hilfe erhofft: Ich habe eine Tabelle mit Feedbacks zu Lehrgängen/Kursen. Diese will ich nach Dozent erst...
  5. Spalte mit nur eindeutigen Werten, aber ohne leere Zeilen

    in Microsoft Excel Hilfe
    Spalte mit nur eindeutigen Werten, aber ohne leere Zeilen: Hallo Community Ich will in der Spalte A im Blatt "Dashboard" nur eindeutige Werte der Spalte A im Blatt "Import" haben. Dabei sollen keine leeren Zeilen inmitten von eindeutigen Werten...
  6. XLS Ausgabe einer Liste eindeutiger, vorhandener Kombinationen (MA + Team)

    in Microsoft Excel Hilfe
    XLS Ausgabe einer Liste eindeutiger, vorhandener Kombinationen (MA + Team): Liebe Leute, ich stehe vor folgender Herausforderung. In einem Tab sind rd. 600.000 Zeilen an Daten. Diese beinhalten die anonymisierten Kommen- & Gehen-Zeiten aller Mitarbeiter. Ziel ist eine...
  7. Nur eindeutige Werte berechnen aus externer Datei

    in Microsoft Excel Hilfe
    Nur eindeutige Werte berechnen aus externer Datei: Hallo zusammen, ich stehe etwas auf dem Schlauch und hoffe ihr könnt mir weiterhelfen falls es überhaupt möglich ist. Ich habe eine Datei wo die Ergebnisse ausgegeben werden sollen und eine...
  8. Excel 2016 Befehl =Eindeutig

    in Microsoft Excel Hilfe
    Excel 2016 Befehl =Eindeutig: Hallo User, ich habe eine Musterdatei aus dem Internet heruntergeladen, in dieser datei ist der Befehl =Eindeutig in einer Matrixformel. Leider fuktoniert diese Funktion in 2016 nicht. Weiss...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden