Office: Endlosformular "on-the-fly" filtern

Zuerst mal meine Aufgabenstellung:

Aus einer Tabelle mit Mitgliederdaten sollen „on-the-fly“, d.h. bei Eingabe eines Teils des Namens, die Datensätze der Mitglieder gefiltert werden. Basis ist Access aus Microsoft Office 2019 Professional.

Mein Lösungsansatz:

In einem Formular gibt es im Kopf ein ungebundenes Textfeld txt_Name zur Eingabe des Suchstrings.

Im Detailbereich gibt es ein Endlosformular mit den relevanten Mitgliederdaten.


Auf txt_Name greife ich im Change-Ereignis über txt_Name.Text zu um nach jedem Eingabezeichen das Textfeld auszuwerten und die Datensatzquelle zu Filtern.

Mein Problem:

Mit Eingabe eines Zeichens wird der bisherige Inhalt in txt_Name gelöscht. Interessant ist, wenn ich auf das Statement Me.Filter einen Stop setze und danach die Prozedur weiterlaufen lasse, wird das Textfeld txt_Name nicht gelöscht.

Hier der Code:

Code:

Private Sub txt_Name_Change()                   ' Wird beim Eingeben eines Zeichens aufgerufen
Dim Filter As String
Dim Name As String

    Name = Me.txt_Name.Text                     ' Übernehme den aktuellen Text
    Debug.Print "Change: " & Name   

    Filter = "MiName Like '*" & Name & "*'"     ' Filtere die Datenquelle (Teil von MiName = eingegebener Text)

    Me.Filter = Filter                          ' Filter setzen
    Me.FilterOn = (Len(Name) > 0)               ' Filter aktivieren wenn (etwas eingegeben wurde)
End Sub

Hat jemand eine Idee, wie ich das besser machen kann?

 

Moin Ingolf,
als erstes: vermeide, reservierte Wörter (Name, Filter) als Variablennamen zu nehmen, man weiß nie, wie Access das übersetzt
ansonsten versuche doch mal

Code:

Private Sub txt_Name_Change()                   ' Wird beim Eingeben eines Zeichens aufgerufen
 Dim strFilter As String
 
    strFilter = "MiName Like '*" & Me.txt_Name & "*'"    ' Filtere die Datenquelle (Teil von MiName = eingegebener Text)
    Me.Filter = strFilter                                ' Filter setzen
    Me.FilterOn = Me.txt_Name) <> ""                     ' Filter aktivieren wenn (etwas eingegeben wurde)
    Me.txt_Name.SelStart = Len(Me.txt_Name) + 1          ' setzt den Cursor ans Ende der Eingabe
End Sub

Gruß
Doming

 

Danke Doming,
mit zwei Korrekturen funktioniert dein Code.

• im FilterOn Statement ist eine ) zuviel
• beim Zugriff auf txt_Name muss noch noch die Eigenschaft .Text dazu

 

Hallo und guten Morgen,
jetzt habe ich mir die Sache nochmal genauer angesehen.

Der Schlüssel zum Erfolg war das Setzen des Cursors (Eingabemarke) ans Ende des eingegebenen Textes. Dazu nochmals Danke an Doming.

Noch eine kleine Anmerkung: Beim SelStart zählen die Zeichen ab 0, damit das +1 ist nicht nötig (aber auch nicht schädlich).
0 ist der Anfang des Feldes, 1 entspricht hinter dem ersten Zeichen u.s.w.
Sind z.B. 5 Zeichen im Feld enthalten, setzt SelStart = 5 den Cursor hinter das 5te Zeichen.

Mein jetziger Code sieht wie folgt aus:

Code:

Private Sub txt_Name_Change()                  ' Wird beim einbgeben eines Zeichens aufgerufen
Dim strFilter As String
Dim strName As String

    strName = Me.txt_Name.Text                 ' Übernehme den aktuellen Text
    strFilter = "MiName Like '*" & strName & "*'"  ' Filtere die Datenquelle (Teil von MiName = eingegebener Text)

    Me.Filter = strFilter                       ' Filter setzen
    Me.FilterOn = (Len(strName) > 0)            ' Filter aktivieren wenn (etwas eingegeben wurde)
    Me.txt_Name.SelStart = Len(strName)         ' Cursor ans Ende des Textes setzen
End Sub