Office: Formel auf Schaltfläche anwenden?

Hallo zusammen,

ich arbeite mit Excel 2010 und habe ein Problem. Ich habe eine Tabelle, in der Wortkürzel aufgelistet und erklärt werden.
Da es mehrere hundert sind würde ich gerne eine Wortsuche integrieren.

Bis jetzt arbeite ich mit einer normalen Formel:
=HYPERLINK("#B"&MAX((B6:B999=B3)*ZEILE(6:999));"Suche beginnen")
die ich auf ein ganz normales Feld beziehe.

So kann ich in B3 das Wort eingeben- danach auf den Link "Suche beginnen" klicken - die Tabelle markiert mir dann aber nur das erste Wort. Außerdem benötige ich somit 2 Felder zur Wortsuche.

Was ich gerne hätte:

Der günstigste Fall wäre zwar ein Suchfeld mit Makro, in dem ich ein Kürzel eintrage und mir das Programm dann alle Felder mit diesem Wort markiert. Die Wörter die ich suchen möchte, befinden sich alle nur in einer Spalte (in meinem Fall B). Leider bin ich im VBA nicht ganz so fit und finde im Internet eigentlich nichts dazu, da es in jedem Code etliche Fehler gibt oder "ganz tolle" Funktionen, die ich aber alle nicht brauche.

Da außerdem viele Menschen an der Tabelle arbeiten und sie auch ständig verändert wird, ist eine normale Formel schon von Vorteil, da sie von mehr Leuten verstanden wird.

- Kann ich also die oben genannte Formel auf eine Schaltfläche beziehen?
- bzw. kann ich meine Such-Idee, für die ich bis jetzt 2 Felder benötige, in einem Feld vereinen?

Freue mich über Antworten, Verbesserungsvorschläge oder Links zu ähnlichen Themen, von denen ich leider keine entdeckt habe :)

 

Hi,

versuche es mal so:

Code:

Sub ZellinhaltSuchen()
    Dim rngZelle As Range
    Dim strSuchbegriff As String
    Dim strStart As String
    Dim bytWeiter As Byte
    Dim lngLetzte As Long
    strSuchbegriff = InputBox("Suchbegriff:")
    If strSuchbegriff <> "" Then
      lngLetzte = IIf(IsEmpty(Cells(Rows.Count, 2)), Cells(Rows.Count, 2).End(xlUp).Row, Rows.Count)
      With Range(Cells(3, 2), Cells(lngLetzte, 2))
         Set rngZelle = .Find(strSuchbegriff, lookat:=xlWhole, LookIn:=xlValues)
         If Not rngZelle Is Nothing Then
             strStart = rngZelle.Address
             Do
                 Application.Goto reference:=rngZelle, scroll:=True
                 bytWeiter = MsgBox("Weiter suchen?", vbOKCancel)
                 If bytWeiter = 2 Then Exit Do
                 Set rngZelle = .FindNext(rngZelle)
             Loop While Not rngZelle Is Nothing And rngZelle.Address <> strStart
         Else
           If rngZelle Is Nothing Then MsgBox "Suchbegriff nicht gefunden"
         End If
         Set rngZelle = Nothing
      End With
   End If
End Sub

Bis später,
Karin

 

Hi Karin,

besser hätte es nicht sein können.
Großes Lob, denn andere Seiten haben miir nur haufenweise Quatsch geschickt.

Vielen lieben Dank und viele Grüße,
Jonas