Office: (Office 365) Formel Optimierung

Hallo ihr lieben Wissenden,

ich habe ein, ich glaube etwas umständliches Formelkonstrukt,
welches eigentlich auch macht was es soll.
Aber ich frage mich ob das nicht irgendwie einfacher geht.
Ich hab vieles versucht, habe es einfach nicht hinbekommen.

Code:

X4=WENNNV(XVERWEIS(Z4;'Tabelle2'!Z:Z;'Tabelle2'!A:A);"NEU")
Y4=WENNNV(XVERWEIS(Z4&D4;'Tabelle2'!Z:Z&'Tabelle2'!D:D;'Tabelle2'!A:A);"geändert")
O4=WENN(X4="NEU";"NEU";WENN(Y4="geändert";"geändert";""))

Mein Versuch war es, die beiden Formeln aus X und Y zu einer zusammen zu bekommen. Ergebnis in X oder Y

wenn in Tabelle2(Z:Z), Z4 vorhanden und D4 in Tabelle2(D:D) sind unterschiedlich dann "geändert";
wenn in Tabelle2(Z:Z), Z4 nicht vorhanden dann "NEU";
wenn in Tabelle2(Z:Z), Z4 vorhanden und D4 in Tabelle2(D:D) vorhanden dann Wert aus Tabelle2(A:A)

Oh je, ich glaube ich lasse es einfach wie es ist. Habe ja beim formulieren meines Ziels schon wieder einen Knoten im Kopf. Vlt. ist es dennoch einfacher als ich mich anstelle.

 

Muahh...
ich glaube fast hab ich es. So beim Schreiben meines Wunsches kam mir die Idee

Code:

=WENN(ZÄHLENWENN('Tabelle2'!Z:Z;Z4)<1;"NEU";WENN(UND(ZÄHLENWENN('Tabelle2'!Z:Z;Z4)>0;ZÄHLENWENN('Tabelle2'!D:D;D4)<1);"geändert";XVERWEIS(Z4;'Tabelle2'!Z:Z;'Tabelle2'!A:A)))

Muss ich noch weiter testen

P.S.
Aus dem Bauch raus denke ich, es ist nicht gewährleistet das die gefundenen Z und D auch in einer Zeile gefunden wurden, oder ? / bei meiner MehrzellenLösung allerdings auch nicht.
gibt es dafür noch eine Lösung?

 

Hola,
das
WENN(UND(ZÄHLENWENN('Tabelle2'!Z:Z;Z4)>0;ZÄHLENWENN('Tabelle2'!D:D;D4)<1);"geändert"
kannst du verkürzen:
...;wenn(zählenwenns(Tabelle2!Z:Z;Z4;Tabelle2!D:D;D4)=0;"geändert";.....
Damit ist auch gewährleistet, dass beide Werte in immer der gleichen Zeile gesucht werden.
Gruß,
steve1da

 

Hallo steve,
danke für den Schubs,
aber ist bei deiner Lösung dann nicht auch Z = 0 und nicht > 0 ?

 

Am besten wäre eine Beispieldatei mit ein paar Varianten und händisch eingetragenem Wunschergebnis.

 

Hallo steve,

das mit der Beispieldatei klappt nicht so einfach.
ABER
dank deine Inspiration habe ich eine bei mir funktioierende Variante hinbekommen.

Code:

=WENN(ZÄHLENWENN('Tabelle2'!Z:Z;Z4)<1;"NEU";WENN(UND(D4<>"";ZÄHLENWENNS('Tabelle2'!Z:Z;Z4;'Tabelle2'!D:D;D4)=0);"geändert";XVERWEIS(Z4;'Tabelle2'!Z:Z;'Tabelle2'!A:A)))

Nochmals Danke und einen schönen Tag

 

Hier eine Lösung mit FILTER:

Code:

=LET(x;FILTER(Tabelle2!A:D;Tabelle2!Z:Z=Z4);y;FILTER(x;SPALTENWAHL(x;-1)=D4);WENN(ISTFEHLER(SPALTENWAHL(x;1));"NEU";WENNFEHLER(SPALTENWAHL(y;1);"geändert")))

 

Hallo Helmut,
danke für die aufgezeigte Alternative (theoretisch)
Leider stüzt mein Excel beim eingeben der Formel reproduzierbar, kommentarlos ab. (warum auch immer)
Bleibe dann bei der #6 Formel, die macht ihren Job.
Liebe Grüße
Cam

 

Auch FILTER zeigt sich manchmal (oder eher: oft!) etwas empfindlich (wenn nicht nur langsam) bei Vollspaltenbezügen! Anpassen!

Wenn man schon mit LET arbeitet, kann man doch die letzte verwendete Zeile gleich am Anfang ermitteln und dann mit ihr arbeiten.

 

Man könnte auch einfach, so wie es sich gehört, Strg-T-Tabellen verwenden. Und vor allgemeine Beispieldatei zur Verfügung stellen…

 

gelöscht