Office: Formel-Contest 365

Helfe beim Thema Formel-Contest 365 in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, Einträge in Spalte A sind sortiert. Gesucht ist eine Spill(!)Formel für die Hilfsspaltenlösung in Spalte B. Was ist Euer Vorschlag?... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von {Boris}, 23. Juni 2024.

  1. {Boris} hat Ahnung

    Formel-Contest 365


    Hallo zusammen,

    Einträge in Spalte A sind sortiert. Gesucht ist eine Spill(!)Formel für die Hilfsspaltenlösung in Spalte B.
    Was ist Euer Vorschlag? (Ich hab schon Formeln woanders online). Tobt Euch mal aus :-) Was ist euer Vorschlag?
     
    {Boris}, 23. Juni 2024
    #1
  2. {Boris} hat Ahnung
    Mein Problem war, dass

    =ZÄHLENWENN(INDIREKT("A2:A"&ZEILE(2:16));INDIREKT("A"&ZEILE(2:16)))

    wohl nur in der aktuellen Beta-Version funktioniert. Auch mit N() bzw. T() scheint die Formel nicht in allen Versionen zu laufen:

    =ZÄHLENWENN(INDIREKT("A2:A"&ZEILE(2:16));WENN(ISTZAHL(A2:A16);N(INDIREKT("A"&ZEILE(2:16)));T(INDIREKT("A"&ZEILE(2:16)))))

    Es wird ein Array aus Nullen erzeugt (zumindest in einigen Excelversionen).

    Dann hab ich ne Alternative gebastelt - werde aber das Gefühl nicht los, dass das auch anders (einfacher) gehen müsste, da mir die Aufgabe eigentlich recht trivial erscheint:

    =LET(x;ZÄHLENWENN(A2:A16;EINDEUTIG(A2:A16));y;MTRANS(TEXTTEILEN(TEXTKETTE(MAP(x;LAMBDA(a;TEXTVERKETTEN(";";;SEQUENZ(a;;1))&";")));";"));--FILTER(y;y<>""))

    Würde mich halt interessieren, wie ihr das lösen würdet.
     
    {Boris}, 24. Juni 2024
    #2
  3. Exl121150 Erfahrener User
    Hallo,

    mein Vorschlag:
    =LET(m;A2:A16; mv;VSTAPELN(""; m); SCAN("";SEQUENZ(ZEILEN(m)); LAMBDA(a; i; WENN(INDEX(mv; i) = INDEX(m; i); a+1; 1))))
     
    Zuletzt bearbeitet: 24. Juni 2024
    Exl121150, 24. Juni 2024
    #3
  4. Exl121150 Erfahrener User

    Formel-Contest 365

    Hallo,

    nochmals geringfügig verkürzt:
    =LET(m;A2:A16; n;VSTAPELN("";m); SCAN("";SEQUENZ(ZEILEN(m)); LAMBDA(a;i; WENN(INDEX(n;i)=INDEX(m;i);a;0)+1)))
     
    Exl121150, 24. Juni 2024
    #4
  5. {Boris} hat Ahnung
    Sehr gut! :-) SCAN hatte ich auch im Blick, hab mich da aber wohl verrannt ;-)
    Andererseits sieht die Aufgabenstellung viel einfacher als die Lösung aus ;-)

    VG, Boris
     
    {Boris}, 24. Juni 2024
    #5
  6. Luschi Erfahrener User
    Hallo {Boris},

    hier noch 1 Version mit REDUCE():
    Code:
    =LET(m;A2:A16;
    n;VSTAPELN("";m);
    WEGLASSEN(
       REDUCE("";
          SEQUENZ(ZEILEN(m));LAMBDA(a;i;
             VSTAPELN(a;WENN(INDEX(n;i)=INDEX(m;i);INDEX(a;ANZAHL2(a));0)+1)));1))
    Daran ist auch gut zu erkennen, worin die Unterschiede zwischen SCAN() und REDUCE() liegen.

    Gruß von Luschi
    aus klein-Paris
     
    Luschi, 25. Juni 2024
    #6
    1 Person gefällt das.
  7. HSV
    HSV hat Ahnung
    Hallo,

    mein Vorschlag.
    =MAP(A1:A11;LAMBDA(a;LET(b;ZÄHLENWENN(a:A1;a);WENN(b>1;b;1))))

    oder:
    =BYROW(A1:A11;LAMBDA(a;LET(b;SUMME(N(A1:a=a));WENN(b>1;b;1))))
     
    Zuletzt bearbeitet: 25. Juni 2024
  8. Exl121150 Erfahrener User

    Formel-Contest 365

    Hallo @HSV,

    kann es sein, dass man deine beiden (Super-) Vorschläge noch weiter vereinfachen kann zu (angepasst an den vorgegebenen Bereich A2:A16):
    =MAP(A2:A16;LAMBDA(a;ZÄHLENWENN(A2:a;a)))
    bzw.
    =NACHZEILE(A2:A16;LAMBDA(a;SUMME(N(A2:a=a))))
     
    Exl121150, 26. Juni 2024
    #8
  9. HSV
    HSV hat Ahnung
    Hallo Anton,

    Sehr schön.
    Es ist wie mit den Handys: Die ersten waren groß.
     
  10. {Boris} hat Ahnung
    Hi Anton,

    genau das meinte ich mit "werde aber das Gefühl nicht los, dass das auch anders (einfacher) gehen müsste,"

    Super!
     
    {Boris}, 26. Juni 2024
    #10
  11. HSV
    HSV hat Ahnung

    =MAP(A2:A16;LAMBDA(a;SUMME(N(A2:a=a))))
     
    1 Person gefällt das.
