Office: excel Funktion in Tabellenzelle aufufen

Hab hier eine schöne Funktion, bin scheinbar zu do.. diese anzuwenden.

Funktion in Modul und in Tabellenblatt DatumsInfo() ist was nach dem else kommt. Aber davor, wie rufe ich da die Funktion auf?

Hier die Funktion

Code:

Function DatumsInfo(Optional datum As Date, _
    Optional was As String) As String
  If datum = 0 Then datum = Date
  Select Case UCase(was)
  Case "L"      'langes Datumsformat (z.B. Montag, 05. Jänner 2004)
    DatumsInfo = Format(datum, "long date")
  Case "KW"     'Kalenderwoche
    If Format(datum, "DDD") = "Mo" Then datum = datum + 1
    DatumsInfo = Format(datum, "ww", vbMonday, vbFirstFourDays)
  Case "MM"     'Monatskürzel
    DatumsInfo = Format(datum, "MMM")
  Case "MN"     'Monatsname ausgeschrieben
    DatumsInfo = Format(datum, "MMMM")
  Case "MZ"     'Monatszahl
    DatumsInfo = Format(datum, "M")
  Case "JT"     'der wievielte Tag des Jahres?
    DatumsInfo = Format(datum, "y")
  Case "Q"      'Quartal
    DatumsInfo = Format(datum, "q")
  Case "WN"     'Wochentag ausgeschrieben
    DatumsInfo = Format(datum, "DDDD")
  Case "WW"     'Wochentags-Kürzel
    DatumsInfo = Format(datum, "DDD")
  Case "WZ"     'Wochentagszahl (1=Mo...7=So)
    DatumsInfo = WeekDay(datum, vbMonday)
  Case Else
    DatumsInfo = Format(datum, "long date") & vbCr & _
      " ( Quartal " & Format(datum, "q") & _
      ", KW " & DatumsInfo(datum, "kw") & _
      ", Tag " & Format(datum, "y") & " des Jahres )"
  End Select
End Function

Gruß jagga007

 

Hallo,

meinst Du die Funktion in einer Tabelle verwenden? Dann ginge es z.B. so:

=DatumsInfo()
=DatumsInfo(;"WW")
=DatumsInfo(;"KW")
=DatumsInfo(A6;"KW")
=DatumsInfo(HEUTE()+10;"KW")

Gruß

 

Ja Super , Danke.

Hab's verstanden.

Gruß jagg007