Office: [Excel2003] VBA - Import Tabellenblätter

Hi,

ich hätte eine Frage zu VBA in Excel 2003:

Und zwar habe ich mehrere .xls-Dateien in einem bestimmten Ordner. Aus diesem Ordner benötige ich Daten aus der aktuellsten Datei in einer neuen Excel Datei.

Bsp.: Im Ordner "XY" benötige ich aus der Datei "Sept_09.xls" sämtliche Daten aus Tabellenblatt 1, 2 und 3 in meiner Datei "neu.xls" (auch in den Tabellenblätern 1, 2 und 3).
In der Datei "neu.xls" möchte ich einen Button haben, der mir auf Knopfdruck die Daten aus den Tabellenblättern in "Sept_09.xls" in die verschiedenen Tabellenblätter von "neu.xls" importiert.

Ich habe schon einen Code ausprobiert, damit klappt das aber nur für je ein Tabellenblatt:

Code:

Option Explicit
Sub Import_Tabellenblatt1()
   Dim fname As Variant
    
   fname = Application.GetOpenFilename("XLS-Dateien,*.xls")
   If fname <> False Then
      With ActiveSheet
         Workbooks.Open fname
         Worksheets(1).UsedRange.Copy .Range("Tabelle1!B10")
         ActiveWorkbook.Close False
        End With
        End If
End Sub

Für das zweite Tabellenblatt benutze ich dann einen eigenen Button mit analogem Code, wobei es dann "Worksheets(2)" und ("Tabelle2!B10") heißt.

Wie kann ich das alles auf einem zentralen Button mit einem Code vereinen?

 

Hallo,

ich nehme an, dass folgendes Makro möglicherweise weiterhilft:

Code:

Option Explicit

Public Sub Import_Tabellenblaetter()
  Dim Fname As Variant
  Dim QuWb As Workbook, ZlWb As Workbook
  Dim I As Long
  
  Fname = Application.GetOpenFilename(filefilter:="XLS-Dateien,*.xls")
  If Fname = False Then Exit Sub
  
  Set ZlWb = ActiveWorkbook
  Set QuWb = Workbooks.Open(Filename:=Fname)
  
  For I = 1 To MinI(3, QuWb.Worksheets.Count)
    QuWb.Worksheets(I).UsedRange.Copy Destination:=ZlWb.Worksheets(I).Range("B10")
  Next I
  
  QuWb.Close SaveChanges:=False
  Set QuWb = Nothing

End Sub

Private Function MinI(I1 As Long, I2 As Long) As Long
  If I1 < I2 Then MinI = I1 Else MinI = I2
End Function