Office: Excel Hyperlink automatisch generieren

Schönen guten Tag Excel-Experten,

ich bin neu hier im Forum und meine Excel Kenntnisse beziehen sich auf normale Kalkulation .

Ich habe mir eine Tabelle gebaut, in der ich alle meine Anmeldungen für Bauarbeiten aufliste.
Diese Anmeldungen werden bei uns im System online erzeugt und bekommen eine eigene ID zugeordnet (z.B. 23456). Jede Anmeldung bekommt dadurch auch einen eigenen Link (z.B. bbp.anmeldungen.com/edit/23456).

Wenn ich jetzt in meine Tabelle in der Spalte B (ID Anmeldung) die 23456 eingebe, gibt es evtl. die Möglichkeit, das Excel mit Hilfe einer Formel, automatisch daraus einen Link erstellt? Also immer vorweg die Adresse bbp.anmeldungen.com/edit/ + der jeweiligen ID der Anmeldung die in der entsprechenden Zeile eingegeben wird?

Ich hoffe, ich konnte mein Anliegen einigermaßen verständlich erklären. Leider habe ich dazu nichts gefunden.

Vielen Dank für Eure Mühe und Hilfe.

 

Hallo,

wenn du zB. in B2 die Zahl 23456 eingibst und du möchtest in Spalte H, also in H2, damit den Hyperlink bilden, dann lautet die Formel in H2: =HYPERLINK("bbp.anmeldungen.com/edit/"& B2)
Der erzeugte Hyperlink in H2 lautet: bbp.anmeldungen.com/edit/23456

 

Hi,

wenn du den Link in derselben Zelle haben möchtest, geht das nur per VBA - mit einer Formel kann der Link nur in einer anderen Zelle erstellt werden.

---

 

Hallo, vielen Dank für Eure schnelle Hilfe. Elegant wäre natürlich die zweite Lösung .
Wie würde die Lösung dabei aussehen, wenn ich fragen darf?

Vielen Dank.

 

Hi,

Karin wird Dir bestimmt den Code dazu liefern - aber ich persönlich würde die Variante mit der zusätzlichen Linkspalte bevorzugen, weil übersichtlicher (und eben auch einfacher).

 

Hi,

Rechtsklick auf den Tabellenreiter -> Code anzeigen -> folgenden Code in das rechte (obere) Codefenster kopieren:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    ' Eintrag erfolgt nur in 1 Zelle
    If Target.Count = 1 Then
        ' Eintrag erfolgt in Spalte B
        If Target.Column = 2 Then
            ' Zellinhalt wird nicht mittels Entf.-Taste gelöscht
            If Target.Value <> "" Then
                ' falls bereits ein Link vorhanden dann diesen entfernen
                If Target.Hyperlinks.Count > 0 Then Target.Hyperlinks(1).Delete
                ' Reaktion auf Eingabe abschalten
                Application.EnableEvents = False
                ' Hyperlinkt eintragen
                Target.Hyperlinks.Add anchor:=Target, Address:="bbp.anmeldungen.com/edit/" & Target.Value
                ' Reaktion auf Eingabe einschalten
                Application.EnableEvents = True
            End If
        End If
    End If
End Sub

Nicht vergessen, die Mappe im Format XLSM (Arbeitsmappe mit Makros) abzuspeichern.

---

 

Moin,
Antons Formel hat neben der Einfachheit noch einen weiteren Vorteil: Manche Firmen lassen aus Sicherheitsgründen leider kein VBA zu. Das Problem wäre mit der Formel umgangen.
Grüße

 

Guten Morgen zusammen,

vielen vielen Dank für Deine Mühe mit dem Code.
Leider bekomme ich folgende Fehlermeldung angeziegt.



Freundliche Grüße und einen guten Start in den Tag

 

Hi,

leider kann ich das Codemodul bei dir nicht sehen, sodass ich nicht nachvollziehen kann, wo das Problem ist, aber die Fehlermeldung bedeutet, dass du außerhelb des Prozedurgerüsts noch irgend etwas anderes stehen hast. Die angehängte Mappe zeigt dir, wie es aussehen muss.

---

 

