Office: (Office 2003) Export Splitten

Helfe beim Thema Export Splitten in Microsoft Access Hilfe um das Problem gemeinsam zu lösen; Hallo EBS17 Das sieht schon mal sehr gut aus! Nun meine Fragen: Wo kann ich den Pfad angeben wo er die XLS Files abspeichern soll. Der Pfad ist... Dieses Thema im Forum "Microsoft Access Hilfe" wurde erstellt von sivu, 3. September 2008.

Seite 2 von 3

WERWOLFLI

Werwolfli

Export Splitten

Hallo EBS17

Das sieht schon mal sehr gut aus!

Nun meine Fragen:

Wo kann ich den Pfad angeben wo er die XLS Files abspeichern soll. Der Pfad ist immer der gleiche.
Ich möchte, dass die Spaltenüberschriften wie in der Abfrage vorhanden ebenfalls in jedes Worksheet übernommen werden, wie mache ich das.

Ich hoffe, Ihr könnt mir nochmals helfen.

Besten Dank!

Grüsse

Werwolf

Werwolfli, 2. Januar 2011

#16
EBS17

ebs17

Etwa:
Code:

Private Sub CrossCheckAllianz_Click()

Const MAXROWS As Long = 5000
Const STARTROW As Long = 1
Const STARTCOL As Long = 1

Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSheet As Excel.Worksheet
Dim i As Long
Dim k As Long
Dim sMyPath As String
Dim rst As DAO.Recordset
sMyPath = "X:\irgendwo\"

Set rst = CurrentDb.OpenRecordset("select * from ABF_CrossCheck_Allianz")
Set xlApp = New Excel.Application
xlApp.Visible = True

With rst
While Not .EOF
Set xlWb = xlApp.Workbooks.Add
Set xlSheet = xlWb.Worksheets(1)
xlSheet.Name = "Ausgabe"
i = i + 1
' Feldnamen
For k = 0 To .Fields.Count - 1
xlSheet.Cells(STARTROW, k + 1) = .Fields(k).Name
Next
xlSheet.Cells(STARTROW + 1, STARTCOL).CopyFromRecordset rst, MAXROWS
xlWb.SaveAs sMyPath & _
"Cross_Check_" & Format(Date, "YYYY_MM_DD_") & Format(i, "000") & ".xls"
xlWb.Close
Wend
.Close
End With

Set rst = Nothing
Set xlSheet = Nothing
Set xlWb = Nothing
xlApp.Quit
Set xlApp = Nothing

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 3. Januar 2011

#17
WERWOLFLI

Werwolfli

Hallo EBS17

Sensationell!!! Vielen Dank!!

Nun noch ein letztes Problemchen. In der Abfrage ABF_CrossCheck_Allianz möchte ich nun das Datum von und das Datum bis eingeben.

Das heisst, wenn ich den Button klicke, soll er mich fragen von welchem Datum bis welches Datum ich die Daten möchte.

Ich habe das probiert mit Parameter in der Abfrage. Aber das funktioniert nicht. Er bring dann immer die Meldung:

2 Parameter erwartet, keiner wurde geliefert.

Kann man das noch irgendwie lösen?

Danke im Voraus!

Grüsse

Werwolf

Werwolfli, 3. Januar 2011

#18
EBS17

ebs17

Export Splitten

Das heisst, wenn ich den Button klicke, soll er mich fragen von welchem Datum bis welches Datum ich die Daten möchte.
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Inputboxen fasse ich nicht an. Zweckmäßiger halte ich es, wenn im Formular neben dem Auslösebutton Auswahlfelder vorhanden sind, wo die Zeitraumgrenzen vorab eingegeben werden (gerne auch mit einem sinnvollen Standardwert vorbelegt). Diese Auswahlfelder kann man per VBA in die Recordseterzeugung einbinden:
Code:

Set rst = CurrentDb.OpenRecordset( _
"select * from ABF_CrossCheck_Allianz " & _
"where Datumsfeld between " & Format(Me!von, "\#yyyy\-mm\-dd\#") & _
" and " Format(Me!bis, "\#yyyy\-mm\-dd\#"), _
dbOpenSnapshot)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 3. Januar 2011

#19
WERWOLFLI

Werwolfli

Hallo Ebs17

Das mit den Feldern im Formular ist auch super! Ich habe nun folgenden Code:

Code:

Private Sub CrossCheckAllianz_Click()

On Error GoTo Err_CrossCheckAllianz_Click

