Office: Fehler beim zweiten Datensatz... VBA code

Hallo zusammen,

hab folgendes kleines Problem. Eine Tabelle die Ruhezeiten hat - soll den Inhalt von einer Zeile in die nächste übertragen - damit hier was berechnet werden kann. Das funktioniert auch soweit - nur mit den ersten zwei Datensätzten haut das nicht hin.

• 
  ID SFDTLC Rest10hrs Last10hrsBreak
  4368 GPE 06.04.2011 04:24
  4410 GPE 07.04.2011 00:30 24.06.2011 01:30
  4476 GPE 08.04.2011 02:53 07.04.2011 00:30
  4532 GPE 09.04.2011 00:15 08.04.2011 02:53

Bei der ID 4410 übernimmt er das Datum vom letzten "Arbeiter" SFDTLC...
Irgendwie bekomme ich nicht hin - das sobald sich der Arbeiter ändert - der erste "Rest10hrs" gelesen wird - und in "Last10hrsBreak" übertragen wird.
Hier mein Code:

Code:

Public Sub Group_Intervalle()
  Dim db As Database
  Dim RstZeit As DAO.Recordset
  Dim ErsterSatz As Boolean, AktArbeiter As String
  Dim Next10hrs As Date
  Dim Next36hrs As Date
  
  Abfrage = _
      "SELECT   Z.SFDTLC, Z.Rest10hrs, Z.Rest36hrs, Z.Last10hrsBreak, Z.Last36hrsBreak " & _
      "FROM     [GroupID_Local] AS Z " & _
      "ORDER BY Z.SFDTLC, Z.MinvonSFDCIdate;"
  'Die Abfrage wird ausgeführt und ein Recordset RstZeit erstellt
  Set db = CurrentDb
  Set RstZeit = db.OpenRecordset(name:=Abfrage, Type:=dbOpenDynaset, Options:=dbConsistent, LockEdit:=dbOptimistic)

ErsterSatz = True: AktArbeiter = ""
    
  With RstZeit
      'Hole den 1. Satz
      .MoveFirst
      'Überprüfe, ob überhaupt noch ein Satz gelesen wurde;
      'falls nicht: beende die Schleife
      Do Until .EOF
        'Überprüfen, ob ein neuer Arbeiter vorliegt
        ErsterSatz = AktArbeiter <> !SFDTLC
        If ErsterSatz Then
          'Aktualisieren des Namens des neuen Arbeiters
          AktArbeiter = !SFDTLC
          Last10hrsBreak = !Rest10hrs
          Last36hrsBreak = !Rest36hrs
          'Ausgabe der 1.Ankunft des Arbeiters in den Direktbereich:
          Debug.Print !SFDTLC, !Rest10hrs, !Rest36hrs
          'Überschrift ausgeben in den Direktbereich:
          Debug.Print "TLC", "CI-Date", "CO-Date"
               '1.Satz-Modus ist vorbei:
                
          ErsterSatz = False
        Else
          'Felder der aktuellen Abfrage können geändert werden:
          .EDIT
            'Abfragefeld wird geändert
            !Last10hrsBreak = Next10hrs
            !Last36hrsBreak = Next36hrs
         'Änderung des Abfragefeldes
          .update
          'Umspeichern um Anfangszeitpunkt für nächsten Satz:
            Next10hrs = !Rest10hrs
            Next36hrs = !Rest36hrs
        End If
        'Hole nächsten Satz
        .MoveNext
      Loop
      'Es gibt nichts mehr zu lesen: Abfrage schließen!
      .Close
  End With
End Sub

Es gibt zwei Spalten einmal mit 36hrs und einmal mit 10hrs... ist aber die gleiche funktion.

Idee warum er beim zweiten Datensatz da was falsch macht?

 

So - fehler gefunden:

Code:

Public Sub Group_Intervalle()
  Dim db As Database
  Dim RstZeit As DAO.Recordset
  Dim ErsterSatz As Boolean, AktArbeiter As String
  Dim Next10hrs As Date
  Dim Next36hrs As Date
  
  Abfrage = _
      "SELECT   Z.SFDTLC, Z.Rest10hrs, Z.Rest36hrs, Z.Last10hrsBreak, Z.Last36hrsBreak " & _
      "FROM     [GroupID_Local] AS Z " & _
      "ORDER BY Z.SFDTLC, Z.MinvonSFDCIdate;"
  Set db = CurrentDb
  Set RstZeit = db.OpenRecordset(name:=Abfrage, Type:=dbOpenDynaset, Options:=dbConsistent, LockEdit:=dbOptimistic)

ErsterSatz = True: AktArbeiter = ""
    
  With RstZeit
      .MoveFirst
      Do Until .EOF
        ErsterSatz = AktArbeiter <> !SFDTLC
        If ErsterSatz Then
          AktArbeiter = !SFDTLC
        '  Last10hrsBreak = !Rest10hrs
        '  Last36hrsBreak = !Rest36hrs
        Next10hrs = !Rest10hrs
        Next36hrs = !Rest36hrs
        '  Debug.Print !SFDTLC, !Rest10hrs, !Rest36hrs
        '  Debug.Print "TLC", "CI-Date", "CO-Date"
          ErsterSatz = False
        Else
          .EDIT
            !Last10hrsBreak = Next10hrs
            !Last36hrsBreak = Next36hrs
          .update
            Next10hrs = !Rest10hrs
            Next36hrs = !Rest36hrs
        End If
        .MoveNext
      Loop
      .Close
  End With
End Sub

So einfach könnte es immer sein...