Office: Formelproblem mit Datum und Sortierbezug

Hab zwei Bedingungen zur Abfrage wie auf dem Bild beschrieben.
Wie muss die Formel lauten?

 

ich benutze nun schon 2010, aber selbst diese Version kann aus einem Bild keine tabelle erstelen. Warum solich die Zet in die erstellung investieren, das hast Du doch schon.

 

Sorry,bin neu hier.
Im Anhang die xls Datei. Ich benötige nur die Formel für die Tabelle.
Danke Buffi

 

=SUMMENPRODUKT((B3:B13>="01.05.2010"*1)*(B3:B13<="31.05.2010"*1)*(C3:C13>10000)*(E3:E13))

 

Danke ,
funktioniert.

Wenn nun in Spalte E in irgend einer Zelle keine Zahl sondern ein Buchstabe "s" steht, dann funktionierts nicht mehr. Kann man dieses auch noch mit einbinden?
Gruß Buffi

 

ich bin nicht der Formelmensch.
Folgende Array Formel
=SUMME(WENN(ISTFEHLER((B3:B13>="01.05.2010"*1)*(B3:B13<="31.05.2010"*1)*(C3:C13>10000)*(ISTZAHL(E3:E13))*E3:E13)=FALSCH;(B3:B13>="01.05.2010"*1)*(B3:B13<="31.05.2010"*1)*(C3:C13>10000)*(ISTZAHL(E3:E13))*E3:E13))
Eingbae mit Strg+Umschalt+Enter

 

Hallo!

So sollte es auch funktionieren:

=SUMMENPRODUKT((MONAT(B3:B13)=5)*(C3:C13>10000);E3:E13)

 

Hallo!
@schatzi Formel hat auch funktioniert. Habe diese nun auf ein Quartal abgeändert. Leider funktionierts da nicht mehr. Mache ich da noch was falsch?
Danke

=SUMMENPRODUKT((MONAT(B3:B402)=1)+(MONAT(B3:B402)=2)+(MONAT(B3:B402)=3)*(C3:C402>10000);e3:e402)

 

Hallo!

Auch Excel rechnet "Punkt vor Strich"! Daher fehlt noch ein Klammerpaar:

=SUMMENPRODUKT(((MONAT(B3:B402)=1)+(MONAT(B3:B402)=2)+(MONAT(B3:B402)=3))*(C3:C402>10000);e3:e402)

offTopic:
Zum Thema "Quartal" kannst du auch mal hier schauen:
http://excelformeln.de/formeln.html?welcher=175

 

Ja super,
jetzt fehlt nur noch eine Kleinigkeit

Spalte
B = Datum
C = Rechnungsnummer
E= Betrag
P= MwSt.

jetzt wenn ich noch unterscheiden könnte zwischen 19% und keiner MwSt.(Österreich)
dann bin ich restlos bedient.
Spalte P mit MwSt. ist bereits vorhanden
Ich werte diese noch nicht mit aus, also Steuer vorhanden oder keine vorhanden 0EUR

=SUMMEWENN(C3:C402;">10000";P3:P402)

=SUMMENPRODUKT(((MONAT(B3:B402)=1)+(MONAT(B3:B402)=2)+(MONAT(B3:B402)=3))*(C3:C402>10000);e3:e402)

 

Hallo!

Das braucht eigentlich nur als zusätzliche Abfrage mit rein, oder nicht?

=SUMMENPRODUKT(((MONAT(B3:B402)=1)+(MONAT(B3:B402)=2)+(MONAT(B3:B402)=3))*(C3:C402>10000)*(P3:P402>0);e3:e402)

 

Super, funktioniert.
Vielen Dank