Office: (Office 365) Excel - ganze Zeile in anderes Blatt verschieben, wenn Bedingung erfüllt

Hallo zusammen

Ich bin leider ein absoluter Excel-Banause und habe folgendes Problem:

Ich habe eine Materialliste für Baugespanne. Dabei möchte ich mit zwei Blättern arbeiten (Baugespanne montiert und Baugespanne demontiert). Sobald im Blatt "Baugespanne montiert" in der Spalte "F" ein Datum eingetragen wird, soll diese Zeile automatisch ins Blatt "Baugespanne demontiert" verschoben werden. Im 3. Blatt habe ich dann die ganze Auswertung für den Lagerbestand.

Funktioniert das? Kriegt man das hin?

Danke für eure Mithilfe.

Liebe Grüsse
Ben

 

Hi Ben,

dein angepasster Code im Codemodul der Tabelle "Bauspanne montiert":

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim lngErste As Long
    Dim varZellen As Variant
    If Target.Column = 4 And Target.Row > 3 Then  '<== ?????
        If UCase(Target) = "JA" Then
            varZellen = Range(Cells(Target.Row, 1), Cells(Target.Row, 4))
            With Worksheets("Abgerechnet")
                lngErste = IIf(IsEmpty(.Cells(.Rows.Count, 1)), .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count) + 1
                .Cells(lngErste, 1).Resize(1, 4) = varZellen
                Application.EnableEvents = False
                Rows(Target.Row).Delete
                Application.EnableEvents = True
            End With
        End If
    ' Code ergänzt für den Übertrage in Tabelle "Baugespanne demontiert"
    ElseIf Target.Cells(1).Column = 6 And Target.Cells(1).Row > 2 Then
        If IsDate(Target.Cells(1)) Then
            varZellen = Range(Cells(Target.Cells(1).Row, 1), Cells(Target.Cells(1).Row, 16))
            With Worksheets("Baugespanne demontiert")
                lngErste = IIf(IsEmpty(.Cells(.Rows.Count, 1)), .Cells(.Rows.Count, 1).End(xlUp).Row, .Rows.Count) + 1
                .Cells(lngErste, 1).Resize(1, 16) = varZellen
                Application.EnableEvents = False
                Rows(Target.Row).Delete
                Application.EnableEvents = True
            End With
        End If
    End If
End Sub

Frage: weshalb steht in deinem Codeteil Target.Row > 3 ? In Zeile 3 stehen doch bereits Daten, die mit deinem Teil bearbeitet werden sollen - oder sehe ich das falsch? M.E. müsste dor ebenfalls > 2 oder zumindest >= 3 stehen

---

 

Perfekt, herzlichen Dank! Funktioniert. Habe etwas versucht mit einem anderen Code, darum stand da noch 3.
DANKE nochmals.