Const MAXROWS As Long = 5000
Const STARTROW As Long = 1
Const STARTCOL As Long = 1

Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSheet As Excel.Worksheet
Dim i As Integer
Dim sMyPath As String
Dim k As Integer
Dim Result As Integer

Dim rst As DAO.Recordset
sMyPath = "\\Hpcf15\kca-dlz-kriens$\SKL_DLZ_Intern\04_Papiermanagement\20_Allianz_SB\07_Textfiles\74_Crosscheckfile\"

Set rst = CurrentDb.OpenRecordset( _
"select * from ABF_CrossCheck_Allianz " & _
"where Datum_Tracking between " & Format(Me!Datumvon, "\#yyyy\-mm\-dd\#") & _
" and " & Format(Me!Datumbis, "\#yyyy\-mm\-dd\#"), _
dbOpenSnapshot)

Set xlApp = New Excel.Application
xlApp.Visible = True

With rst
While Not .EOF
Set xlWb = xlApp.Workbooks.Add
Set xlSheet = xlWb.Worksheets(1)
xlSheet.NAME = "Cross_Check"
i = i + 1
' Feldnamen
For k = 0 To .Fields.Count - 1
xlSheet.Cells(STARTROW, k + 1) = .Fields(k).NAME
Next
xlSheet.Cells(STARTROW + 1, STARTCOL).CopyFromRecordset rst, MAXROWS
xlWb.SaveAs sMyPath & _
"Cross_Check_" & Format(Date, "YYYYMMDD_") & Format(Time, "HHmmSS_") & Format(i, "000") & ".xls"
xlWb.Close
Wend
.Close
End With

Set rst = Nothing
Set xlSheet = Nothing
Set xlWb = Nothing
xlApp.Quit
Set xlApp = Nothing

Result = DCount("*", "ABF_CrossCheck_Allianz")

MsgBox ("Es wurden " & Result & " Datensätze in Excel Files exportiert!"), vbOKOnly, "Datensätze exportiert"

Exit_CrossCheckAllianz_Click:
Exit Sub

Err_CrossCheckAllianz_Click:
MsgBox Err.Description
Resume Exit_CrossCheckAllianz_Click

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Die Felder im Formular heissen Datumvon und Datum bis

Nun bringt er aber immer die Meldung:

1 Parameter wurde erwartet, aber es wurden zu wenige Parameter übergeben

An was kann das liegen?

Grüsse

Werwolf

Werwolfli, 3. Januar 2011

#20
EBS17

ebs17

Die Datumsfelder sind auch wirklich Datumsfelder?
Die Abfrage "ABF_CrossCheck_Allianz" enthält keine "Störgeräusche"?

Mit Debug.Print kann man sich die resultierende Abfragedefinition ins Direktfenster ausgeben lassen und eine Sichtprüfung auf Syntaxfehler vornehmen.
Code:

' statt
xlSheet.Cells(STARTROW, k + 1) = .Fields(k).NAME

' besser so (konsequente Berücksichtigung der Konstanten)
xlSheet.Cells(STARTROW, STARTCOL + k) = .Fields(k).NAME
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 3. Januar 2011

#21
WERWOLFLI

Werwolfli

Hallo EBS17

Das Problem ist dass das Datumsfeld "Datum_Tracking" auf das ich mich in der Abfrage beziehe, nicht exportiert werden darf. Das Feld soll in der Abfrage sein, aber nicht exportiert werden. Wie geht das?

Wenn ich das Feld mit exportiere, kommt immer die Meldung am Schluss

Überlauf

Kannst Du mir nochmals helfen?

Grüsse

Werwolf

Werwolfli, 5. Januar 2011

#22
EBS17

ebs17

Export Splitten

Mit select * from ABF_CrossCheck_Allianz werden alle Felder erfasst. Alternativ bzw. sogar besser führst Du alle benötigten Felder einzeln auf:
Code:

select feld1, feld2, feld3 from ABF_CrossCheck_Allianz
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das andere kann ich nicht beurteilen: Weder kenne ich die Abfrage "ABF_CrossCheck_Allianz", noch hast Du die Datentypfrage beantwortet, und der Punkt des Überlaufs ist mit "am Schluss" recht undeutlich.

ebs17, 5. Januar 2011

#23
WERWOLFLI

Werwolfli

Die Datumsfelder sind mit dem Format Datum.
Datum kurz ist das Format

Wenn ich nun alle Felder aufzähle, dann zähle ich das Feld "Datum_Tracking" nicht auf. Denn dieses Feld darf im Export nicht erscheinen.

Ich brauche dieses aber um das Datum einzugrenzen.

