Office: Excel:Mac 2008: Summenbildung nach Monat und Textteil

Hallo,

Eure Hilfe ist mal wieder nötig.
Ich habe eine Tabelle mit Ausgaben verschiedener Art und an Tagen übers ganze Jahr verteilt. Die Ausgabenarten sind so benannt, dass verschiedene Gruppen gebildet werden können, zB Haus Strom, Haus Gas, Haus Wasser, VW Versicherung, VW Steuer, VW Tanken etc.
Wie kann ich jetzt für einzelne Monate Summen bilden nach den unterschiedlichen Gruppen Haus, VW...?

Danke schon mal.

Zum besseren Verständnis hänge ich eine Beispieldatei an

 

Hallo!

Stehen "Haus" und "VW" immer am Anfang? Dann so:

	A	B	C	D	E	F
1	Datum	Ausgabe	Grund		Monat	1
2	25.01.2010	101	VW gfr		Haus	207
3	26.01.2010	102	VW gfr		VW	203
4	27.01.2010	103	Haus lkj
5	28.01.2010	104	Haus lkj
6	29.01.2010	105	grgt
7	30.01.2010	106	rth
8	31.01.2010	107	hth
9	01.02.2010	108	VW gfr
10	02.02.2010	109	Haus lkj

Zelle	Formel
F2	=SUMMENPRODUKT((MONAT(A$2:A$99)=F$1)*(LINKS(C$2:C$99;LÄNGE(E2))=E2)*B$2:B$99)
F3	=SUMMENPRODUKT((MONAT(A$2:A$99)=F$1)*(LINKS(C$2:C$99;LÄNGE(E3))=E3)*B$2:B$99)

Oder du machst dir eine Hilfsspalte, in der du die Kategorie "Haus" oder "VW" ermittelst, und wertest es dann mit einer Pivot-Tabelle aus.

 

Hallo schatzi,

funktioniert super. Das mit der Pivotabelle probiere ich auch noch aus. Darin bin ich noch unerfahren.

Vielen Dank und herzliche Grüße

 

Hallo!

Für die PT brauchst du wie gesagt noch einen Hilfsspalte, in der die Kategorie ermittelt wird:

	A	B	C	D	E	F	G
1	Datum	Ausgabe	Grund	Hilfe			Kategorien
2	25.01.2010	101	VW gfr	VW			Haus
3	26.01.2010	102	VW gfr	VW			VW
4	27.01.2010	103	Haus lkj	Haus
5	28.01.2010	104	Haus lkj	Haus
6	29.01.2010	105	grgt	#NV
7	30.01.2010	106	rth	#NV
8	31.01.2010	107	hth	#NV
9	01.02.2010	108	VW gfr	VW
10	02.02.2010	109	Haus lkj	Haus

Zelle	Formel
D2	=VERWEIS(WAHR;FINDEN(G$2:G$3;C2)=1;G$2:G$3)
D3	=VERWEIS(WAHR;FINDEN(G$2:G$3;C3)=1;G$2:G$3)
D4	=VERWEIS(WAHR;FINDEN(G$2:G$3;C4)=1;G$2:G$3)
D5	=VERWEIS(WAHR;FINDEN(G$2:G$3;C5)=1;G$2:G$3)
D6	=VERWEIS(WAHR;FINDEN(G$2:G$3;C6)=1;G$2:G$3)
D7	=VERWEIS(WAHR;FINDEN(G$2:G$3;C7)=1;G$2:G$3)
D8	=VERWEIS(WAHR;FINDEN(G$2:G$3;C8)=1;G$2:G$3)
D9	=VERWEIS(WAHR;FINDEN(G$2:G$3;C9)=1;G$2:G$3)
D10	=VERWEIS(WAHR;FINDEN(G$2:G$3;C10)=1;G$2:G$3)

Für die PT selbst ziehst du dann
Hilfe in den Zeilenbereich
Datum im den Spaltenbereich
Ausgabe in den Wertebereich

Dann noch einen Rechtsklick auf irgendein Datum in der PT > Gruppieren > Monate > OK

 

Hey Schatzi,
danke für Deine Mühe.

Hat alles geklappt. Jetzt habe ich mich endlich mal an PT getraut. Geht ja echt gut, das kann ich sicher noch ganz oft brauchen.

Danke nochmals und schöne Grüße