Office: (Office 2010) Excel SOS Funktion

Hallo zusammen,

ich weiß nicht mehr weiter und hoffe, dass Ihr mir helfen könnt....ich hab alles was ich weiss ausprobiert
Ich will in Excel eine Funktion einstellen, die sich auf 3 Spalten (evtl. auch mehr) bezieht nur komm ich einfach nicht weiter...wenn ich das mit der WENN-Funktion erstellen möchte und mehrer WENN-Funktionen zusammenfügen möchte....


Folgende Spalten:

Datum heute
Fällig am
Offener Betrag

Datum heute: 04.08.2016


Fällig am Offener Betrag
10.08.2016 200,00 €
20.07.2016 150,00 €
04.08.2016 480,00 €

mit der Funktion will ich folgende Information erhalten:

wenn "offener Betrag"=0 dann = bezahlt und grün
Wenn"Offener Betrag" >0 dann fällig am/fällig seit +Anzahl der Tage ; sonst "überprüfen"
(wenn bereits fällig rot und noch zeit gelb, das mit den Farben müsste mit der Bedingten-Formatierung klappen)

Ich weiss nicht ob ich in die richtige Richtung gehe, aber so sieht es bei mir für den Anfang aus, nur komm ich nicht weiter...
=wenn(offener Betrag=0;"bezahlt";wenn(offener Betrag>0;summe(fällig am-datum heute)=<0;"fällig";Wenn(offener Betrag>0;summe(fällig am-datum heute)>0;"zu zahlen" in XY Tagen...

Ich habe die Formel öfters umgestellt etc., aber dann funktioniert es bei positiven Ergebnissen von Fälligkeit am und Datum heute, aber wenn die Differenz negativ ist bekomme ich eine komische Zahl....oder die Formel funktioniert, aber wenn ich < oder > Zeichen ändere, dann funktioniert es wieder nicht ;(((

Ich hoffe Ihr könnt mir helfen, ich weiß nicht wo mein Denkfehler liegt
Vieeeeeeeeelen Dank....

LG Salma

 

Hola,

stell doch bitte eine Beispieldatei mit händisch eingetragenen Wunschergebnissen zur Verfügung.

Gruß,
steve1da

 

Hallo steve1da,

so ungefähr würde ich es haben wollen, wenn ihr Verbesserungsvorschläge habt, gerne. Es geht darum, dass ich anhang der eingepflegten daten, die Information erhalten soll, ob ein "Betrag offen" und wenn ja, ob die "Frist fällig" ist +Anzahl Tage, und wenn die Frist noch nicht fällig wie lange bis fällig.....

Den Anhang 9091 betrachten Datum heute 05.08.2016

Fällig am Bezahlter Offen Status
08.08.2016 20,00 € 0,00 € bezahlt
08.08.2016 0,00 € 20,00 € fällig in 3 Tagen
18.07.2016 580,00 € 0,00 € bezahlt
15.08.2016 0,00 € 100,00 € fällig in 10 Tagen
31.07.2016 70,00 € -20,00 € überprüfen hier soll die Funktion ("überprüfen anzeigen")
25.07.2016 0,00 € 250,00 € fällig seit 11 Tagen

vielen dank

Gruß, Salma

 

Hallo,


war nach einer Beispieldatei oder einem Bildchen gefragt????

 

Hola,

in D4 folgende Formel:

Code:

=WENN(C4=0;"bezahlt";WENN(UND(A4>$B$1;C4>0);"fällig in "&A4-$B$1&" Tagen";WENN(UND(C4>0;A4<$B$1);"fällig seit "&$B$1-A4&" Tagen";WENN(C4<0;"überprüfen";""))))

Für die Farben D4 bis D8 markieren. Start - Bedingte Formatierung - Neue Regel - Formel zur Ermittlung....

Hier legst du 4 Regeln an:

Code:

=D4="bezahlt"

für grün

Code:

=LINKS(D4;9)="fällig in"

für gelb

Code:

=LINKS(D4;11)="fällig seit"

für rot

Code:

=D4="überprüfen"

für grau

Gruß,
steve1da

 

Hallo,

einfache Formel:

Code:

=WENN(C2=0;"bezahlt";WENN(C2 > 0;"fällig "&WENN(A2 < HEUTE();"seit ";"in ")&ABS(HEUTE()-A2)&" Tagen";"überprüfen!"))

Arbeitsblatt mit dem Namen 'Tabelle1'
*	A	B	C	D
1	Datum heute	05.08.2016	*	*
2	*	*	*	*
3	Fällig am	Bezahlter in €	Offen	Status
4	08.08.2016	20,00 €	0,00 €	bezahlt
5	08.08.2016	0,00 €	20,00 €	fällig in 3 Tagen
6	18.07.2016	580,00 €	0,00 €	bezahlt
7	15.08.2016	0,00 €	100,00 €	fällig in 10 Tagen
8	31.07.2016	70,00 €	-20,00 €	überprüfen!
9	25.07.2016	0,00 €	250,00 €	fällig seit 11 Tagen

Zelle	Formel
D4	=WENN(C4=0;"bezahlt";WENN(C4>0;"fällig "&WENN(A4<HEUTE();"seit ";"in ")&ABS(HEUTE()-A4)&" Tagen";"überprüfen!"))

Zelle	bedingte Formatierung...	Format
D4	1: =C4=0	abc
D4	2: =C4<0	abc
D4	3: =A4>HEUTE()	abc
D4	4: =A4<HEUTE()	abc

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Häkchen bei Anhalten setzen!!!!

 

Hallo Steve!da,

Danke, Danke, Danke, Danke, es funktioniert.....ich muss noch einiges lernen was Excel betrifft....

 

Hallo Boskobiati,

sorry hab Deine ANtwort jetzt gesehn.............vielen Dank.