Office: Formel-Vereinfachung

Guten Morgen,
da ich in Excel nur begrenzte Fähigkeiten beim Benutzen von Formeln habe, wollte ich euch als Experten einfach mal fragen, ob die folgende Formel (die zwar schon funktioniert) nicht etwas einfacher gestalltet werden kann?

Zur einfacheren und vor allem schnelleren Übersicht, habe ich alle absoluten Bezüge ($) und Arbeitsblätter (vor der Zelle) entfernt.

Code:

=WENN(Q2="X";
WENN(T2="X";
WENN(K2="X";(E3+3-(U2*5*E1)-S2);(D3+3-(U2*5*D1)-S2));
WENN(K2="X";(E3-(U2*5*E1)-S2);(D3-(U2*5*D1)-S2))
);
WENN(T2="X";
WENN(K2="X";(E3+3-(U2*5*E1)-S2)+P2;(D3+3-(U2*5*D1)-S2)+P2);
WENN(K2="X";(E3-(U2*5*E1)-S2)+P2;(D3-(U2*5*D1)-S2)+P2))
)

Die Prüfung auf das "X" soll so eine Art Flag sein, wie z.B. eine Checkbox, wobei ich sowas bei Excel nicht kenne. Möglicherweise ne VB-Sache?

Ich würde mich über kreative Anregungen freuen.
Sollte ich als Neuling hier irgendwas falsch gemacht haben, bitte ich um Rücksicht und will mich gerne bessern.

Grüße, tonder

P.S.: Ich besitze übrigens auch noch Excel 2003 auf einem anderen PC, falls es nötig/einfacher ist. ;)

 

die Formel ist meiner Meinung nach nicht korrekt. Du schreibst wenn K2="X", dann mache dies ansonsten wenn K2="X" das ist schon geprüft

 

Ähm, nein.

Ich prüfe doch zuerst auf Q2, in Abhängigkeit davon prüfe ich auf T2 und je nachdem, ob T2 ein "X" enthält oder nicht, soll noch mal auf K2 geprüft werden. Je nachdem, ob dann K2 ein "X" enthält oder nicht, soll entweder +3 am Anfang gerechnet werden oder eben nicht.

Das ganze ich ja nichts anderes, als ne 3-fache if-Abfrage, quasi verschachtelt.

 

Hat denn niemand eine Anregung oder Idee?
Mir würde auch helfen, wenn ich von mehreren ein "Nein" höre, damit ich weiß, dass es nicht besser geht.

 

Hallo,

als ich stimme Hajo zu. Die Formel ist Quark.
Poste doch mal ne Bsp.-Datei (mit dem Format vom anderen Rechner :-D ) und erläutere dazu nochmals in Worten, was die Formel so tun muss!

 

Hallo,

zerlegt man die WENNs in nachfolgende hierarchische Struktur:

	A	B	C	D	E	F	G
2	=WENN(
3		Q2="X"	WENN(
4				[color=blue][b]T2="X"[/b][/color]	WENN(
5						K2="X"	(E3[color=blue][b]+3[/b][/color]-(U2*5*E1)-S2)
6						K2<>"X"	(D3[color=blue][b]+3[/b][/color]-(U2*5*D1)-S2)
7					);
8				T2<>"X"	WENN(
9						K2="X"	(E3-(U2*5*E1)-S2)
10						K2<>"X"	(D3-(U2*5*D1)-S2)
11					)
12			);
13		[color=red][b]Q2[/b][/color][color=red][b]<[/b][/color][color=red][b]>"X"[/b][/color]	WENN(
14				[color=blue][b]T2="X"[/b][/color]	WENN(
15						K2="X"	(E3[color=blue][b]+3[/b][/color]-(U2*5*E1)-S2)[color=red][b]+P2[/b][/color]
16						K2<>"X"	(D3[color=blue][b]+3[/b][/color]-(U2*5*D1)-S2)[color=red][b]+P2[/b][/color]
17					);
18				T2<>"X"	WENN(
19						K2="X"	(E3-(U2*5*E1)-S2)[color=red][b]+P2[/b][/color]
20						K2<>"X"	(D3-(U2*5*D1)-S2)[color=red][b]+P2[/b][/color]
21					)
22			)
23	)
24

erkennt man unschwer, dass Q2<>"X" die Addition von P2 zur Folge hat und dass T2="X" die Addtion von 3 bewirkt. Ferner kann man das S2 noch aus den WENNs herausziehen und die Klammern aus Spalte G weglassen, sodass sich die Formel vereinfacht zu:

Code:

=WENN(K2="X";E3-U2*5*E1;D3-U2*5*D1) - S2 + WENN(Q2="X";0;P2) + WENN(T2="X";3)

 

Die Formel ist kein Quark, nur etwas zu umständlich aufgestellt, siehe "Exl121150"s Erläuterung.

Ich bedanke mich recht herzlich. Bei allem inhaltlichen hin und her bin ich gar nicht drauf gekommen den reinen Rechenweg zu nehmen und bei jeder einzelnen Position eine WENN-Abfrage zu machen. Ich hatte es ja alles doppelt abgefragt, auch wenn meins ja ebenfalls funktionierte. Also nochmal DANKE. Die überflüssigen Klammern hatte ich übrigens nur der Übersicht halber gesetzt. ;)
Hab jetzt alle absoluten Bezüge u.s.w. angepasst und nun sieht es richtig schick und vor allem übersichtlich aus.

Code:

=S2
+ WENN(Q2="X";0;P2)
- WENN($K3="X";Seite1!$E$3-U2*5*Seite1!$E$1;Seite1!$D$3-U2*5*Seite1!$D$1)
- WENN(T2="X";3;0)

*closed*