Office: Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel

Helfe beim Thema Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo zusammen, ich hoffe mal wieder auf eine gute Idee oder eine Hilfe aus dem Forum. Ich habe mal einen kleinen Ausschnitt meiner Datei hochgeladen,... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von herma, 2. Januar 2023.

  1. herma Erfahrener User

    Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel


    Hallo zusammen,

    ich hoffe mal wieder auf eine gute Idee oder eine Hilfe aus dem Forum. Ich habe mal einen kleinen Ausschnitt meiner Datei hochgeladen, die ich erstellt habe. Mir geht es um eine Formel die ich in mehreren Zellen verwende und die dafür sorgt, dass Excel sich minutenlang aufhängt. Sowohl beim Öffnen als auch bei jedem Klick verbraucht Excel alle Prozessorkaüazitäten für mehrere Minuten.

    Es geht um die Formel in Tabelle 3 z.b. in Zelle N5.

    =ZÄHLENWENNS(Tabelle1!G:G; "01.01.2023"+ZEILE(B2)-1;Tabelle1!F:F;"*Bearbeitung*")-SUMMENPRODUKT((Tabelle1!G:G=--"01.01.2023"+ZEILE(B2)-1)*
    ISTZAHL(SUCHEN("Bearbeitung";Tabelle1!F:F))*ISTZAHL(SUCHEN("Abgeschlossen";Tabelle1!H:H&Tabelle1!J:J&Tabelle1!L:L&Tabelle1!N:N&Tabelle1!P:P)))

    Kurz gesagt: Hier wird gezählt, wenn in Tabelle 1 etwas in Bearbeitung gesetzt wird und wenn es in einer späteren Spalte als abgeschlossen gekennzeichnet wird, wird es nicht mehr als in Bearbeitung gezählt. Die Formel funktioniert, führt aber zu den genannten Problemen.

    Meine Frage, hat jemand eine Idee, wie ich vielleicht mit einer einfacheren Formel trotzdem zum Ziel komme? So dass Excel sich nicht komplett aufhängt, ich meine Auswertung aber trotzem bekomme?

    Ich habe die Formel schon mit Hilfe des Forums erstellt und es wäre echt super, wenn jemand Ideen hat, wie ich es vielleicht hinbekommen kann, ohne dass Excel sich total aufhängt.

    Vielen Dank schonmal im Voraus für jede Beteiligung....
     
  2. lupo1
    lupo1 Tutorial Guru
    Statt G:G nimm G$1:G$999 und entsprechend!
     
  3. herma Erfahrener User
    Vielen Dank für den schnellen Tipp Lupo1.......ich habe es alles angepasst und es sieht auf den ersten Blick deutlich deutlich besser aus. Ich werde das jetzt nochmal genauer testen und beobachten, ob sich das Problem aufgelöst hat.
     
  4. HKindler
    HKindler hat Ahnung

    Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel

    Hi,

    du kannst auch deine Tabelle mit Strg-T in eine intelligente Tabelle umwandeln. Allerdings kannst du sie dann nicht mehr frei geben. Der Vorteil dabei ist aber, dass du dann deine Formel automatisch auf den korrekten Bereich beschränken kannst:
    =ZÄHLENWENNS(Tabelle1[Datum]; "01.01.2023";Tabelle1[1. Bearbeitung];"*Bearbeitung*")-SUMMENPRODUKT((Tabelle1[Datum]=--"01.10.2023")*
    ISTZAHL(SUCHEN("Bearbeitung";Tabelle1[1. Bearbeitung]))*ISTZAHL(SUCHEN("Abgeschlossen";Tabelle1[2. Bearbeitung]&Tabelle1[3. Bearbeitung]&Tabelle1[4. Bearbeitung]&Tabelle1[5. Bearbeitung]&Tabelle1[6. Bearbeitung])))


    Wenn es schneller werden soll, dann kannst du auch in deiner Ausgangstabelle eine weitere Spalte z.B. "Status" einfügen. Dorthin schreibst du dann die Formel:
    =WENN(ISTZAHL(SUCHEN("Abgeschlossen";TEXTVERKETTEN("";;Tabelle1[@[2. Bearbeitung]:[6. Bearbeitung]])));"Abgeschlossen";WENN([@[1. Bearbeitung]]="Bearbeitung";"Bearbeitung";""))
    bzw. wenn du keine Strg-T-Tabelle verwenden willst
    =WENN(ISTZAHL(SUCHEN("Abgeschlossen";TEXTVERKETTEN("";;H2:P2)));"Abgeschlossen";WENN(F2="Bearbeitung";"Bearbeitung";""))
    Und falls dein Excel noch kein Textverketten kennt
    =WENN(ISTZAHL(SUCHEN("Abgeschlossen";H2&J2&L2&N2&P2));"Abgeschlossen";WENN(F2="Bearbeitung";"Bearbeitung";""))

    Mit Hilfe dieser Spalte (nehmen wir an, der Status steht in Spalte R) wird dann deine Ursprungsformel zu
    =ZÄHLENWENNS(Tabelle1[Datum]; "01.01.2023"+ZEILE(B2)-1;Tabelle1[Status];"Bearbeitung")
    bzw.
    =ZÄHLENWENNS(Tabelle1!G:G; "01.01.2023"+ZEILE(B2)-1;Tabelle1!R:R;"Bearbeitung")
    Hier kannst du dann ungestraft auch wieder die komplette Spalte referenzieren und daher auf die Strg-T-Tabelle verzichten und die Mappe frei geben.
     
    HKindler, 3. Januar 2023
    #4