Thema:

Formel-Contest 365

Die Seite wird geladen...
  1. Formel-Contest 365 - Similar Threads - Formel Contest 365

  2. Formel mit INDEX, MATCH und MAX gibt Fehler #NAME!

    in Microsoft Excel Hilfe
    Formel mit INDEX, MATCH und MAX gibt Fehler #NAME!: Hallo zusammen, ich habe mit Hilfe von Copliot eine Formel gebaut, die 2 Werte aus einer Tabelle 1 in einer Tabelle 2 prüfen soll und wenn die Konstellation vorkommt, soll das größte Wert dieser...
  3. Hilfe gesucht bei Fertigstellung einer Formel

    in Microsoft Excel Hilfe
    Hilfe gesucht bei Fertigstellung einer Formel: Ich habe einen Stundenzettel erstellt und stehe gerade vor einem kleinen Problem mit meiner Excelformel. Es geht um 3 Spalten im Stundenzettel. Ich habe für die automatische Berechnung des...
  4. Hilfe gesucht, Formel bauen, (Wenn,Dann, 3 Bedingungen, 3 Ergebnisse) )

    in Microsoft Excel Hilfe
    Hilfe gesucht, Formel bauen, (Wenn,Dann, 3 Bedingungen, 3 Ergebnisse) ): Moin, ich könnte mal Hilfe beim Formelbauen gebrauchen. Excel ist mir zwar nicht neu, aber Formeln erstellen habe ich fast noch nie gemacht. Ich wollte eigentlich die Tabelle hier anhängen, aber...
  5. automatische Formelanpassung

    in Microsoft Excel Hilfe
    automatische Formelanpassung: Hallo Excel Spezialisten Bin dankbar für eure Hilfe zu folgender Situation: In einem Arbeitsblatt mit Spalte A, beginnend mit A4, habe ich in Spalte C einen Produktionswert auch ab C4. Der Wert...
  6. VBA Code Anpassen "Wert Einfügen statt Formel"

    in Microsoft Excel Hilfe
    VBA Code Anpassen "Wert Einfügen statt Formel": Hallo alle zusammen. Ich benötige bitte Hilfe von einem Experten, da ich mit meinem Code unzufrieden bin und dieser bei größeren Datenmengen respektive Zeilen ziemlich langsam wird. Wie müsste man...
  7. Formel auf andere Zellen unterschiedlicher Größe anwenden

    in Microsoft Excel Hilfe
    Formel auf andere Zellen unterschiedlicher Größe anwenden: Hallo zusammen, ich habe eine Formel gebastelt, die wie angehängt in der Beispiel-Excel zu sehen ist, funktioniert. Kann ich die Formel so vereinfachen, dass ich nicht 3x die angepasste Formel...
  8. Summewenns erkennt text aus der formel nicht

    in Microsoft Excel Hilfe
    Summewenns erkennt text aus der formel nicht: Hallo zusammen, ich habe ein Problem das meine Formel Summewenns nicht den ausgegebenen Text in der Zelle erkennt!! Bekomme das einfach nicht hin. In der Zelle B8:B60 wird der Monat mit einer...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden