Office: Einen CommandButton per VBA einfügen

Hallo, liebe Mituser!

In meinem VBA-Programm generiere ich Tabellenblätter. Diese sollen auch eine bestimmte Befehlsschaltfläche bekommen. Auch per VBA. Der Endnutzer kann sie nicht erzeugen, also soll der Code das tun.

Wie lautet der Befehl zum Einfügen einer Befehlsschaltfläche auf einem Tabellenblatt und wie weist man Namen, Caption und Eigenschaften der Befehlsschaltfläche zu? Und natürlich: wie weist man der Befehlsschaltfläche Ereignis-Code zu?

Vielen lieben Dank für eure wertvollen Tipps
euer
Streethawk68
*Smilie

:)

 

Abend,

die M.E. einfachste Lösung:

kopiere eine Muster-Tabelle mit einem Button aus Steuerelemente. Dabei wird der Code automatisch mit kopiert.

cu, Bernd

 

Ich möchte aber bitte lieber wissen, wie der VBA-Befehl zur Generierung einer Befehlsschaltfläche (CommandButton) lautet.
*Smilie
*wink.gif*

 

Moin, Streethawk68,

ab Excel2002 Zugriff aufs VBA Vertrauen anhaken: Neue Schaltfläche mit zugehörigem Code in Tabellenblatt.

 

HAllo

http://www.herber.de/mailing/129000h.htm
beschreibt das Vorgehen wenn der Button aus der Symbolleiste Formular stammt.
Willst du einen echten CommandButton (ActiveX-Steuerelement) einfügen ist das Vorgehen ähnlich, aber nicht genauso.

Bau dir das mal nach:
Im Codemodul von Tabelle1 liegt der Code der ins neue Blatt soll.
' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub CommandButton1_Click()
MsgBox "Test"
MsgBox "...und noch ein Text"
End Sub


Damit das Ganze auch automatisch angeschubst wird, diesen Code ins CodeModul von DieseArbeitsmappe:
' **********************************************************************
' Modul: DieseArbeitsmappe Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Workbook_NewSheet(ByVal Sh As Object)
Dim CB As Object
Dim sh_New As Object
Dim sh_mit_Code As Object 'Tabelle1. Hier liegt der Code der ins neue Blatt soll.
Dim i As Integer

If Sh.Type <> xlWorksheet Then Exit Sub

Set CB = Sh.OLEObjects.Add("Forms.CommandButton.1") 'Button einfügen

With CB 'Button formatieren
.Object.Caption = "Lalala..."
.Top = 123
.Left = 456
.Height = 40
.Width = 150
End With

Set sh_mit_Code = Application.VBE.ActiveVBProject.VBComponents(Sheets("Tabelle1").CodeName)
Set sh_New = Application.VBE.ActiveVBProject.VBComponents(Sh.CodeName)

With sh_New.CodeModule
.DeleteLines 1, .countoflines 'Alte Zeilen löschen
For i = 1 To sh_mit_Code.CodeModule.countoflines 'Zeilen aus Tabelle1 "abschreiben"
.InsertLines i, sh_mit_Code.CodeModule.Lines(i, 1)
Next
End With

End Sub


ransi

 

Ich hatte jetzt eher an die folgende Lösung gedacht:

ActiveSheet.OLEObjects.Add(ClassType:="Forms.Commandbutton.1", Link:=True, _
DisplayAsIcon:=False, Left:=6, Top:=210, Width:=77, Height:=33). _
Select
Selection.Name = "CM"

Selection.OnAction = "IndivAktivitätenplanDrucken"

Sub IndivAktivitätenplanDrucken()
ActiveSheet.PrintOut
End Sub

Aber da kommt die Fehlermeldung:
"Die OnAction-Eigenschaft des OLEObject-Objektes kann nicht festgelegt werden."

Bin ich nah dran?

Gruß
Streethawk68
*Smilie

 

Morgen,

Nein. Bei OleObjects gibt es kein OnAction, die haben dafür Ereignisse.

OnAction gibt es nur bei den älteren Teilen aus Formular.

Wenn Du dynamisch OleObjects erstellen willst musst Du Code per Code erzeugen und/oder ein Klassenmodul benutzen.

Ransi hat Dir doch bereits gezeigt wie das funktionieren könnte ?

cu, Bernd

 

Ransi, das ist 'voll stark'. *Smilie
Es funktioniert!
Danke.

Der CommandButton dient zum Ausdrucken des neuen Blattes. Er soll aber selbst nicht mitgedruckt werden. Vielleicht lautet das ähnlich wie

ActiveWorkbook.Objects.CB.Visible = False

aber das spricht das CommandButton-Objekt nicht wirklich an. Ideen?
Vielen Dank für eure wertvollen Tipps, euer
Streethawk68

 

HAllo

Das geht so:

With CB 'Button formatieren
.PrintObject = False
.Object.Caption = "Lalala..."
.Top = 123
.Left = 456
.Height = 40
.Width = 150
End With


ransi

 

Sehr gut.
*Smilie

Das hätte ich allein nicht gekonnt. Ich denke, es steht auch nirgendwo in meinen Büchern.