Office: Format für Vorwahlen

Hallo,

war wohl etwas spät. Hatte die neue Formel nicht in alle Zellen kopiert, und nicht einmal gespeichert. Daher hier was Neues:

Code:

=WENN(LINKS(Tabelle1!F2;3)="+49";Tabelle1!F2;WENN(ISTZAHL(WECHSELN(Tabelle1!F2;" ";"")*1);WENN(LINKS(Tabelle1!F2;2)="01";"+49("&TEIL(Tabelle1!F2;2;3)&")"&WECHSELN(TEIL(Tabelle1!F2;5;15);" ";"");"+49("&TEIL(INDEX(Tabelle3!$A:$A;VERGLEICH(Tabelle1!$E2;Tabelle3!$B:$B;0));2;99)&")"&WENN(LINKS(Tabelle1!F2;1)="0";WECHSELN(WECHSELN(Tabelle1!F2;INDEX(Tabelle3!$A:$A;VERGLEICH(Tabelle1!$E2;Tabelle3!$B:$B;0));"");" ";"");WECHSELN(Tabelle1!F2;" ";"")));"Korrigieren: "&Tabelle1!F2))

Gruß

Edgar

 

re

Hi!
danke dir, aber irgendwie steht nun häufig korrigieren in den feldern, teilweise auch in feldern welche das format +49(34604)03460412344555
besitzen. hm.

Gruß Nimus

 

Hallo,

kann ich nicht nachvollziehen:

Arbeitsblatt mit dem Namen 'Tabelle2'
	D	E	F
1	PnPlz	PnOrt	PnTelPrivat_15
2	06122	Halle	+49(345)4455342
3	06124	Halle	+49(345)8043212
4	06124	Halle	+49(345)6901669
5	06124	Halle	+49(345)8070649
6	06124	Halle	+49(345)8064308
7	06188	Landsberg	Korrigieren:
8	06124	Halle	+49(345)8043218
9	06124	Halle	+49(345)8064305
10	06124	Halle	+49(345)8043213
11	06116	Halle	+49(345)8043225
12	06124	Halle	+49(345)8043223
13	06254	Kötschlitz	+49(172)3622461
14	66571	Eppelborn	+49(6827)6901514
15	06124	Halle	Korrigieren: DIENSTL.2131992
16	06124	Halle	+49(345)8043219
17	06124	Halle	+49(171)3048900
18	06124	Halle	+49(345)8062703
19	06124	Halle	+49(345)8043232

Zelle

Formel

F2

=WENN(LINKS(Tabelle1!F2;3)="+49";Tabelle1!F2;WENN(ISTZAHL(WECHSELN(WECHSELN(Tabelle1!F2;" ";"");"/";"")*1);WENN(LINKS(Tabelle1!F2;2)="01";"+49("&TEIL(Tabelle1!F2;2;3)&")"&WECHSELN(WECHSELN(TEIL(Tabelle1!F2;5;15);" ";"");"/";"");"+49("&TEIL(INDEX(Tabelle3!$A:$A;VERGLEICH(Tabelle1!$E2;Tabelle3!$B:$B;0));2;99)&")"&WENN(LINKS(Tabelle1!F2;1)="0";WECHSELN(WECHSELN(Tabelle1!F2;INDEX(Tabelle3!$A:$A;VERGLEICH(Tabelle1!$E2;Tabelle3!$B:$B;0));"");" ";"");WECHSELN(Tabelle1!F2;" ";"")));"Korrigieren: "&Tabelle1!F2))

<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Gruß

Edgar

 

re

Hallo!

hab mal die mappe verändert und bereich mit der von dir bearbeiteten alten formel und daneben die neue formel.


Gruß Nimus

 

Hallo,

Problem ist, ich kann mit Excel2003 nicht alle Eventualitäten abdecken. Da in der Telefonnummer ein "-" steht, erkennt die Formel das als Fehler. Den Kompromiss muß ich eingehen zugunsten der Nummern mit Vorwahl.
Ich sehe momentan auch keine Möglichkeit, alles abzudecken, dafür ist in Excel2003 nicht genug Raum.

Gruß

Edgar

 

re

Hallo!

Ah ok, dann weiß ich bescheid. Fals ich noch fragen habe, werd ich sie einfach hier stellen und bedanke mich bei dir über deine erfolgreiche hilfe.

Gruß Nimus

 

Hallo Nimus,

ich habe durch umstellen noch etwas verbessern können:

Code:

