Office: Expertenfrage: Bedingte Formatierung und komplexe Suche

Guten Tag zusammen.

Problemstellung: Es sollen zwei Datensätze miteinander vergleicht werden.
Datensatz 1 ist eine Liste mit ca. 1500 Datensätzen (Beispielwert: YZ3543).
Datensatz 2 ist teils Fließtext, teils numerische Zahlen, teils Leerzeichen auf ca. 10000 Zellen in einer Spalte verteilt.
Je Datensatz ein Blatt.

Frage: (seht Euch bitte dazu auch den Anhang an)
Ich möchte wissen welche Werte des Datensatzes 1 in Datensatz 2 vorhanden sind.
Wenn in Datensatz 2 der Satz
"Milch schmeckt immer gut" steht, soll das Wort "Milch" als gefunden angezeigt werden. (Grün markiert). Im Moment findet meine Version nur absolute Übereinstimmungen.
Zudem wäre es super, wenn die in Spalte B hinterlegten Formeln und auch bedingten Formatierungen nur soweit nach unten gingen, wie auch in Spalte A Werte zum Suchen vorhanden sind. Am besten automatisch...
Die Krönung wäre folgendes (da setze ich ein Kopfgeld von 10 EUR via paypal aus, kein Witz!)
Alle nichtgefundenen Werte werden in B farblich markiert. So weit, so gut. Jedoch bei mehr als 2000 Spalten kann das ein ziemliches Gescrolle werden.
Daher: eine Liste die ausgibt, in welchen Zeilen die im Datensatz 2 nicht gefundenen Werte stehen....

Hoffe das war verständlich - ich bin sehr gespannt.



Beste Grüße,

Steffen

 

Hallo!

Arbeitsblatt mit dem Namen 'Datensatz2'
	A
1	Ab December
2	2013
3	werde ich meinen Kaffee
4	nur noch mit Milch trinken
5

Arbeitsblatt mit dem Namen 'Datensatz1'
	A	B	C	D	E	F	G
1	value	result					nicht gefundene stehen in den Zeilen
2	1	gefunden in Zeile 2					7
3	1	gefunden in Zeile 2					8
4	1	gefunden in Zeile 2					9
5	2	gefunden in Zeile 2					10
6	3	gefunden in Zeile 2					11
7	4						12
8	5						14
9	6						15
10	7						17
11	8						18
12	9						#ZAHL!
13	0	gefunden in Zeile 2					#ZAHL!
14	ß						#ZAHL!
15	´						#ZAHL!
16	2013	gefunden in Zeile 2					#ZAHL!
17	test1						#ZAHL!
18	test2						#ZAHL!
19	Milch	gefunden in Zeile 4					#ZAHL!
20	Kaffee	gefunden in Zeile 3					#ZAHL!
21	December	gefunden in Zeile 1					#ZAHL!

Zelle	Formel
B2	=WENN(A2="";"";WENN(ISTNV(VERWEIS(9^9;SUCHEN(A2;Datensatz2!A$1:A$99)));"";"gefunden in Zeile "&VERWEIS(9^9;SUCHEN(A2;Datensatz2!A$1:A$99);ZEILE($1:$99))))
G2	{=KKLEINSTE(WENN((A$2:A$99<>"")*(B$2:B$99="");ZEILE($2:$99));ZEILE(A1))}

Achtung, Matrixformel enthalten!Die geschweiften Klammern{} werden nicht eingegeben.Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.

 

Das ist ja der Wahnsinn! Vielen Dank! Ist es auch möglich dass sich die Formeln der Anzahl der befühlten Spalten A anpassen?

 

Dazu könntest du theoretisch auf dynamische Bereichsnamen (http://www.office-hilfe.com/support/showthread.php/5515-Excel-Dynamische-Bereichsnamen) zurück greifen.
Aber du kannst auch einfach den Bereich großzügig angeben. Wenn du also weißt, dass die absolut maximale Datenmenge z.B. 20000 wohl nicht übersteigen wird, dann erweiterst du den Bereich einfach entsprechend:

=WENN(A2="";"";WENN(ISTNV(VERWEIS(9^9;SUCHEN(A2;Datensatz2!A$1:A$22222)));"";"gefunden in Zeile "&VERWEIS(9^9;SUCHEN(A2;Datensatz2!A$1:A$22222);ZEILE($1:$22222))))

Das geht dann natürlich zu Lasten der Rechenzeit, aber diese Formeln arbeiten eigentlich recht schnell.

 

Großartig! Vielen Dank. hast Du einen paypal Account?

 

Nö, natürlich nicht...