Office: Formulardaten speichern - lesen

Hallo,

ich habe ein Formular in VB in EXCEL erstellt.

Jetzt möchte ich "Datensätze" speichern und zwar in einem Excelsheet.
Diese Daten möchte ich auch wieder auslesen können in das Formular.

Im Excelsheet soll sowas dann stehen:
1;Herbert;Müller
2;Franz;Berger
3;Helga;Brun;
...

usw


Weis jemand hilfreiche methoden??? Bin totalle VB-Neuling

Danke

 

Hallo,

ich nehme an, dass Du mehrere Textfelder angelegt hast, zB.:
Textfeld 'txtNr', um Deine Satznummer aufzunehmen
Textfeld 'txtVorname', um den Vornamen aufzunehmen
Textfeld 'txtNachname', um den Familiennamen aufzunehmen, usw.
ferner nehme ich an, dass Du mehrere Buttons angelegt hast im Formular, zB.:
Button 'cmdVorher', um den vorhergehenden Satz auswählen zu können,
Button 'cmdNachher', um den nächsten Satz auswählen zu können,
Button 'cmdSchließen', um das Formular zu schließen (=verbergen), usw.
ferner nehme ich an, dass du im Arbeitsblatt eine Tabelle hast, zB.:
in Spalte A ab Zelle A2, um die Satznummern zu speichern
in Spalte B ab Zelle B2, um die Vornamen zu speichern
in Spalte C ab Zelle C2, um die Familiennamen zu speichern, usw.

dann benötigst Du im Codemodul der UserForm folgendes Makro:

Code:

Option Explicit
Dim Zl As Range

Private Sub UserForm_Initialize()
  Set Zl = Sheets("Tabelle1").Range("A2:C2")
  SetSatzfelder
End Sub
Private Sub UserForm_Activate()
  UserForm_Initialize
End Sub
Private Sub UserForm_Terminate()
  Set Zl = Nothing
End Sub
'-------------
Private Sub cmdVorher_Click()
  If Zl.Row>2 Then Set Zl = Zl.Offset(-1)
  SetSatzfelder
End Sub
Private Sub cmdNachher_Click()
  Set Zl = Zl.Offset(1)
  SetSatzfelder
End Sub
Private Sub cmdSchließen_Click()
  Me.Hide
End Sub
'------------
Private Sub SetSatzfelder()
  txtNr.ControlSource = Zl.Columns(1).Address
  txtVorname.ControlSource = Zl.Columns(2).Address
  txtNachname.ControlSource = Zl.Columns(3).Address
End Sub

Ins Arbeitsblatt, in dem Du die Sätze gespeichert hast, fügst Du einen ActiveX-Button ein, der dazu dient, die UserForm zu öffnen. Auf diesen machst Du einen Rechtsklick mit der Maus, wählst 'Code anzeigen' aus, sodass sich der VBA-Editor öffnet und die Button_Click-Prozedur anzeigt: in diese fügst Du den Formularaufruf ein: Formularname.Show (wobei Formularname der Name ist, der im Projektexplorer des VBA-Editors für das Formular angezeigt wird).

Das wäre im Prinzip alles, was anzulegen ist. Dieses Demo-Beispiel ist natürlich noch beliebig ausbaufähig.

Wenn Du zB. noch weitere Felder (=Spalten) im Arbeitsblatt ansprechen willst, müsstest Du noch weitere Felder ins Formular aufnehmen. Damit diese dann einen Inhalt haben, müsstest Du im Formularcode in der Sub SetSatzfelder() die entsprechenden Programmzeilen für die zusätzlichen Spalten/Felder ergänzen und ebenfalls in der Sub Userform_Initialize() den Bereich "A2:C2" erweitern auf zB. "A2:D2".

Eine zentrale Variable im obigen Makrocode ist die Variable 'Zl': sie ist ein Bereichsobjekt und stellt im Arbeitsblatt genau den Zeilenbereich dar, in dem 1 Datensatz (=Zeile) enthalten ist (deshalb auch ihr Name 'Zl' für 'Zeile').
Durch die Subs für die beiden Buttons 'cmdVorher' und 'cmdNachher' wird dieser Zeilenbereich zeilenweise nach oben bzw. nach unten verschoben.

 

vielen Dank für die ausführliche Hilfe, ich denke jetzt kriege ich das hin.