Office: Feldinhalte in separate Felder einfuegen

Hallo,

villeicht kann mir jemand bei meinem Problemchen helfen?
ich habe eine Tabelle nur mit dem gefüllten Feld3:

Feld1|Feld2|Feld3
8000 / 9999 S Schule
- Apotheke
Einkaufszentrum
Bahnhof
Gewerbepark

Feld1 und Feld2 ist noch leer.

Meine Zieltabelle soll so aussehen:

Feld1|Feld2|Feld3
8000|9999|Schule
8000|9999|Apotheke
8000|9999|Einkaufszentrum
8000|9999|Bahnhof
8000|9999|Gewerbepark

1.) Wie bekomme ich durch eine oder mehre (Aktualisierungs-)Abfragen 8000 in Feld1 und 9999 in Feld2 ? Diese Zahlen können auch weniger Stellen besitzen.
2.) Wie kille ich dabei " / " und " S " in der ersten Zeile?
3.) Wie kille ich in der zweiten Zeile "- ", nur falls es mal vor dem Namen stehen sollte?


Vielen Dank für eure Hilfe.

MfG,
Mat

 

Hallo Mat,

im folgenden VBA-Makro steuere ich über die log.Variable 'IstErster' die unterschiedliche Behandlung des 1.Satzes und der restlichen Sätze.
Die Felder habe ich so benannt wie in Deinem Posting.

Code:

Option Compare Database
Option Explicit

Public Sub Tabelle_Aktualisieren()
  Dim Db As Database
  Dim Rst As DAO.Recordset
  Dim IstErster As Boolean, S$, F$, F1&, F2&, Ps&
  
  Set Db = CurrentDb
  Set Rst = Db.OpenRecordset("Tabelle7", dbOpenTable)
  IstErster = True
  
  Do Until Rst.EOF
    S$ = Rst!Feld3
    If IstErster Then
      Ps& = InStr(S$, "/")
      F1& = Left$(S$, Ps& - 1): S$ = LTrim(Mid$(S$, Ps& + 1))
      Ps& = InStr(S$, " ")
      F2& = Left$(S$, Ps& - 1): S$ = Trim(Mid$(S$, Ps& + 1))
      If Left(S$, 2) = "S " Then S$ = LTrim$(Mid$(S$, 3))
      IstErster = False
    Else
      If Left(S$, 2) = "- " Then S$ = LTrim$(Mid$(S$, 3))
    End If
    With Rst
      .Edit
      !Feld1 = F1&
      !Feld2 = F2&
      !Feld3 = S$
      .Update
      Rst.MoveNext
    End With
  Loop
  Rst.Close
  
End Sub