Wenn ich das Feld "Datum_Tracking" auch exportieren würden, sprich in meiner Abfrage anzeige, dann funktioniert es. Zeige ich das Feld nicht an, kommt immer die Meldung

1 Parameter erwartet, es wurden zu wenige Parameter übergeben.

Überlauf ist behoben.

Wie kann ich das mit dem Feld Datum_Tracking lösen?

Werwolfli, 5. Januar 2011

#24
EBS17

ebs17

Du solltest vielleicht noch einmal die vollständige SQL-Anweisung zeigen. Bei der gegebenen Beschreibung habe ich keine Vorstellung.

ebs17, 5. Januar 2011

#25
WERWOLFLI

Werwolfli

Hier der Code der Abfrage:

Code:

SELECT TBL_Tracking.GFB_NR AS POLNR_GFB, "" AS POLNR_ALT_1, "" AS POLNR_ALT_2, "" AS ABLDAT, "" AS FIRMA, "" AS ZUSTAND, "" AS SPRACHE, "" AS HSP_PRODBEZ, "Ja" AS SCANNEN, "Kriens" AS ORT, "1" AS TAG, Date() AS ARCHIV_ENTNAHME, "" AS VERMERKE
FROM TBL_Tracking
WHERE (((TBL_Tracking.StatusNr)=70));
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wie du siehst, ist das Feld "Datum_Tracking" nicht in der Abfrage, da dieses ja nicht im Excel File erscheinen kann.

Im Formular greife ich aber genau auf das Feld "Datum_Tracking" zu, wie du siehst.

Code:

Private Sub CrossCheckAllianz_Click()

On Error GoTo Err_CrossCheckAllianz_Click

Const MAXROWS As Long = 5000
Const STARTROW As Long = 1
Const STARTCOL As Long = 1

Dim xlApp As Excel.Application
Dim xlWb As Excel.Workbook
Dim xlSheet As Excel.Worksheet
Dim i As Integer
Dim sMyPath As String
Dim k As Integer

Dim rst As DAO.Recordset
sMyPath = "\\Hpcf15\kca-dlz-kriens$\SKL_DLZ_Intern\04_Papiermanagement\20_Allianz_SB\07_Textfiles\74_Crosscheckfile\"

Set rst = CurrentDb.OpenRecordset( _
"select * from ABF_CrossCheck_Allianz " & _
"where Datum_Tracking between " & Format(Me!Datumvon, "\#yyyy\-mm\-dd\#") & _
" and " & Format(Me!Datumbis, "\#yyyy\-mm\-dd\#"), _
dbOpenSnapshot)

Set xlApp = New Excel.Application
xlApp.Visible = True

With rst
While Not .EOF
Set xlWb = xlApp.Workbooks.Add
Set xlSheet = xlWb.Worksheets(1)
xlSheet.NAME = "Cross_Check"
i = i + 1
' Feldnamen
For k = 0 To .Fields.Count - 1
xlSheet.Cells(STARTROW, STARTCOL + k) = .Fields(k).NAME
Next
xlSheet.Cells(STARTROW + 1, STARTCOL).CopyFromRecordset rst, MAXROWS
xlWb.SaveAs sMyPath & _
"Cross_Check_" & Format(Date, "YYYYMMDD_") & Format(Time, "HHmmSS_") & Format(i, "000") & ".xls"
xlWb.Close
Wend
.Close
End With

Set rst = Nothing
Set xlSheet = Nothing
Set xlWb = Nothing
xlApp.Quit
Set xlApp = Nothing

MsgBox ("Es wurden die gewünschten Datensätze in Excel Files exportiert!"), vbOKOnly, "Datensätze exportiert"

Exit_CrossCheckAllianz_Click:
Exit Sub

Err_CrossCheckAllianz_Click:
MsgBox Err.Description
Resume Exit_CrossCheckAllianz_Click

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Wenn ich das genau so ausführe wie die Codes oben, dann kommt die Meldung

1 Parameter wurde erwartet, es wurden zu wenige Parameter übergeben.

Füge ich bei der SQL Abfrage das Feld "Datum_Tracking" hinzu, dann funktioniert alles. Nur die Spalte Datum_tracking darf nicht im Excel erscheinen.

Wie könnte ich das schaffen?

Werwolfli, 6. Januar 2011

#26
USER

User

Die Antwort hast Du doch schon in #23 erhalten!
Du hast es aber scheinbar nicht verstanden.
Du lässt das Feld in der Abfrage drin und machst im Code was Eberhard in #23 beschrieben hat.

