Office: (Office 2010) Email automatisch aus Excel erstellen

Helfe beim Thema Email automatisch aus Excel erstellen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo Mitstreiter, ich habe mal wieder ein Problem. Ich habe eine Excel-Datei, aus der über ein Botton ein CSV-Datei erzeugt wird und in ein... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Andy1962, 23. Februar 2016.

  1. Andy1962 Erfahrener User

    Email automatisch aus Excel erstellen


    Hallo Mitstreiter,

    ich habe mal wieder ein Problem.

    Ich habe eine Excel-Datei, aus der über ein Botton ein CSV-Datei erzeugt wird und in ein Übergabeverzeichnis abgelegt wird.

    Aus dem Übergabeverzeichnis muss diese Datei dann von einem berechtigtem Mitarbeiter diese CSV-Datei dann in ein geschütztes Verzeichnis verschoben werden. Damit nun die/der Mitarbeiter/in nicht jedes mal, wenn sie/er eine Mail an das Team senden muss, habe ich mir gedacht, dass die Mail auch automatisch an das Team gesendet werden könnte.

    Nun habe ich hier folgendes gefunden:

    Application.Dialogs(xlDialogSendMail).Show "test@test.de", "Datei wie gewünscht"

    hierbei wird dann eine Email geöffnet und mit der und auch die Emailadresse richtig angegeben und auch der Betreff eingetragen.

    Jedoch wird auch die Exceldatei in den Anhang gelegt und die Email muss noch selbst abgesendet werden.

    Mein Wunsch wäre nun, dass die Email ohne den Dateianhang automatisch auch versendet wird.

    Ich hoffe ihr könnt mir helfen

    Gruß
    Andreas
     
    Andy1962, 23. Februar 2016
    #1
  2. Beverly
    Beverly Erfahrener User
    Hi Andreas,

    falls bei euch Outlook verwendet wird, hilft dir vielleicht dieser Code:

    Code:
    ' Der Verweis auf die Bibliothek
    ' "Microsoft Outlook 12.0 Object Library"
    ' muss aktiviert sein
    ' ISBN 978-3-86645-209-1 Richtig einsteigen: Excel 2007 VBA-Programmierung
    Sub SendMail()
       Dim olApp As Outlook.Application
       Dim objMail As Outlook.MailItem
       Set olApp = Outlook.Application
       Set objMail = olApp.CreateItem(olMailItem)
       With objMail
          .To = "monika@nospam.xyz; zulfu@nospam.xyz"
          .CC = "irgendwer@nospam.xyz"
          .BCC = "jemand@nospam.xyz"
          .Subject = "Hier steht der Betreff"
          .Body = "Hier steht der Nachrichtentext" & Chr(10) & _
                  "... eine weitere Zeile"
          .ReadReceiptRequested = True
          ' .Display  '<== Anzeige
          .Send       '<== Versand ohne vorherige Anzeige
       End With
       Set olApp = Nothing
       Set objMail = Nothing
    End Sub
    
    
    Bis später,
    Karin
     
    Beverly, 23. Februar 2016
    #2
  3. Andy1962 Erfahrener User
    Hallo Karin,
    Danke erstmal für Deine schnelle Antwort.
    Ich bekomme jedoch die Fehlermeldung: Fehler beim Kompilieren: End Sub erwartet

    der Code sieht wie folgt aus:

    Private Sub CommandButton1_Click()

    Sheets("ASP-DB").Visible = True 'Tabellenblatt einblenden
    Dim newname As String
    newname = "N:\Allgemein\Organisatorische Themen\InfoNet\01_Übergabeverzeichnis\06_Infobox\0018_Ansprechpartner-Datenbank\06_0080_ASP-DB"

    Worksheets("ASP-DB").Copy

    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs Filename:=newname, FileFormat:=xlCSV, Local:=True
    Application.DisplayAlerts = True
    ActiveWorkbook.Close False
    Sheets("ASP-DB").Visible = False 'Tabellenblatt ausblenden

    'Email versenden

    ' Der Verweis auf die Bibliothek
    ' "Microsoft Outlook 12.0 Object Library"
    ' muss aktiviert sein
    ' ISBN 978-3-86645-209-1 Richtig einsteigen: Excel 2007 VBA-Programmierung
    Sub SendMail()
    Dim olApp As Outlook.Application
    Dim objMail As Outlook.MailItem
    Set olApp = Outlook.Application
    Set objMail = olApp.CreateItem(olMailItem)
    With objMail
    .To = "Test@Test.de"

    .Subject = "Ansprechpartnerdatenbank"
    .Body = "Liebes Redaktionsteam," & Chr(10) & _
    "es wurde vom Absender eine neue CSV-Datei erstellt"
    .ReadReceiptRequested = True
    ' .Display '<== Anzeige
    .Send '<== Versand ohne vorherige Anzeige
    End With
    Set olApp = Nothing
    Set objMail = Nothing
    End Sub

    'MsgBox für eine Sekunde einblenden
    Dim objShell As Object
    Set objShell = CreateObject("WScript.Shell")
    objShell.Popup "CSV-Datei wurde gespeichert", 1, "Info"
    Set objShell = Nothing

    End Sub



    'MsgBox "CSV-Datei wurde gespeichert", vbInformation


    '
    Ich hoffe du kannst mir helfen

    Gruß
    Andreas
     
    Andy1962, 23. Februar 2016
    #3
  4. Beverly
    Beverly Erfahrener User

    Email automatisch aus Excel erstellen

    Hi Andreas,

    benutze das Tag für formatierte Codeanzeige wenn dein Code formatiert geschrieben ist (wie in meinem Beitrag), dann lässt er sich besser lesen. Das Tag wird dir oberhalb des Antwortfensters eigneblendet sobald du den Schalter "Erweitert" gedrückt hast.

    Wenn du deinen Code genau anschaust wirst du sehen, dass du 2mal die Zeile End Sub stehen hast.

    Bis später,
    Karin
     
    Beverly, 23. Februar 2016
    #4
  5. Andy1962 Erfahrener User
    Hallo Karin,

    irgendwie verstehe ich nur Bahnhof :-). Ich habe jetzt auch versucht einmal ein Sub End raus zu nehmen, aber die Fehlermeldung bleibt die gleiche.

    Ich hab dir noch mal den Code reingesetzt. Ich bin in VBA aber auch ein absoluter Neuling.

    Code:
    Private Sub CommandButton1_Click()
    
        Sheets("ASP-DB").Visible = True 'Tabellenblatt einblenden
        Dim newname As String
            newname = "N:\Allgemein\Organisatorische Themen\InfoNet\01_Übergabeverzeichnis\06_Infobox\0018_Ansprechpartner-Datenbank\06_0080_ASP-DB"
        
        Worksheets("ASP-DB").Copy
        
        Application.DisplayAlerts = False
        ActiveWorkbook.SaveAs Filename:=newname, FileFormat:=xlCSV, Local:=True
            Application.DisplayAlerts = True
            ActiveWorkbook.Close False
           Sheets("ASP-DB").Visible = False 'Tabellenblatt ausblenden
           
           'Email versenden
           
           ' Der Verweis auf die Bibliothek
    ' "Microsoft Outlook 12.0 Object Library"
    ' muss aktiviert sein
    ' ISBN 978-3-86645-209-1 Richtig einsteigen: Excel 2007 VBA-Programmierung
    Sub SendMail()
       Dim olApp As Outlook.Application
       Dim objMail As Outlook.MailItem
       Set olApp = Outlook.Application
       Set objMail = olApp.CreateItem(olMailItem)
       With objMail
          .To = "test@test.de"
         
          .Subject = "Ansprechpartnerdatenbank"
          .Body = "Liebes Redaktionsteam," & Chr(10) & _
                  "es wurde vom Absender eine neue CSV-Datei erstellt"
          .ReadReceiptRequested = True
          ' .Display  '<== Anzeige
          .Send       '<== Versand ohne vorherige Anzeige
       End With
       Set olApp = Nothing
       Set objMail = Nothing
    End Sub
          
           'MsgBox für eine Sekunde einblenden
    Dim objShell As Object
        Set objShell = CreateObject("WScript.Shell")
        objShell.Popup "CSV-Datei wurde gespeichert", 1, "Info"
        Set objShell = Nothing
    
    End Sub
    
    
    
     
    Andy1962, 23. Februar 2016
    #5
  6. Beverly
    Beverly Erfahrener User
    Hi Andreas,

    jetzt kann man auch klar erkennen wo dein Fehler liegt (das war mir vorhin durch die vermukste :D Schreibweise des Codes gar nicht aufgefallen): du hast 2 Subs ineinander verschachtelt - das geht so nicht. Entweder du schreibst den Code für das Versenden der Mail ohne die beiden Zeilen Sub SendMail() und die dazugehörige Zeile End Sub (also die 1. Zeile mit End Sub direkt vor Dim objShell As Object) oder du schreibst das Versenden der Mail in eine eigene Sub und rufst diese aus der ersten Prozedur auf:

    Code:
    Private Sub CommandButton1_Click()
    
        Sheets("ASP-DB").Visible = True 'Tabellenblatt einblenden
        Dim newname As String
        newname = "N:\Allgemein\Organisatorische Themen\InfoNet\01_Übergabeverzeichnis\06_Infobox\0018_Ansprechpartner-Datenbank\06_0080_ASP-DB"
        
        Worksheets("ASP-DB").Copy
        
        Application.DisplayAlerts = False
        ActiveWorkbook.SaveAs Filename:=newname, FileFormat:=xlCSV, Local:=True
         Application.DisplayAlerts = True
         ActiveWorkbook.Close False
        Sheets("ASP-DB").Visible = False 'Tabellenblatt ausblenden
        
        'Email versenden
        [B][COLOR=#ff0000]SendMail[/COLOR][/B]
        
        'MsgBox für eine Sekunde einblenden
        Dim objShell As Object
        Set objShell = CreateObject("WScript.Shell")
        objShell.Popup "CSV-Datei wurde gespeichert", 1, "Info"
        Set objShell = Nothing
    
    End Sub
    
    ' Der Verweis auf die Bibliothek
    ' "Microsoft Outlook 12.0 Object Library"
    ' muss aktiviert sein
    ' ISBN 978-3-86645-209-1 Richtig einsteigen: Excel 2007 VBA-Programmierung
    Sub SendMail()
       Dim olApp As Outlook.Application
       Dim objMail As Outlook.MailItem
       Set olApp = Outlook.Application
       Set objMail = olApp.CreateItem(olMailItem)
       With objMail
          .To = "test@test.de"
         
          .Subject = "Ansprechpartnerdatenbank"
          .Body = "Liebes Redaktionsteam," & Chr(10) & _
                  "es wurde vom Absender eine neue CSV-Datei erstellt"
          .ReadReceiptRequested = True
          ' .Display  '<== Anzeige
          .Send       '<== Versand ohne vorherige Anzeige
       End With
       Set olApp = Nothing
       Set objMail = Nothing
    End Sub
    
    
    Bis später,
    Karin
     
    Beverly, 23. Februar 2016
    #6
Thema:

Email automatisch aus Excel erstellen

Die Seite wird geladen...
  1. Email automatisch aus Excel erstellen - Similar Threads - Email automatisch Excel

  2. Autom. Email verschieben in Ordner anhand einer Nummer im Betreff

    in Microsoft Outlook Hilfe
    Autom. Email verschieben in Ordner anhand einer Nummer im Betreff: Hallo! Ich würde gerne in Outlook Mails aus der Inbox anhand einer Nummer im Betreff in einen entsprechenden Ordner mit der gleichen Nummer verschieben. Aktuell gibt es im Standard bei "Element...
  3. email automatisch verschiken Von einer WENN Unktion

    in Microsoft Excel Hilfe
    email automatisch verschiken Von einer WENN Unktion: Hallo ich kenne mich was VBA angeht nicht aus! Ich habe das Logo Access toll das von einer Logo Steuerung Werte Abgreift! In der Spalte V Wenn Funktionen die mir Bei bestimten werten dan...
  4. Makro für automatische Email

    in Microsoft Excel Hilfe
    Makro für automatische Email: Hallo zusammen, ich bin in Makros schreiben und machen noch nicht so fit. In diesem Forum kann mir bestimmt jemand weiterhelfen. Ich habe ein Excel Dokument mit ca. 50 Arbeitsblättern. Ich...
  5. Automatisch Email verschicken (If then?)

    in Microsoft Access Hilfe
    Automatisch Email verschicken (If then?): Hallo zusammen, ich starte ein neues Thema, da das im alten nicht mehr passte thematisch: altes Thema: http://www.ms-office-forum.net/forum...=330717&page=5 es handelt sich immer noch um...
  6. Bei gmx online gelöschte Emails löschen sich automatisch im Outlook

    in Microsoft Outlook Hilfe
    Bei gmx online gelöschte Emails löschen sich automatisch im Outlook: Ich benötige Hilfe bezüglich des Löschens von Emails bei gmx bzw den direkten Auswirkungen davon im Outlook. Wenn ich eine Email online lösche, verschwindet diese daraufhin auch in meinem...
  7. Excel Zeilen-Felder in eMail automatisch übertragen

    in Microsoft Excel Hilfe
    Excel Zeilen-Felder in eMail automatisch übertragen: Hallo, ich würde gern aus einer Excel-Liste z.B. die Spalte A Zeile 5 aus Spalte B Zeile 6 und Spalte B Zeile 8 automatisch in eine eMail überträgen, wenn ich auf einen bestimmten Punkt klicke....
  8. Outlook 2016: Beim Klick auf Hyperlinks in Emails wird sofort zum Browser gewechselt

    in Microsoft Outlook Hilfe
    Outlook 2016: Beim Klick auf Hyperlinks in Emails wird sofort zum Browser gewechselt: Hallo Leute! Mich nervt etwas, kann es aber nicht abstellen: Nutze Outlook 2016, beim Klick auf Hyperlinks in Emails wird sofort zum Browser geswitched, um das Linkziel anzuschauen - ich würde...
Schlagworte:

Users found this page by searching for:

  1. excel email generieren

    ,
  2. email aus excel generieren

  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden