Office: (Office 2007) Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ...

z10.2 · 11. Mai 2009

Hallo Forum,
dank der Beiträge im Forum konnte ich als Laie in Excel 2003 mit VB bestimmte wiederkehrende Aufgaben bei der Erzeugung einer Bestellung automatisieren. Sicher ist meine zusammengebastelte VB Programmierung nicht ganz optimal und sauber gestaltet, erfüllt aber halt ihren Zweck. Jetzt habe ich aber ein Problem. Nach der Umstellung auf Office 2007 funktioniert meine VB Programmierung nicht mehr. Als Fehlermeldung erhalte ich folgenden Text:

Die folgenden Features können in Arbeitsmappen ohne Makros nicht gespeichert werden
VB Projekt
Zum Speichern einer Datei mit diesen Features klicken Sie auf nein. Wählen Sie dann einen Dateityp mit aktivierten Makros in der Liste "Dateityp" aus
Klicken Sie auf Ja um die Datei als Arbeitsmappe ohne Makros zu speichern.

Egal was ich dann auch mache, hängt die Ausführung sich dann bei Kill. FullName auf.

Ich weiß mir trotz aller Recherchen keinen Rat mehr und möchte euch bitten, einmal über die beigefügte Programmierung zu schauen.

Vielleicht seht ihr ja direkt was "falsch läuft" und könnt mir einen Typ geben.
Dafür schon jetzt besten Dank und Gruß

z10.2

:)

chris-kaiser · 12. Mai 2009

hi

ohne jetzt etwas getestet zu haben

ändere mal

ActiveWorkbook.SaveAs Filename:=wbname & ".xls"

auf

ActiveWorkbook.SaveAs Filename:=wbname & ".xlsm"

mumpel · 12. Januar 2021

Hallo!

von chris-kaiser

ohne jetzt etwas getestet zu haben

ändere mal
ActiveWorkbook.SaveAs Filename:=wbname & ".xls"
auf
ActiveWorkbook.SaveAs Filename:=wbname & ".xlsm"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Das funktioniert so in Office 2007 nicht mehr. Besser so:

ActiveWorkbook.SaveAs Filename:=wbname, FileFormat:=xlOpenXMLWorkbookMacroEnabled
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Gruß, René

chris-kaiser · 12. Mai 2009

Hallo René

Danke für den Hinweis

mumpel · 13. Mai 2009

Habe mir das Projekt mal angeschaut (mir scheint, Du hast hier mit dem Macrorecorder gearbeitet->zuviel Selection. Das sollte geändert werden). Das selbe Problem hatte ich auch. Das liegt am SaveAs (nicht am Dateiformat). Ich habe das dann etwas anders gelöst. Zuerst wird der Name der aktiven Arbeitsmappe zwischengespeichert, dann die aktive Arbeitsmappe unter neuem Namen gespeichert (die Originalmappe wird von Excel automatisch geschlossen). Dann hänge ich die neue Datei an, schließe diese und zum Schluß wird die Originalmappe wieder geöffnet (ReOpenOriginatorWorkbook). Anbei mal mein Code aus meinem Projekt (Office 2007 Telefon- und Mailfunktion). Der Code ist für Excel 2007 und Outlook 2007 geschrieben. Einige Funktionen (zum Beispiel: .SendUsingAccount) funktionieren nur in Outlook 2007. Vielleicht hilft der Code ja bei der Problemlösung. Wichtig wäre hier der Abschnitt Mailvorbereitung (Dateianhänge und Attachment)

Option Private Module

Public MailAnhangEin As Boolean
Public RangetoHTMLYes As Boolean
Public AktiveDateiSchließen As Boolean
Public MailenShow As Boolean

Rem ******************************************************************************** ************
Rem ******************************************************************************** ************

Sub SendeEmail()

Dim oApp As Outlook.Application
Dim oAccount As Outlook.Account
Dim oMail As Outlook.MailItem

Dim WsShell
Dim intSheetCounter As Integer
Dim rng As Range
Dim objNode As Node
Dim vntSheetArray() As Variant

Dim aktWb As Object
Dim aws As String
Dim Datei As String
Dim ReOpenOriginatorWorkbook As String
Dim s As String
Dim strpath As String

SaveSetting "RMH_Installationen", "MailSettingsExcel", "MailExcelTo", Mailen.TextBox1.Value
SaveSetting "RMH_Installationen", "MailSettingsExcel", "MailExcelBetreff", Mailen.TextBox2.Value
SaveSetting "RMH_Installationen", "MailSettingsExcel", "MailExcelBody", Mailen.TextBox3.Value
SaveSetting "RMH_Installationen", "MailSettingsExcel", "MailExcelCC", Mailen.TextBox5.Value
SaveSetting "RMH_Installationen", "MailSettingsExcel", "MailExcelBCC", Mailen.TextBox6.Value

Rem ******************************************************************************** ************
Rem Mailvorbereitung (Dateianhänge und Attachment)

Rem Markierten Bereich in Mailbody einfügen.
Rem Nur möglich mit HTML-Mail
If Mailen.OptionButton3.Value = True Then
RangetoHTMLYes = True
GoTo Weiter
End If

MailAnhangEin = True

Rem Aktive Arbeitsmappe als Anhang
If Mailen.OptionButton1.Value = True Then
Application.DisplayAlerts = False
If Mailen.OptionButton4.Value = True Then
ActiveWorkbook.Save
ElseIf Mailen.OptionButton5.Value = True Then
If Mailen.TextBox4.Value = "" Then GoTo Fehler
ReOpenOriginatorWorkbook = ActiveWorkbook.FullName
ActiveWorkbook.SaveAs Filename:=Mailen.TextBox4.Value, FileFormat:=xlExcel8
AktiveDateiSchließen = True
End If
aws = ActiveWorkbook.FullName
Application.DisplayAlerts = True

Rem Aktive Tabelle als Anhang
ElseIf Mailen.OptionButton2.Value = True Then
If Mailen.TextBox4.Value = "" Then GoTo Fehler
Application.DisplayAlerts = False
ActiveWorkbook.ActiveSheet.Copy
If Mailen.OptionButton4.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlOpenXMLWorkbook
ElseIf Mailen.OptionButton5.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlExcel8
End If
aws = ActiveWorkbook.FullName
AktiveDateiSchließen = True
Application.DisplayAlerts = True

Rem ausgewählte Tabellen als Anhang
ElseIf Mailen.OptionButton12.Value = True Then
If Mailen.TextBox4.Value = "" Then GoTo Fehler
Application.DisplayAlerts = False

For Each objNode In Mailen.TreeView1.Nodes
If objNode.Checked = True Then
Redim Preserve vntSheetArray(0 To intSheetCounter)
vntSheetArray(intSheetCounter) = objNode.text
intSheetCounter = intSheetCounter + 1
End If
Next objNode

ActiveWorkbook.Sheets(vntSheetArray).Copy
If Mailen.OptionButton4.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlOpenXMLWorkbook
ElseIf Mailen.OptionButton5.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlExcel8
End If
aws = ActiveWorkbook.FullName
AktiveDateiSchließen = True
Application.DisplayAlerts = True

Rem Markierten Bereich in neue Arbeitsmappe
ElseIf Mailen.OptionButton14.Value = True Then
Selection.Copy
Workbooks.Add
Range("A1").PasteSpecial (xlPasteValues)
Application.CutCopyMode = False
Application.DisplayAlerts = False
ActiveWorkbook.Sheets(Array("Tabelle2", "Tabelle3")).Delete
If Mailen.TextBox4.Value = "" Then GoTo Fehler
If Mailen.OptionButton4.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlOpenXMLWorkbook
ElseIf Mailen.OptionButton5.Value = True Then
ActiveWorkbook.SaveAs _
Filename:=Mailen.TextBox4.Value, FileFormat:=xlExcel8
End If
aws = ActiveWorkbook.FullName
AktiveDateiSchließen = True
Application.DisplayAlerts = True

Rem Ausgewählte Datei (aus ordner) als Anhang
ElseIf Mailen.OptionButton13.Value = True Then
aws = Mailen.TextBox4.text
End If
Rem ******************************************************************************** ************

Weiter:

Rem ******************************************************************************** ************
Rem Beginn Mail erstellen
Rem Dieses Makro erfordert einen Verweis auf die Microsoft Outlook 12.0 Object Library

On Error Resume Next

Rem Outlooksitzung starten/Auf Outlooksitzung zugreifen

Rem Prüfen, ob Outlook gestartet ist. Wenn ja, dann darauf zugreifen
Rem Wenn nicht gestartet, dann Outlooksitzung starten (temporär)

Set oApp = GetObject(, "OUTLOOK.Application")
If Not oApp Is Nothing Then
GoTo Erstellen
Else
Err.Clear

Set oApp = CreateObject("OUTLOOK.Application")
End If

On Error GoTo 0

Erstellen:
Set oMail = oApp.CreateItem(olMailItem)
With oMail
Set rng = Selection

Rem Empfänger (An...)
.To = Mailen.TextBox1.text

Rem Kopie an (CC...)
.CC = Mailen.TextBox5.text

Rem Blindkopie an (Bcc...)
.BCC = Mailen.TextBox6.text

Rem Betreff erstellen
.Subject = Mailen.TextBox2.text

Rem Kontoauswahl
If Mailen.ComboBox3.Value <> "" Then _
.SendUsingAccount = .Session.Accounts(Mailen.ComboBox3.Value)

Rem Text und Mailformat festlegen
If RangetoHTMLYes = True Then
.BodyFormat = olFormatHTML
.HTMLBody = Mailen.TextBox3.Value & vbCrLf & vbCrLf & vbCrLf & RangetoHTML(rng)
ElseIf Mailen.OptionButton8.Value = True Then
.BodyFormat = olFormatHTML
.HTMLBody = Mailen.TextBox3.Value
ElseIf Mailen.OptionButton15.Value = True Then
.BodyFormat = olFormatRichText
.Body = Mailen.TextBox3.Value
Else
.BodyFormat = olFormatPlain
.Body = Mailen.TextBox3.Value
End If