Thema:

Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel

Die Seite wird geladen...
  1. Formel vereinfachen, aktuelle Formel führt zu extrem langen Ladezeiten bei Excel - Similar Threads - Formel vereinfachen aktuelle

  2. Formel gesucht

    in Microsoft Excel Hilfe
    Formel gesucht: Hallo zusammen, ich möchte Kosten mittels eines manuell eingebbaren Schlüssels umlegen. Allerdings sollen diese dann nur innerhalb eines Bereichs umgelegt werden. Ich habe euch meine Datei...
  3. Hilfe bei Formel-Vereinfachung/-Kürzung

    in Microsoft Excel Hilfe
    Hilfe bei Formel-Vereinfachung/-Kürzung: Hallo zusammen, ich stehe gerade auf dem Schlauch bei der Vereinfachung/Kürzung einer Formel. Mein aktuelles Ziel ist es in Excel die Umsätze bei der Einstellung neuer Vertriebsmitarbeiter zu...
  4. Formel vereinfachen

    in Microsoft Excel Hilfe
    Formel vereinfachen: Hallo, ich hab mal eine Frage, kann man folgende Formel auch vereinfachen? Ich stehe gerade etwas auf dem Schlauch. =WENN(A4="";"";WENN(UND(ODER(A4="A4 Farbe";A4="A3 Farbe";A4="A4 sw";A4="A3...
  5. WENN Formel vereinfachen

    in Microsoft Excel Hilfe
    WENN Formel vereinfachen: Hallo, ich habe ein Anliegen bei folgende Ausgangslage: Tabelle1 ist eine Datenbank und in Tabelle2 werden gezielt Daten aus Tabelle1 ausgegeben In Tabelle2 hat Zelle C1 folgende Formel...
  6. Formel-Vereinfachung

    in Microsoft Excel Hilfe
    Formel-Vereinfachung: Guten Morgen, da ich in Excel nur begrenzte Fähigkeiten beim Benutzen von Formeln habe, wollte ich euch als Experten einfach mal fragen, ob die folgende Formel (die zwar schon funktioniert) nicht...
  7. Wie kann ich dieses system in eine formel vereinfachen

    in Microsoft Excel Hilfe
    Wie kann ich dieses system in eine formel vereinfachen: hallo, ich möchte das wenn ich in eine zelle z.b. "5" scheibe er in eine andere "15" ausgebit und bei "10" "55" . nach folgendem system (gibts bestimmt einen namen den ich aber nicht kenne)...
  8. Formel vereinfachen - bitte um Hilfe

    in Microsoft Excel Hilfe
    Formel vereinfachen - bitte um Hilfe: Hallo, ich sitze gerade an nem Knackpunkt und kommt nicht so ganz weiter....
Schlagworte:
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden