Office: (Office 2010) Erstellung eines eigenen Kontextmenü für ein Diagramm

Kossy · 27. Juni 2011

Hallo !

Danke für den Code Ransi.

Ich habe ihn jetzt wiefolgt verwendet, allerdings geschah auch hier nicht das gewünschte Resultat:

Code:

Private Sub BubbleChartPortfolio_MouseDown(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)

If Button = 2 Then

Dim intZaehler As Integer
Dim cmdSchalter As CommandBarButton

Dim myCB As CommandBarPopup

Set myCB = Application.CommandBars.FindControl(ID:=30022)

For intZaehler = myCB.CommandBar.Controls.Count To 1 Step -1

myCB.CommandBar.Controls(intZaehler).delete

Next intZaehler

Set cmdSchalter = myCB.CommandBar.Controls.Add

With cmdSchalter

.Caption = "Erstes Feld"
.Caption = "Zweites Feld"

End With

Set cmdSchalter = Nothing

End If

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Danke nochmal für die Hilfe !

Grüße
Kossy

Beverly · 27. Juni 2011

\@Ransi,

ich habe schon mal irgendwo gelesen, dass, wie Kossy auch die Vermutung geäußert hat, sich das Kontextmenü aus Schaltern von mehreren Menüs zusammensetzt. Wennn man sich die Schalter der ID 30022 auflisten lässt, sind nur "Trendlinie hinzufügen" und "Daten auswählen" von den Schaltern enthalten, die tatsächlich im Kontextmenü vorkommen. Aber selbst wenn man versucht, die Schalter der ID 30022 zu löschen oder neue hinzuzufügen, passiert nichts - weder in Excel2010 noch in Excel2003.

@Kossy,

was willst du denn eigentlich erreichen - vielleicht kann man es ja auf andere Weise lösen.

Kossy · 27. Juni 2011

Hallo Beverly!

ich möchte ein eigene Kontextmenü schrieben bzw. für den Benutzer sichtbar machen, wenn dieser mit der rechten Maustaste auf eine der Blasen im Blasendiagramm klickt. Über dieses individuelle Kontextmenü soll er dann weiter mit einem Programm interagieren können.

Schau Dir bitte nochmal das Bild in meinem vorletzten Post an, dort ist das betroffene Excel Kontextmenü zu sehen.

Grüße
Kossy

mumpel · 9. Februar 2021

Hallo!

Ich befürchte dass man da nichts machen kann. Aber hatten wir nicht vor kurzem erst einen ähnlichen Fall?

von ransi

... aber in Excel2010 habe ich noch nie ein Kontextmenu erstellt.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In Excel 2010 hat man auch zwei Möglichkeiten. Per VBA auf die altbekannte Weise (funktioniert noch immer) oder per RibbonX.

Gruß, René

Beverly · 28. Juni 2011

Hi Kossy,

zu dem besagten Kontextmenü habe ich bereits ausführlich meine Meinung geäußert, die ja von René auch bestätigt wurde.
Ich würde an deiner Stelle beim Öffnen der Arbeitsmappe ein eigenens Kontextmenü erstellen und dieses bei Einfachklick auf den Datenpunkt bzw. Datenreihe anzeigen lassen - dann musst du keins der vorhandenen (und nicht manupulierbaren) Kontextmenüs verwenden.

Kossy · 28. Juni 2011

Hallo Beverly !

Meinst Du mit einem eigenen Kontextmenü ein kleines Formular, dass aussieht wie ein Kontextmenü und jeweils an den verschiedenen Blasen per Mausklick aufgerufen und angezeigt wird oder meintest Du etwas anderes?

mfg
Kossy

Beverly · 28. Juni 2011

Hi Kossy,

nein, ich meine ein eigenes Kontextmenü - andernfalls hätte ich geschrieben, dass ich ein UserForm oder etwas anderes meine.

Im Codemodul DieseArbeitsmappe diesen Code:
Code:

Option Explicit

Private Sub Workbook_Open()
Dim cbLeiste As CommandBar
On Error Resume Next
Set cbLeiste = Application.CommandBars.Add(Name:="Anzeige", Position:=msoBarPopup)
On Error GoTo 0
If Not cbLeiste Is Nothing Then
With cbLeiste
With .Controls.Add
.OnAction = "ausfuehren1"
.Caption = "Schalter 1"
End With
With .Controls.Add
.OnAction = "ausfuehren2"
.Caption = "Schalter 2"
End With
End With
End If
DiaInit
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
MenueLoeschen
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

In einem allgemeinen Modul diesen Code:
Code:

Option Explicit
Dim arrDiagramme() As New clsDiagramm

Sub DiaInit()
Dim chrDiagramm As ChartObject
Dim intDiagramm As Integer
intDiagramm = 1
ReDim arrDiagramme(1 To Worksheets("Tabelle2").ChartObjects.Count) ' Tabellenname anpassen
For Each chrDiagramm In Worksheets("Tabelle2").ChartObjects
Set arrDiagramme(intDiagramm).chrDia = chrDiagramm.Chart
intDiagramm = intDiagramm + 1
Next chrDiagramm
End Sub

Sub ausfuehren1()
MsgBox "Schalter 1 wurde gedrückt"
End Sub

Sub ausfuehren2()
MsgBox "Schalter 2 wurde gedrückt"
End Sub

Sub MenueLoeschen()
Application.CommandBars("Anzeige").Delete
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Und im Klassenmodul clsDiagramm diesen Code:
Code:

Option Explicit
Public WithEvents chrDia As Chart

Private Sub chrDia_Mousedown(ByVal Button As Long, ByVal Shift As Long, ByVal x As Long, ByVal y As Long)
Dim IDNum As Long
Dim a As Long
Dim b As Long
chrDia.GetChartElement x, y, IDNum, a, b
On Error Resume Next
If IDNum = 3 Then
Application.CommandBars("Anzeige").ShowPopup
End If
On Error GoTo 0
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Kossy · 28. Juni 2011

Hi Beverly !

Hab vielen Dank für die Codierung !

Grüße
Kossy

Office: (Office 2010) Erstellung eines eigenen Kontextmenü für ein Diagramm

Erstellung eines eigenen Kontextmenü für ein Diagramm

Erstellung eines eigenen Kontextmenü für ein Diagramm

Erstellung eines eigenen Kontextmenü für ein Diagramm

Erstellung eines eigenen Kontextmenü für ein Diagramm

Erstellung eines eigenen Kontextmenü für ein Diagramm - Similar Threads - Erstellung Kontextmenü Diagramm

Grafik durch bedingte Formatierung erstellen

Kamera in Excel einbinden und per vba Fotos erstellen

Dynamischen QR-Code erstellen

Zellen-Eintrag in Zellen-Name

Auswertung aus mehreren Registern erstellen (nur die Gelbmarkierten oder mit Datum von akt. Woche)

2 Benutzerdefiniertes Inhaltsverzeichnis erstellen

Kontextmenü mit VBA erstellen