=WENN(LINKS(Tabelle1!F2;3)="+49";Tabelle1!F2;WENN(LINKS(Tabelle1!F2;2)="01";"+49("&TEIL(WECHSELN(Tabelle1!F2;" ";"");2;3)&")"&TEIL(WECHSELN(WECHSELN(WECHSELN(Tabelle1!F2;" ";"");"/";"");"-";"");6;99);WENN(ISTZAHL(WECHSELN(WECHSELN(Tabelle1!F2;" ";"");"/";"")*1);"+49"&TEIL(INDEX(Tabelle3!A:A;VERGLEICH(Tabelle1!$E2;Tabelle3!B:B;0));2;9)&WECHSELN(WENN(LINKS(Tabelle1!F2;1)="0";WECHSELN(Tabelle1!F2;INDEX(Tabelle3!A:A;VERGLEICH(Tabelle1!$E2;Tabelle3!B:B;0));"");Tabelle1!F2);" ";"");WENN(Tabelle1!F2="";"";"korrigieren: "&Tabelle1!F2))))

Gruß

Edgar

 

re

Hallo!

Danke dir für die nochmalige Bearbeitung, aber da fehlen jetzt die klammern bei den vorwahlen^^. die erste habe ich mit eingebaut bekommen in deiner formel,aber die ) weiß ich nicht wohin^^.
also jede anweisung soll aufgezeigt werden und mit dem ergebnis dann halt mit der nächsten formel weiter editieren^^. und am ende soll halt das selbe ergebnis sein wie bis her, nur das halt wirklich alle nur eine vorwahl haben und nicht wie in manchen fällen 2mal auftauchen. und der text bei manchen feldern soll rausgenommen werden,aber in eine separate spalte eingefügt werden, da es sich vlt um wichtige notizen handeln können^^.
wenn du lust und laune hast^^, könntest du mir ja behilflich sein.

Danke dir erstmal.

Gruß Nimus

 

Hallo nimus,

ich bin auch kein Programmierer und habe das lösen können. Mit der Aufgabenstellung, die Du jetzt hast, solltest Du jetzt wohl alleine hinkommen. Für einen Ausbildungserfolg ist es sowieso besser, wenn man das Ganze selbst macht, dann versteht man es auch besser. Als Ausbilder unterstütze ich das sowieso nicht

Keine weiteren Antworten mehr von mir!

Gruß

Edgar

 

re

Hallo!

Danke dir trotzdem bis dahin.
ist kein bereich von meiner ausbildung. wie gesagt, danke trotzdem und müsste wie du schon sagtest es eh jetzt ohne hilfe hinbekommen.

Gruß Nimus

 

Hallo,

ich habe gerade meinen sozialen Tag:

Arbeitsblatt mit dem Namen 'Tabelle2'
	D	E	F	G	H	I	J	K
2	06122	Halle	4455342	4455342	4455342	+49(0345)4455342	+49(0345)4455342	+49(0345)4455342

Zelle	Formel
D2	=Tabelle1!D2
E2	=Tabelle1!E2
F2	=WECHSELN(WECHSELN(WECHSELN(Tabelle1!F2;" ";"");"/";"");"-";"")
G2	=WECHSELN(WENN(LINKS(F2;2)="01";"+49("&TEIL(F2;2;3)&")"&TEIL(F2;5;99);F2);" ";"")
H2	=WENN(LINKS(G2;1)="0";WECHSELN(G2;INDEX(Tabelle3!A:A;VERGLEICH(E2;Tabelle3!B:B;0));"+49("&TEIL(INDEX(Tabelle3!A:A;VERGLEICH(E2;Tabelle3!B:B;0));2;9)&")");G2)
I2	=WENN(ISTZAHL(H2*1);"+49("&INDEX(Tabelle3!A:A;VERGLEICH(E2;Tabelle3!B:B;0))&")";"")&H2
J2	{=WENN(LINKS(I2;4)="+49(";I2;TEIL(I2;MIN(FINDEN({1.2.3.4.5.6.7.8.9.0};I2&1234567890));ANZAHL(((TEIL(I2;MIN(FINDEN({1.2.3.4.5.6.7.8.9.0};I2&1234567890));SPALTE(3:3))*1)>=0)*1)))}
K2	=WENN(J2="";"";WENN(LINKS(J2;3)="+49";J2;"+49("&INDEX(Tabelle3!A:A;VERGLEICH(E2;Tabelle3!B:B;0))&")"&J2))

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]<table><tr><td>Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg</td></tr></table>[/parsehtml]

Gruß

Edgar

 

re

Hallo!

Danke dir, habs heute erst ausprobiert und klappt wunderbar! vielen dank an dich. nur noch eine frage, wie bekomme ich den text aus den zellen mit den zahlen? habe versucht nur die buchstaben zu erhalten mit deiner funktion mit der matrix aber no chance. ka.

Gruß Nimus