Gruß

LL

User, 6. Januar 2011

#27
EBS17

ebs17

Export Splitten

Anders formuliert: Du hast das Datumsfeld aus der falschen Abfrage entfernt. Mit etwas Überlegung kann man da selber drauf kommen.

Alternativ könnte man gleich in die ursprüngliche Abfrage das zusätzliche Kriterium einbauen:
Code:

Set rst = CurrentDb.OpenRecordset( _
"SELECT T.GFB_NR AS POLNR_GFB, '' AS POLNR_ALT_1, '' AS POLNR_ALT_2," & _
" '' AS ABLDAT, '' AS FIRMA, '' AS ZUSTAND, '' AS SPRACHE, '' AS HSP_PRODBEZ," & _
" 'Ja' AS SCANNEN, 'Kriens' AS ORT, '1' AS TAG, Date() AS ARCHIV_ENTNAHME, '' AS VERMERKE" & _
" FROM TBL_Tracking T WHERE T.StatusNr = 70" & _
" AND T.Datum_Tracking between " & Format(Me!Datumvon, "\#yyyy\-mm\-dd\#") & _
" AND " & Format(Me!Datumbis, "\#yyyy\-mm\-dd\#", _
dbOpenSnapshot)
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 6. Januar 2011

#28
WERWOLFLI

Werwolfli

Tatsächlich!!!!!

Vielen Dank, ich habe das wirklich falsch verstanden. Jetzt geht es!!

Kann ich die Datensätze zählen welche ich exportiere? Ich möchte diese zahl am Schluss in einer MSG Box ausgeben.

Daaaaaaaaanke!!!!

Werwolfli, 6. Januar 2011

#29
EBS17

ebs17

Code:

With rst
' ...
MsgBox rst.RecordCount
.Close
End With
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

ebs17, 6. Januar 2011

#30

(Du musst angemeldet oder registriert sein, um eine Antwort erstellen zu können.)

Seite 2 von 3

Thema:

Export Splitten

Die Seite wird geladen...

Export Splitten - Similar Threads - Export Splitten
Makros für csv-Export mit Anführungszeichen für ausgewählte Splaten
in Microsoft Excel Hilfe
Makros für csv-Export mit Anführungszeichen für ausgewählte Splaten: Hallo liebe Forengemeinde, ich habe folgendes Problem: Ich muss eine csv-Datei bearbeiten und anschließend wieder als csv-Datei speichern. In der Originaldatei sind einige Spalteninhalte in in...
Export-Makro überschreibt .xlsx-Dateien nur taggleich
in Microsoft Access Hilfe
Export-Makro überschreibt .xlsx-Dateien nur taggleich: Hallo zusammen, arbeite bereits seit vielen Jahren mit Access-Datenbanken. Seit einigen Wochen habe ich einen Fehler der mich in den Wahnsinn treibt. Wir verwenden Access-Datenbanken als...
Export als Textdatei in UTF-8
in Microsoft Excel Hilfe
Export als Textdatei in UTF-8: Hallo zusammen, ich habe gerade ein Exportproblem und wäre für jede Hilfe dankbar. In unserem CAD Programm habe ich das Wörterbuch exportiert als .txt-Datei. Das Textprogramm gibt eine in UTF-8...
Export CSV - Laufzeitfehler 3625
in Microsoft Access Hilfe
Export CSV - Laufzeitfehler 3625: Moin Zusammen Ich steh gerade ein wenig auf dem Schlauch... Habe eine Tabelle die ich exportieren will. Habe es einmal gemacht und den Exportschritt unter "exportDatev" gespeichert. Über VBA...
Outlook Export Assistent funktioniert nicht mehr
in Microsoft Outlook Hilfe
Outlook Export Assistent funktioniert nicht mehr: Ich habe heute ein wenig experimentiert und dabei wohl einen Fehler gemacht, der zur Folge hat, das ich keine Daten mehr mit Export Assistenten exportieren kann. Am Anfang läuft alles normal In...
Fehler beim Export in eine PDF
in Microsoft Word Hilfe
Fehler beim Export in eine PDF: m
Bildqualität beim Exportieren
in Microsoft Word Hilfe
Bildqualität beim Exportieren: Hallo zusammen, in Word 2019 habe ich ein 85-seitiges Büchlein angelegt mit zahlreichen Fotos (.jpg), einige sind freigestellt (.png). Nun möchte ich das Ganze als PDF als PDF exportieren unter...

Anmelden oder registrieren

Suche

Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.

Akzeptieren Weitere Informationen...

Information ausblenden