Office: feste Satzlängen definieren in EXCEL

Hallo Zusammen,
ich versuche gerade in Excel eine Datei mit festen Satzlängen zu definieren. Beispiel:
Spalte1: 3-stellig
Spalte2: 15-stellig

Soweit kann man das ja über die Formartierung hinbekommen. Aber! Wenn ich jetzt einen Wert hineinkopiere (in die Spalte 2 bspw. einen 6-stelligen Begriff), dann ist die Formatierung dahin. Habe es auch schon mit Bearbeiten, Inhalte einfügen, nur Werte probiert. Wird trotzdem überschrieben.
Also wie bekomme ich es hin, dass ein einmal definiertes Formal beim Füllen eines Wertes nicht überschrieben wird.

Herzlichen Dank

 

Grüezi Juergen

Du kannst zwar die Länge eines Inhaltes über Daten/Gültigkeite auf die fixen Längen vorgeben, allerdings klappt das nur wenn der Wert über das Editieren der Zelle verändert wird.

Wenn auch Copy/Paste abgedeckt werden soll, musst du mit einer Ereignis-Prozedur in VBA arbeiten, die dann wie folgt aussehen kann:

Code:

Private Sub Worksheet_Change(ByVal Target As Range)
Dim rngBereich                As Range
Dim rngZelle                  As Range
Set rngBereich = Intersect(Target, Range("A:B"))    'Bereich prüfen/festlegen
If Not rngBereich Is Nothing Then                'Abbruch wenn Änderung ausserhalb des Bereiches

        On Error GoTo ErrorHandler
        Application.EnableEvents = False
        For Each rngZelle In rngBereich

            With rngZelle
                If .Column = 1 Then              'Wenn in Spalte 1 geändert
                    If Len(.Value) <> 3 Then     'Gewünschte Länge vorgeben
                        MsgBox "Zelle " & .Address(0, 0) & " entspricht nicht der Längenvorgabe und wird gelöscht"
                        .ClearContents
                    End If
                Else                             'Wenn in Spalte 2 geändert.
                    If Len(.Value) <> 15 Then    'Gewünschte Länge vorgeben
                        MsgBox "Zelle " & .Address(0, 0) & " entspricht nicht der Längenvorgabe und wird gelöscht"
                        .ClearContents
                    End If
                End If
            End With
        Next rngZelle
    End If
ErrorHandler:
    Application.EnableEvents = True
End Sub