Office: Excel 2010 Externe Daten Quellen über VBA Makro aktualisieren

Hallo zusammen,

ich habe ein kleines Problem mit dem importieren von Daten aus einer .csv Datei.

Mit dem Marko:

Code:

Sub Daten_importieren()
'
' Daten_importieren Makro
'
    ActiveWorkbook.RefreshAll
End Sub

will ich die Daten aus der .csv Datei in mein Excel Sheet importieren. Klappt auch wunderbar, nur leider muss ich immernoch von hand den Speicherpfad der Datei auswählen und auf improtieren klicken.

Die Datei heißt immer gleich und liegt immer am selben Ort, da sollte es doch möglich sein, das ins Marko mit aufzunehmen oder?

Nur wie ist die Frage?

Vielen Dank für eure Hilfe.

Gruß

 

Hallo,

1) an die Stelle Deines bisherigen Makros die beiden folgenden Makros kopieren
2) anstelle von "I:\Buchung.csv" Deinen Pfad zur CSV-Datei eingeben
3) falls die linke obere Zelle für den Importbereich im aktiven Arbeitsblatt nicht die Zelle A1 ist, muss auch diese abgeändert werden.
4) Ferner musst Du das Array, das der Eigenschaft ".TextFileColumnDataTypes" zugewiesen wird, an Deine Spalten der Importdatei anpassen.
5) Beim erstmaligen Import der Daten aus der CSV-Datei ins aktive Arbeitsblatt das Makro "Import_CSV_Daten" aufrufen.
6) Bei weiteren Importen der CSV-Datei in dieses Arbeitsblatt (Refreshing) das Makro "CSV_Import_aktualisieren" aufrufen.

Code:

Option Explicit

Const Pfad_Datei$ = "[COLOR=#0000cd]I:\Buchung.csv[/COLOR]"
Const LinkeObereEcke$ = "[COLOR=#0000cd]A1[/COLOR]"

Public Sub Import_CSV_Daten()

  With ActiveSheet
  
    .Cells.Clear                               'Alle Zellen des aktiven Arbeitsblattes werden gelöscht
    
    With .QueryTables.Add(Connection:="TEXT;" & Pfad_Datei$, Destination:=Range(LinkeObereEcke$))
      .Name = "Buchungsbereich"                'Name des Bereiches
      .FieldNames = True                       'Feldbezeichner sind enthalten
      .RowNumbers = False                      'Keine Zeilennummern in der 1. Spalte
      .FillAdjacentFormulas = False            'Eventuell angrenzende Formeln werden nicht aktualisiert
      .PreserveFormatting = True               'Feldformatierung bleibt erhalten
      .RefreshOnFileOpen = False               'Beim Öffnen der Arbeitsmappe wird keine automatischer Import ausgeführt
      .RefreshStyle = xlInsertDeleteCells      'Hinzufügen/Löschen von Zellen für den benötigten Bereich
      .SavePassword = False
      .SaveData = True                         'Die Daten werden zusammen mit dem Bericht gespeichert
      .AdjustColumnWidth = True                'Feldbreite automatisch anpassen
      .RefreshPeriod = 0                       'Autom. Aktualisierungen sind deaktiviert
      .TextFilePromptOnRefresh = False         'Keine Angabe des Pfades/Dateinamens im Dateidialog
      .TextFilePlatform = 1252
      .TextFileStartRow = 1                    'Zeilen-Nr. in der sich die 1.Datenzeile befindet
      .TextFileParseType = xlDelimited         'Felder sind Zeichen-getrennt (keine festen Feldbreiten)
      .TextFileTextQualifier = xlTextQualifierDoubleQuote 'Doppelte Anführungszeichen als Textfeldkenner
      .TextFileConsecutiveDelimiter = False    'Aufeinanderfolgende Trennzeichen trennen leere Felder!
      .TextFileTabDelimiter = True             'Felder sind Tabulator-getrennt
      .TextFileSemicolonDelimiter = True       'Felder sind Strichtpunkt-getrennt
      .TextFileCommaDelimiter = False          'Felder sind nicht Komma-getrennt
      .TextFileSpaceDelimiter = False          'Felder sind nicht Leerzeichen-getrennt
      '
      'Import von Feldern/Spalten: 1=xlGeneralFormat, 2=xlTextFormat, 9=xlSkipColumn
      'Für jedes Feld/Spalte ist die Angabe einer dieser 3 Zahlen notwendig --> Anpassung an aktuelle Importdatei !!!
      .TextFileColumnDataTypes = Array(1, 1, 2, 1, 1, 1, 9, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, _
                                       1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 9)
      '                                 
      .TextFileTrailingMinusNumbers = True     'Zahlen, die mit "-" beginnen, werden als neg.Zahlen importiert
      .Refresh BackgroundQuery:=False          'Importaktualisierung erfolgt nicht im Hintergrund
    End With
  End With
    
End Sub

Public Sub CSV_Import_aktualisieren()

   With ActiveSheet.QueryTables
      .Item(1).Refresh
   End With
   
End Sub

 

Vielen Dank, klappt wunderbar.

Super Anleitung :)