Office: EXCLE Makro zum imporieren von txt

Hallo!
ich bin auf der suche nach einem EXCLE makro, dass eine .txt datei importiert. Dabei soll der vorhärige import überschrieben werden.
Klingt vielleicht etwas einfach aber ich habe überhaupt keine Kentinisse von Excle Makros... ich wäre deswegen um ein codebeispeil sehr dankbar ;) die txt datei ist immer am gleichen ort gespeichert und ändert sich immer wieder mal, deshalb soll der vorhärige import überschrieben werden. aus den Daten der .txt datei möchte ich mir in einer anderen arbeitsmappe ein diagramm erstellen , jedoch kann ich dieses problem selbst lösen. die spalten sind in der textdatei durch kommata getrennt.

Danke für jede Hilfe
Euer Forum-Neuling greendonut

 

Hi,

versuche es mal so:

Code:

Sub TextDatei()
    Dim arrText()               ' Array für die Zeileninhalte der Textdatei
    Dim lngZeile As Long        ' Schleifenzähler
'   benutzten Bereich Inhalte löschen
    ActiveSheet.UsedRange.ClearContents
'   Textdatei zum Einlesen öffnen
    Open "D:\Eigene Dokumente\Excel\Mappe2.txt" For Input As #1    '<== Pfad und Dateiname anpassen
'   Schleife bis Dateiende
    Do While Not EOF(1)
'       Array dimensionieren in Abhängigkeit von der jeweiligen Zeilennummer der Textdatei
        ReDim Preserve arrText(lngZeile)
'       Text zeilenweise ins Array schreiben
        Line Input #1, arrText(lngZeile)
'       Zeilenzähler um 1 erhöhen
        lngZeile = lngZeile + 1
    Loop
'   Textdatei schließen
    Close #1
'   Inhalt des Arrays in Spalte A ausgeben
    Range("A1").Resize(UBound(arrText()) + 1, 1) = Application.Transpose(arrText())
'   Text in Spalten mit ";" als Trenner
    Columns(1).TextToColumns Destination:=Range("A1"), DataType:=xlDelimited, _
        TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, _
        Semicolon:=True
End Sub

Bis später,
Karin

 

super!! Hat perfekt funktioniert :)
Danke