Office: (Office 2013) Email nur versenden wenn Inhalt in Bereich

Helfe beim Thema Email nur versenden wenn Inhalt in Bereich in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo Zusammen, in dem unten stehenden Code wird der Bereich A38:M51 per Mail versendet. Leider auch wenn kein Text in dem Bereich eingetragen wird.... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von merkurmedium, 7. Januar 2022.

  1. Email nur versenden wenn Inhalt in Bereich


    Hallo Zusammen,

    in dem unten stehenden Code wird der Bereich A38:M51 per Mail versendet.
    Leider auch wenn kein Text in dem Bereich eingetragen wird.
    Wie muss man den Code ändern damit die Mail nur raus geht wenn auch etwas in dem Bereich eingetragen ist ?

    Code:
    Set olApplication = Nothing
            Set objEMail = Nothing
            Set objWorkbook = Nothing
            Set rng = Nothing
            
            Set rng = Worksheets("Testblatt").Range("A38:M51")
            
            Set olApplication = CreateObject("Outlook.Application")
            
            Set objEMail = olApplication.CreateItem(0)
            
            With objEMail
                
               .to = "XXXXXXXXXXXXXXXXXXXXXXXXX"
                .Subject = "Test"
                
                .HTMLBody = RangetoHTML(rng)
                
                'Call .Attachments.Add(strFilePath)
                
                Call .send
                
            End With
            
            Set olApplication = Nothing
            Set objEMail = Nothing
            Set objWorkbook = Nothing
            Set rng = Nothing
     
    merkurmedium, 7. Januar 2022
    #1
  2. Exl121150 Erfahrener User
    Hallo,

    Code:
    Sub Demo_Program()
       Dim olApplication As Object, objEMail As Object
       Dim rng As Range
      
       Set olApplication = Nothing
       Set objEMail = Nothing
       Set rng = Nothing
      
       Set rng = Worksheets("Testblatt").Range("A38:M51")
       If Not IstBereichLeer(rng) Then
      
          Set olApplication = CreateObject("Outlook.Application")
          Set objEMail = olApplication.CreateItem(0)
        
          With objEMail
            
             .to = "XXXXXXXXXXXXXXXXXXXXXXXXX"
              .Subject = "Test"
              .HTMLBody = RangetoHTML(rng)    '<==== Muss irgendwo codiert sein!
              'Call .Attachments.Add(strFilePath)
              Call .send
            
          End With
        
          Set olApplication = Nothing
          Set objEMail = Nothing
      
       End If
    End Sub
    
    Public Function IstBereichLeer(rngBereich As Range) As Boolean
      Dim Zelle As Range
      IstBereichLeer = True
      For Each Zelle In rngBereich.Cells
        If Not IsEmpty(Zelle.Value) Then
           IstBereichLeer = False
           Exit For
        End If
      Next Zelle
    End Function
    
    
     
    Exl121150, 7. Januar 2022
    #2
    1 Person gefällt das.
  3. Beverly
    Beverly Erfahrener User
    Hi,

    wenn in dem Bereich absolut nichts steht, also auch keine Formeln, dann geht das ganz einfach so:

    Code:
        Set rng = Worksheets("Testblatt").Range("A38:M51")
        If Application.CountA(rng) = 0 Then
            MsgBox "Bereich A38:M51 ist leer"
            Exit Sub
        End If
    


    Email nur versenden wenn Inhalt in Bereich GrußformelEmail nur versenden wenn Inhalt in Bereich Beverly's Excel - Inn
     
    Beverly, 8. Januar 2022
    #3
    1 Person gefällt das.
  4. Email nur versenden wenn Inhalt in Bereich

    Hallo ,

    danke für Eure Hilfe.
    Habe mich für Variante 1 entschieden.

    Schönen Sonntag.
     
    merkurmedium, 9. Januar 2022
    #4
Thema:

Email nur versenden wenn Inhalt in Bereich

Die Seite wird geladen...
  1. Email nur versenden wenn Inhalt in Bereich - Similar Threads - Email versenden Inhalt

  2. per Makro eMail versenden mit Text einfügen

    in Microsoft Excel Hilfe
    per Makro eMail versenden mit Text einfügen: Hallo Guten Morgen, habe folgendes Problem im Makro... es übernimmt den Text nicht in die Email... was ist falsch wer kann mir helfen... schon mal Danke!!!! Sub einzelnes_Blatt_senden() '** Das...
  3. Schaltfläche Email versenden

    in Microsoft Access Hilfe
    Schaltfläche Email versenden: In einem Formular kann man mithilfe einer Schaltfläche den Bericht per Email versenden. Es ist aber "nervig" wenn man die Email-Adressen immer auswählen muss, vor allem wenn man x-Kollegen hat die...
  4. Abfrage als Anhang per Email (VBA) versenden

    in Microsoft Access Hilfe
    Abfrage als Anhang per Email (VBA) versenden: Ich habe diesen Code. Nun möchte ich noch eine Access Abfrage als Anhang (Excel Format) mitsenden. Ich habe den befehl im Access "objEmail.Attachments" gefunden, aber weiss nicht wie ich angeben...
  5. Outlook versende keine emails mehr ??

    in Microsoft Outlook Hilfe
    Outlook versende keine emails mehr ??: Hi, seit dem 02.07.2020 versendet Outlook (MS Office 365 ProPlus Windows) keine Emails mehr von einem meiner Emailkonten sondern speichert diese im Postausgang?? Ich habe in Outlook 12 Email...
  6. Problem beim Versenden eines Anhangs via Word->Freigabe->EMail->Outlook

    in Microsoft Outlook Hilfe
    Problem beim Versenden eines Anhangs via Word->Freigabe->EMail->Outlook: Hallo, ich kann in Word 2016 direkt aus einem von mir bearbeiteten Word-Dokument über Datei->Freigabe->EMail das Dokument als Anhang zu einer Mail versenden. Leider erscheint dann die Mail mit...
  7. Email an alle

    in Microsoft Outlook Hilfe
    Email an alle: Hallo, würde mir bitte jmd. schreiben wie ich eine Email an alle meine Absender im Posteingang verschicken kann? Danke.
  8. versenden emails

    in Microsoft Outlook Hilfe
    versenden emails: Hallo Leute Über mein ehemaligen Anbieter 1und1 hatte ich meine E-Mail Adresse angelegt und mit Outlook zusammen eingerichtet. Es lief alles wunderbar.Ich arbeite gerne mit Outlook Version...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden