Office: Formel-Contest 365

Hallo zusammen,

Einträge in Spalte A sind sortiert. Gesucht ist eine Spill(!)Formel für die Hilfsspaltenlösung in Spalte B.
Was ist Euer Vorschlag? (Ich hab schon Formeln woanders online). Tobt Euch mal aus :-) Was ist euer Vorschlag?

 

Mein Problem war, dass

=ZÄHLENWENN(INDIREKT("A2:A"&ZEILE(2:16));INDIREKT("A"&ZEILE(2:16)))

wohl nur in der aktuellen Beta-Version funktioniert. Auch mit N() bzw. T() scheint die Formel nicht in allen Versionen zu laufen:

=ZÄHLENWENN(INDIREKT("A2:A"&ZEILE(2:16));WENN(ISTZAHL(A2:A16);N(INDIREKT("A"&ZEILE(2:16)));T(INDIREKT("A"&ZEILE(2:16)))))

Es wird ein Array aus Nullen erzeugt (zumindest in einigen Excelversionen).

Dann hab ich ne Alternative gebastelt - werde aber das Gefühl nicht los, dass das auch anders (einfacher) gehen müsste, da mir die Aufgabe eigentlich recht trivial erscheint:

=LET(x;ZÄHLENWENN(A2:A16;EINDEUTIG(A2:A16));y;MTRANS(TEXTTEILEN(TEXTKETTE(MAP(x;LAMBDA(a;TEXTVERKETTEN(";";;SEQUENZ(a;;1))&";")));";"));--FILTER(y;y<>""))

Würde mich halt interessieren, wie ihr das lösen würdet.

 

Hallo,

mein Vorschlag:
=LET(m;A2:A16; mv;VSTAPELN(""; m); SCAN("";SEQUENZ(ZEILEN(m)); LAMBDA(a; i; WENN(INDEX(mv; i) = INDEX(m; i); a+1; 1))))

 

Hallo,

nochmals geringfügig verkürzt:
=LET(m;A2:A16; n;VSTAPELN("";m); SCAN("";SEQUENZ(ZEILEN(m)); LAMBDA(a;i; WENN(INDEX(n;i)=INDEX(m;i);a;0)+1)))

 

Sehr gut! :-) SCAN hatte ich auch im Blick, hab mich da aber wohl verrannt ;-)
Andererseits sieht die Aufgabenstellung viel einfacher als die Lösung aus ;-)

VG, Boris

 

Hallo {Boris},

hier noch 1 Version mit REDUCE():

Code:

=LET(m;A2:A16;
n;VSTAPELN("";m);
WEGLASSEN(
   REDUCE("";
      SEQUENZ(ZEILEN(m));LAMBDA(a;i;
         VSTAPELN(a;WENN(INDEX(n;i)=INDEX(m;i);INDEX(a;ANZAHL2(a));0)+1)));1))

Daran ist auch gut zu erkennen, worin die Unterschiede zwischen SCAN() und REDUCE() liegen.

Gruß von Luschi
aus klein-Paris

 

Hallo,

mein Vorschlag.
=MAP(A1:A11;LAMBDA(a;LET(b;ZÄHLENWENN(a:A1;a);WENN(b>1;b;1))))

oder:
=BYROW(A1:A11;LAMBDA(a;LET(b;SUMME(N(A1:a=a));WENN(b>1;b;1))))

 

Hallo @HSV,

kann es sein, dass man deine beiden (Super-) Vorschläge noch weiter vereinfachen kann zu (angepasst an den vorgegebenen Bereich A2:A16):
=MAP(A2:A16;LAMBDA(a;ZÄHLENWENN(A2:a;a)))
bzw.
=NACHZEILE(A2:A16;LAMBDA(a;SUMME(N(A2:a=a))))

 

Hallo Anton,

Sehr schön.
Es ist wie mit den Handys: Die ersten waren groß.

 

Hi Anton,

genau das meinte ich mit "werde aber das Gefühl nicht los, dass das auch anders (einfacher) gehen müsste,"

Super!

 

=MAP(A2:A16;LAMBDA(a;SUMME(N(A2:a=a))))