Rem Datei als Anhang einfügen
If MailAnhangEin = True Then _
.Attachments.Add aws

Rem Im Namen von senden (Von...)
If Mailen.ComboBox4.Value <> "" Then _
.SentOnBehalfOfName = Mailen.ComboBox4.Value

Rem Lesebestätigung anfordern
If Mailen.CheckBox1.Value = True Then _
.ReadReceiptRequested = True

Rem Übermittlungsbestätigung anfordern
If Mailen.OptionButton10.Value = True Then _
.OriginatorDeliveryReportRequested = True

Rem Mail nicht weiterleiten
If Mailen.CheckBox3.Value = True Then _
.Permission = olDoNotForward

Rem Keine Kopie der Mail in "Gesendete Objekte" speichern
If Mailen.OptionButton11.Value = True Then _
.DeleteAfterSubmit = True

Rem Vertraulichkeit abfragen/einstellen
Rem 0 = Normal, 1 = Persönlich, 2 = Privat, 3 = Vertraulich
If Mailen.ComboBox1.Value = "Normal" Then
.Sensitivity = 0
ElseIf Mailen.ComboBox1.Value = "Privat" Then
.Sensitivity = 2
ElseIf Mailen.ComboBox1.Value = "Persönlich" Then
.Sensitivity = 1
ElseIf Mailen.ComboBox1.Value = "Vertraulich" Then
.Sensitivity = 3
End If

Rem Wichtigkeit abfragen/einstellen
Rem 0 = Niedrig, 1 = Normal, 2 = Hoch
If Mailen.ComboBox2.Value = "Niedrig" Then
.Importance = 0
ElseIf Mailen.ComboBox2.Value = "Normal" Then
.Importance = 1
ElseIf Mailen.ComboBox2.Value = "Hoch" Then
.Importance = 2
End If

Rem Sendetermin festlegen
If Mailen.TextBox7.Value <> "" Or Mailen.ComboBox6 <> "" Then _
.DeferredDeliveryTime = Mailen.TextBox7.Value & " " & Mailen.ComboBox6.Value

Rem Mail anzeigen
.Display

Rem Mail sofort senden
If Mailen.OptionButton6.Value = True Then
Set WsShell = CreateObject("WScript.Shell")
WsShell.AppActivate olApp
WsShell.SendKeys "%s"
Set WsShell = Nothing
End If

Rem Adressbuch öffnen
If Mailen.OptionButton7.Value = True Then
Set WsShell = CreateObject("WScript.Shell")
WsShell.AppActivate olApp
WsShell.SendKeys "%b"
End If
End With

Rem Mail erstellen beendet
Rem ******************************************************************************** ************

Rem Datei nach dem Senden löschen
If Mailen.CheckBox4.Value = True Then
Set aktWb = ActiveWorkbook
aktWb.Activate
strpath = aktWb.Path & "\" & aktWb.Name
aktWb.Close
Kill strpath
If Mailen.OptionButton5.Value = True And Mailen.OptionButton1.Value = True Then _
Workbooks.Open ReOpenOriginatorWorkbook
Else
If AktiveDateiSchließen = True Then ActiveWorkbook.Close
If Mailen.OptionButton5.Value = True And Mailen.OptionButton1.Value = True Then _
Workbooks.Open ReOpenOriginatorWorkbook
End If

Rem Objektvariablen freigeben
Set rng = Nothing
Set olApp = Nothing
Set WsShell = Nothing
Set aktWb = Nothing

Rem Öffentliche Variablen ausschalten
MailAnhangEin = False
RangetoHTMLYes = False
AktiveDateiSchließen = False

Rem Dialog beenden
Unload Mailen
Exit Sub

Fehler:
MsgBox "Sie müssen einen Namen für die Kopie/Datei angeben!", vbOKOnly + vbExclamation, "Hinweis"

End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

Code eingefügt mit VBA in HTML 2.0

rudse · 24. August 2010

Hatte den gleichen Fehler, genial, funktioniert perfekt!

xlOpenXMLWorkbookMacroEnabled

User · 31. Oktober 2012

hat bei mir auch funktioniert, danke!
Da ich ActiveWorkbook.SaveAs nicht direkt aus Excel aufrufe hat er xlOpenXMLWorkbookMacroEnabled nicht gekannt.
Alternativ kann man dann auch die Zahl 52 dafür angeben:
ActiveWorkbook.SaveAs Filename:=strFileName & ".xlsm", FileFormat:=52

Office: (Office 2007) Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ...

Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ...

Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ...

Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ...

Fehler VBA: die folgenden Features können in Arbeitsmappen ohne Makros nicht ... - Similar Threads - Fehler VBA Features

Kreuztabelle / VBA / Fehler behandlung

VBA Stapelspeicher Fehler

VBA - Fehler beim Kompilieren (Mehrdeutiger Name - Worksheet_Change)

Makro Problem nach Wörtern filtern und Zeilen löschen

Fehler beim übertragen einer funktionierenden VBA

Warum Fehler beim Kompilieren (VBA)???

VBA Fehler auf 1 von 3 Rechnern