Office: Excel Datei über Makro importieren

Hallo zusammen,

ich will eine Excel-Datei über VBA importieren.
Problem an der Sache ist, dass sich der Name der Datei ändert.
Die Datei wird einmal am Tag generiert und mit Datum und Uhrzeitstempel versehen. Das Datum bekäme man ja noch gelöst, aber bei der Uhrzeit unmöglich.

Kann mir jemand sagen, wie ich die Datei trotzdem automatisch über VBA importiert bekomme?

Der Name der Datei ist bspw.

CN_SNV_LU_BSP_SNV_20131022082051.csv

Ich würde gerne das Datum noch vorgeben, da es die Datei nur einmal am Tag und mit diesem Datumsstempel gibt. Die Uhrzeit jedoch offen bleibt.
Also brauche ich ein Befehl der sagt, öffne die Datei die wie folgt beginnt:

CN_SNV_LU_BSP_SNV_20131022


Ich habe folgendes Makro als Vorlage und so gehe ich normalerweise vor, wenn ich den Namen der Datei kenne.

Code:

Sub Anteil_importieren() 

    Dim ReportName As String 
    
    Sheets("Kontrolle Anteil").Select 
    Columns("A:AA").Select 
    Selection.ClearContents 
    ReportName = "J:\XYZ\ABC\NAME DER DATEI.csv" 
    Workbooks.Open Filename:=ReportName, UpdateLinks:=0 
    Columns("A:I").Select 
    Selection.Copy 
    Windows("_Kontrolle Anteil.xlsm").Activate 
    Sheets("Kontrolle Anteil").Select 
    Range("A1").Select 
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False 
    Application.CutCopyMode = False 
    Windows ("NAME DER DATEI.csv").Activate 
    ActiveWorkbook.Close 
    Windows("_Kontrolle Anteil.xlsm").Activate 
    Sheets("Übersicht").Select 
        
End Sub 

Kann mir bei dem Problem jemand weiterhelfen?

Vorab schon einmal vielen Dank
Martin

 

Hallo Martin,

anstelle der 1. blauen Zeile fügst Du Folgendes ein:
Reportname = Dir("J:\XYZ\ABC\CN_SNV_LU_BSP_SNV_" & Format(Now(),"YYYYMMDD") & "*.csv")
und anstelle der 2. blauen Zeile fügst Du diese VBA-Anweisung ein:
Windows(Reportname).Activate

 

Vielen Dank für die Hilfe.
Leider bekomme ich an dieser Stelle eine Fehlermeldung
Also direkt nach der ersten blauen Zeile.

 

Hi Martin,

versuche es mal nach diesem Prinzip:

Code:

Sub Anteil_importieren()
   Dim strPfad As String
   Dim strDatei As String
   strPfad = "J:\XYZ\ABC\"
   Sheets("Kontrolle Anteil").Columns("A:AA").ClearContents
   strDatei = Dir(strPfad & "*.csv")
   Do While strDatei <> ""
      If InStr(strDatei, "CN_SNV_LU_BSP_SNV_20131022") > 0 Then
         Workbooks.Open Filename:=strPfad & strFile
         Columns("A:I").Copy
         Workbooks("_Kontrolle Anteil.xlsm").Sheets("Kontrolle Anteil").Range("A1").PasteSpecial _
            Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
         Workbooks(strDatei).Close
         Exit Do
      End If
      strDatei = Dir()
   Loop
End Sub

Bis später,
Karin

 

Hallo Martin,

ich hatte leider übersehen, dass die Dir()-Funktion nur den Dateinamen liefert und nicht auch den Dateipfad. Deswegen versuchte das Makro die Datei ohne Pfad zu öffnen, was natürlich fehl schlagen musste.
Nachfolgend nochmals das Makro und zwar diesmal ohne den überflüssigen Selects des Makrorecorders:

Code:

Sub Anteil_importieren()
  '
  Dim Pfad As String, ReportName As String
  Dim Blatt As String, Mappe As String
  '
  Blatt$ = "Kontrolle Anteil"
  Mappe$ = ActiveWorkbook.Name
  Sheets(Blatt$).Columns("A:AA").ClearContents
  '
  Pfad$ = "J:\XYZ\ABC\"
  ReportName$ = "CN_SNV_LU_BSP_SNV_" & Format(Now(), "YYYYMMDD") & "*.csv"
  ReportName$ = Dir(Pfad$ & ReportName$, vbNormal)
  Workbooks.Open Filename:=Pfad$ & ReportName$
  '
  Columns("A:I").Copy
  Workbooks(Mappe$).Sheets(Blatt$).Range("A1").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
  Application.CutCopyMode = False
  '
  ActiveWorkbook.Close
  Sheets("Übersicht").Activate
  '
End Sub

@Karin: Dich hat leider auch (so wie mich) der Fehlerteufel beim Open-Befehl verfolgt: Es müsste wohl "strDatei" und nicht "strFile" heißen bei Dir.

 

@Anton,

ja, an dieser Stelle muss es heißen

Code:

Workbooks.Open Filename:=strPfad & [COLOR=#ff0000]strDatei[/COLOR]

Ändert aber nichts am Codeablauf.

Übrigens ist bei deinem Code Bedingung, dass die Uhrzeit bekannt ist. Außerdem steht die Uhrzeit hinter dem Datum im Dateinamen und nicht davor.

Bis später,
Karin

 

Hallo Karin,

der VBA-Ausdruck:
Format(Now(),"YYYYMMDD")
den ich verwendete, liefert zB. am heutigen Tag (das ist der 25.10.2013)
den Stringwert "20131025".

Genau das war ja gewünscht vom User dobby110, dass ein vom heutigen Tag abhängiges Stringelement in diesem Format im Dateinamen enthalten sein soll und der Code genau diesen Dateinamen finden soll.

 

Hallo nochmal.

Der letzte Code funktioniert.
Jetzt ist nur ein neues Problem aufgetaucht. Und zwar handelt es sich ja um eine .csv Datei.
Wenn ich diese importiere, schreibt er mir alles in Spalte A.

Ich hab auch noch einen Code, mit dem ich die .csv importieren kann. Aber dann hab ich wieder das Problem wegen der Uhrzeit.