Hallo Karin,
Vielen Dank für Deine Hilfe. Mit deiner Datei und den Code draus kopieren hat es wunderbar geklappt. Genau so, wie ich mir das gewünscht habe.

Vielen lieben Dank.

 

Hallo Karin, eine Frage nochmal zu Deinem Code. (ist mir echt unangenehm, wirkt wie den kleinen Finger reichen und daraufhin die ganze Hand nehmen)

Ich habe es selber versucht, bin aber natürlich kläglich gescheitert.
Wäre es möglich, das ganze auch in Spalte K umzusetzen, nur mit einem etwas anderen Link?

 

Hi,

kein Problem. Du musst nur im Code entsprechend festlegen, welche Linkadresse in welcher Spalte verwendet werden soll, und das kannst du in einer If-Verzweigung und einer String-Variablen realisieren. Sonst bleibt der Code fast so wie er war, nur musst du eben anstelle der festen Linkadresse die Variable verwenden:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim strLink As String
    ' Eintrag erfolgt nur in 1 Zelle
    If Target.Count = 1 Then
        ' Eintrag erfolgt in Spalte B
        If Target.Column = 2 Then
            strLink = "bbp.anmeldungen.com/edit/"
        ' Eintrag erfolgt in Spalte K
        ElseIf Target.Column = 11 Then
            strLink = "bbp.anmeldungen.com/edit55/" '<== hier die Zieladresse für Spalte K
        End If
        ' Zellinhalt wird nicht mittels Entf.-Taste gelöscht
        If Target.Value <> "" Then
            ' falls bereits ein Link vorhanden dann diesen entfernen
            If Target.Hyperlinks.Count > 0 Then Target.Hyperlinks(1).Delete
            ' Reaktion auf Eingabe abschalten
            Application.EnableEvents = False
            ' Hyperlinkt eintragen
            Target.Hyperlinks.Add anchor:=Target, Address:=strLink & Target.Value  '<== mit variabler Linkadresse
            ' Reaktion auf Eingabe einschalten
            Application.EnableEvents = True
        End If
    End If
End Sub

---

 

Hi,

ich habe gerade festgestellt, dass der Link auch in den anderen Spalten erstellt wird - also vergiss bitte den Code aus dem vorhergehenden Beitrag. So sollte es aber funktionieren:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
    ' Eintrag erfolgt nur in 1 Zelle
    If Target.Count = 1 Then
        ' Eintrag erfolgt in Spalte B
        If Target.Column = 2 Then
            ' Zellinhalt wird nicht mittels Entf.-Taste gelöscht, deshalb Function aufrufen
            If Target.Value <> "" Then Eintrag 2, Target, "bbp.anmeldungen.com/edit/"
        ' Eintrag erfolgt in Spalte K
        ElseIf Target.Column = 11 Then
            ' Zellinhalt wird nicht mittels Entf.-Taste gelöscht, deshalb Function aufrufen
            If Target.Value <> "" Then Eintrag 11, Target, "bbp.anmeldungen.com/edit55/"  '<== hier die Zieladresse für Spalte K
        End If
    End If
End Sub

Private Function Eintrag(intSpalte As Integer, rngZelle As Range, strLink As String)
    ' Reaktion auf Eingabe abschalten
    Application.EnableEvents = False
    ' falls bereits ein Link vorhanden dann diesen entfernen
    If rngZelle.Hyperlinks.Count > 0 Then rngZelle.Hyperlinks(1).Delete
    ' Hyperlinkt eintragen
    rngZelle.Hyperlinks.Add anchor:=rngZelle, Address:=strLink & rngZelle.Value
    ' Reaktion auf Eingabe einschalten
    Application.EnableEvents = True
End Function

Das eigentliche Erstellen des Links habe ich in eine Function ausgelagert, da sie ja für beide Spalten gleich ist, nur eben die Linkadresse unerschiedlich. Es wird die Spaltennummer, die Zelle und die Linkadresse an die Function übergeben.

---

 

Guten Morgen Karin,

der zweite Code funktioniert perfekt. Vielen Dank für Deine schnelle Hilfe.
Wünsche ein schönes Wochenende.