Office: Filter hinter Filter

Hallo zusammen,
ich habe zwei Tabellen, welche ich mit der FILTER Funktion auf einen neuen Reiter filtere.
Dabei möchte ich gerne die zweite Filterfunktion ans Ende der ersten Filter Funktion setzen.

Da die Zeilenanzahl der ersten Filterfunktion variabel ist, weiß ich nicht wie und wo ich die zweite hinsetze, damit am Ende die Daten alle schön untereinander stehen.

Gibt es eine Möglichkeit dies umzusetzen?

Vielen Dank,
Ron

 

Hola,
hast du ein konkretes Beispiel dazu?
Gruß,
steve1da

 

Hi,

dafür gibt es (noch in der Beta-Version) die Funktion VSTAPELN.

Einfaches (sinnfreies) Beispiel (weil man die beiden Filterungen natürlich auch miteinander verbinden kann):

1. Einträge aus A1:A10 filtern, bei denen in Spalte B ein x steht.
2. Einträge aus A1:A10 filtern, bei denen in Spalte B ein y steht.

Jetzt beide Einzelfilterergebnisse untereinander ausgeben:

=LET(x;FILTER(A1:A10;B1:B10="x");y;FILTER(A1:A10;B1:B10="y");VSTAPELN(x;y))

 

Einmal ein Beispiel im Anhang.

Wie aktiviere ich denn die Beta? Aber vermutlich wird das nichts da ich es in sharepoint online machen muss...

 

Hi,

zum Sharepoint kann ich Dir nix sagen. Grundsätzlich kannst Du Beta kostenlos freischalten, wenn Du die Abo-Version von xl365 hast.

Dein angehängtes Beispiel kapier ich nicht so ganz. Was soll wonach genau gefiltert werden und wie soll nachher genau die Ausgabe aussehen (bitte per Hand erzeugen!)?

 

Filterfunktion 1 erstellt diese Tabelle anhand des Filterkriterium Buchstabe "d" in Spalte 2.


Filterfunktion 2 erstellt diese Tabelle anhand des Filterkriterium Buchstabe "s" in Spalte 1.


Je nachdem, nach welchem Buchstaben ich Filter, ändert sich die Zeilenanzahl der Filterfunktion.

Am Ende sollen beide Funktionen untereinander stehen, egal wie viele Zeilen die obere Funktion hat.
D.h. keine leeren Spalten zwischen den beiden Funktionen

 

Hi,

OK - aber ich wiederhole mich: Genau dafür wurde die Funktion VSTAPELN eingeführt - bezogen auf Deine Beispielmappe:

=LET(x;FILTER(Tabelle2;Tabelle2[Spalte2]="d");y;FILTER(Tabelle24;Tabelle24[Spalte1]="s");VSTAPELN(x;y))

Ohne diese Funktion wird es sehr kompliziert. Einfacher wäre es, die beiden Tabellen zusammenzuführen und dann auf diese zusammengeführte Tabelle die FILTER-Funktion anzuwenden.

 

Hallo,

falls dein Excel365 bereits die LAMBDA()-Funktion enthält, habe ich dir behelfsweise die neue VSTAPELN()-Funktion, die Boris verwendet, im Namensmanager eingefügt.

Dann kannst du die Formeln von Boris oder auch die Versionen aus meiner Excel-Datei verwenden.

 

Hallo,

in Ergänzung zu meinem Posting #8:
Falls du weder die Funktion VSTAPELN() noch die Funktion LAMBDA() zur Verfügung hast, gibt es die Möglichkeit zB. in Zelle A30 folgende Formel einzugeben:
=LET(
m; FILTER(Tabelle2;Tabelle2[Spalte2]=F4);
n; FILTER(Tabelle24;Tabelle24[Spalte1]=F10);
zm; ZEILEN(m);
i; SEQUENZ(zm+ZEILEN(n));
j; SEQUENZ(;MAX(SPALTEN(m);SPALTEN(n)));
WENNFEHLER(WENN(i<=zm;INDEX(m;i;j);INDEX(n;i-zm;j));""))

wobei sich die beiden Filterkriterien wiederum in den Zellen F4 und F10 enthalten sind.

Datei samt Erklärung dazu liegt bei.