Office: Geburtstag Liste

Helfe beim Thema Geburtstag Liste in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Ich habe eine Tabelle wo die Geburtstage drin stehen Dann möchte ich mir die top 5 der nächsten Geburtstage anzeigen lassen das klappt auch alles gut... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Wedaustadion, 7. Dezember 2023.

  1. Geburtstag Liste


    Ich habe eine Tabelle wo die Geburtstage drin stehen
    Dann möchte ich mir die top 5 der nächsten Geburtstage anzeigen lassen das klappt auch alles gut

    nur wenn 2 Leute am selben Tag Geburtstag haben dann wir in der Top 5 Liste 2x der gleiche Namen angezeigt

    wie kann man das umgehen?
     
    Wedaustadion, 7. Dezember 2023
    #1
  2. steve1da Office Guru
    Hola,
    mit einer Formel.
    Gruß,
    steve1da
     
    steve1da, 7. Dezember 2023
    #2
  3. RPP63_neu hat Ahnung
    Ergänzend:
    Zeige was Du bereits hast.
    Welche Excel-Version?
    Ich habe was für alle Geburtstage vom letzten bis zum nächsten Arbeitstag.
    Code:
    =LET(t;"MMTT";
    g;TEXT($A$2:$A$2000;t);
    f;FILTER($A$2:$C$2000;(g>=TEXT(G1;t))*(g<=TEXT(G3;t)));
    SORTIERENNACH(f;TEXT(SPALTENWAHL(f;1);t)))
    Geburtstag Liste C5DcfSo.png

    Gruß Ralf
     
    RPP63_neu, 7. Dezember 2023
    #3
  4. Geburtstag Liste

    Das ist die Datei
    Es geht um die Top 5 Geburtstage
    Die in gelb haben am gleichen Tag Geburtstag
     
    Wedaustadion, 7. Dezember 2023
    #4
  5. Exl121150 Erfahrener User
    Hallo,

    unter der Voraussetzung von Excel365 führt folgende Formel
    =VSTAPELN(HSTAPELN("Alter";"Name";"Wann"); SPALTENWAHL(ÜBERNEHMEN(SORTIEREN(Tabelle1;13;1);5);4;2;13))

    zu diesem Ergebnis:
    Geburtstag Liste upload_2023-12-7_14-44-47.png
    wobei ich die 3. Spalte (Wann) mit dem benutzerdefinierten.Format
    "in" 0" Tagen"
    versehen habe. Allerdings funktioniert obige Formel nicht in einer struktur.Tabelle (Top5Geb)
     
    Exl121150, 7. Dezember 2023
    #5
  6. In der Formel auf welche Tabelle wird zugegriffen?
    Tabelle1;13;1);5);4;2;13))
    das Ende verstehe ich nicht.
     
    Wedaustadion, 7. Dezember 2023
    #6
  7. Exl121150 Erfahrener User
    Hallo,

    1) Mit SORTIEREN(Tabelle1;13;1) wir die struktur.Tabelle "Tabelle1" (in A3:P32) nach der 13. Spalte ("Geburtstag in" - Spalte M) aufsteigend sortiert.
    2) Mit ÜBERNEHMEN(SORTIEREN(Tabelle1;13;1);5) werden die ersten 5 Zeilen der sortierten Tabelle aus 1) herangezogen.
    3) Mit SPALTENWAHL(ÜBERNEHMEN(SORTIEREN(Tabelle1;13;1);5);4;2;13) wird die 4., die 2. und die 13. Spalte der 5zeiligen Tabelle aus 2) herausgegriffen (das sind: die Spalte D = "Alter", die Spalte B = "Name" und die Spalte M = "Geburtstag in"). Das sind ja genau die 3 Spalten, die du haben willst.
    4) Mit =VSTAPELN(HSTAPELN("Alter";"Name";"Wann"); SPALTENWAHL(ÜBERNEHMEN(SORTIEREN(Tabelle1;13;1);5);4;2;13)) wird dann noch eine Kopfzeile oberhalb der Tabelle aus 3) darüber gestapelt.

    Das sind die ganzen "Geheimnisse" hinter dieser Formel.
     
    Exl121150, 7. Dezember 2023
    #7
  8. Geburtstag Liste

    Vielen Dank
     
    Wedaustadion, 7. Dezember 2023
    #8
  9. Würde es zur der Formel auch eine Alternative geben für ältere Excel Version? Excel 2016
     
    Wedaustadion, 8. Dezember 2023
    #9
  10. Exl121150 Erfahrener User
    Hallo,

    dazu habe ich dir in der beiliegenden Datei folgende Änderungen eingebaut:

    1) In der struktur.Tabelle "Tabelle1" habe ich eine weitere Spalte "Sortierung" (in Spalte Q) angefügt, die folgende Formel enthält:
    =SUMMENPRODUKT((((TEXT([Geburtstag in];"000")&[Name])<(TEXT([@[Geburtstag in]];"000")&[@Name])))*1)+1
    Diese Formel gewährleistet eine eindeutige Zeilennummerierung, wobei die Zeile mit dem niedrigsten Wert in [Geburtstag in] die Sortierung-Nr. 1 erhält, die mit dem zweitniedrigsten Wert die Sortierung-Nr. 2 erhält, usw. Sie berücksichtigt auch die Fälle mit gleichen Zahlen in [Geburtstag in], indem für die Sortierung zusätzlich der Name aus Feld [Name] verwendet wird (was zB. für Dzieza und Marschalik, beide mit 16 in [Geburtstag in] vertreten, wichtig ist).

    2) Vor der struktur. Tabelle "Top5Geb" habe ich im Bereich S19:S23 weitere 5 Hilfsformeln eingefügt, wobei die in S19 lautet:=VERGLEICH(ZEILE($A1);Tabelle1[Sortierung];0)
    Diese ermittelt die Zeilennummer in der strukt."Tabelle1" innerhalb der Spalte "Sortierung", wobei sie die Nr.1 in der Zeile 25 der Tabelle "Tabelle1" findet, die Nr. 2 in der Zeile 9, usw.

    3) Die Formeln in der strukt.Tabelle "Top5Geb" habe ich auch ersetzt:
    Spalte "Alter": =INDEX(Tabelle1;S19;SPALTE(Tabelle1[Alter+1]))
    Spalte "Name": =INDEX(Tabelle1;S19;SPALTE(Tabelle1[Name]))
    Spalte "Wann": =INDEX(Tabelle1;S19;SPALTE(Tabelle1[Geburtstag in]))
    wobei ich in der Spalte "Wann" das benutzerdefinierte Zahlenformat
    "in "0"Tagen"
    eingefügt habe. Ohne dieses Zahlenformat würde die Formel natürlich lauten:
    ="in " & INDEX(Tabelle1;S19;SPALTE(Tabelle1[Geburtstag in])) & " Tagen"

    Anmerkung: Du hattest am Ende der strukt.Tabelle "Tabelle1" eine Leerzeile. Diese habe ich entfernt. Kommen weitere Zeilen hinzu, ist das kein Problem. Die Formel in Spalte "Sortierung" aktualisiert sich dann entsprechend. Zu beachten ist, dass eine eventuelle künftige Leerzeile die Sortierung-Nr. 1 erhielte, usw. !!
     
    Exl121150, 8. Dezember 2023
    #10
  11. Exl121150 Erfahrener User
    Hallo,

    ich habe erst hinterher bemerkt, dass du in der strukt.Tabelle "Top5Geb" eine versteckte Spalte W hast. Damit kannst du die 5 Hilfsformeln aus S19:S23 (siehe den Punkt 2) im Posting#10) verlagern in diese Spalte:

    zu 2) Ich habe dem Spaltenbereich W von "Top5Geb" den Namen "Zeile_Tabelle1" gegeben und dann die 5 Hilfsformeln eingefügt, beginnend
    mit: =VERGLEICH(ZEILE($A1); Tabelle1[Sortierung]; 0)
    ...

    bis zu: =VERGLEICH(ZEILE($A5); Tabelle1[Sortierung]; 0)

    zu 3) Dann lauten die Formeln in der
    Spalte "Alter": =INDEX(Tabelle1;[@[Zeile_Tabelle1]];SPALTE(Tabelle1[Alter+1]))
    Spalte "Name": =INDEX(Tabelle1;[@[Zeile_Tabelle1]];SPALTE(Tabelle1[Name]))
    Spalte "Wann": =INDEX(Tabelle1;[@[Zeile_Tabelle1]];SPALTE(Tabelle1[Geburtstag in]))
     
    Exl121150, 8. Dezember 2023
    #11
Thema:

Geburtstag Liste

Die Seite wird geladen...
  1. Geburtstag Liste - Similar Threads - Geburtstag Liste

  2. Nach Import von Kontakten keine Geburtstag

    in Microsoft Outlook Hilfe
    Nach Import von Kontakten keine Geburtstag: Hallo, ich habe meine Kontakte in Outlook über eine csv Datei hinzugefügt. Sie sind auch alle vorhanden auch mit Geburtstagen. Mir werden die Geburtstage aber nicht in meinem Kalender angezeigt....
  3. Nahe Geburtstage anzeigen

    in Microsoft Excel Tutorials
    Nahe Geburtstage anzeigen: In A:A die Namen, in B:B Geburtsdatümer. Dann =LET(c;A1:B999;d;365,2425;b;INDEX(c;;2)-HEUTE(); FILTER(HSTAPELN(c;RUNDEN(ABS(b/d);0)); NACHZEILE(REST({1.-1}*b;d);LAMBDA(a;MIN(a)<8)))) gibt als...
  4. Geburtstag und Jubiläumstag -> Datum kombinieren

    in Microsoft Access Hilfe
    Geburtstag und Jubiläumstag -> Datum kombinieren: Hallo, Ich habe eine Mitgliederdatenbank für einen Verein. Darin sind die Mitglieder mit Geburtsdatum erfasst. Ich habe eine Auswertung erstellt, die mir alle Mitglieder mit "runden" Geburtstagen...
  5. Hinzufügen eines Geburtstags oder Jubiläums für einen Kontakt

    in Microsoft Outlook Tutorials
    Hinzufügen eines Geburtstags oder Jubiläums für einen Kontakt: Hinzufügen eines Geburtstags oder Jubiläums für einen Kontakt Outlook für Microsoft 365 Outlook 2019 Outlook 2016 Outlook 2013 Outlook 2010 Mehr......
  6. Office 365 - Outlook Geburtstage

    in Microsoft Outlook Hilfe
    Office 365 - Outlook Geburtstage: Hallo wir haben unsere Software aktualisiert und sind auf Office 365 umgestiegen. Im Outlook hat die Übernahme aller Kontakte zwar geklappt, ich habe aber ein Problem mit den Geburtstagen....
  7. Outlook 365 Erinnerung an Geburtstage etc.

    in Microsoft Outlook Hilfe
    Outlook 365 Erinnerung an Geburtstage etc.: Hallo Zusammen, an die Outlook Experten, es geht um die Erinnerungs Einstellungen im Outlook für Geburtstage etc. Habe schon viel gesucht aber nichts gefunden. Beispiel: Wenn ich im Outlook...
  8. Auslesen von runden Geburtstagen aus einer Liste

    in Microsoft Excel Hilfe
    Auslesen von runden Geburtstagen aus einer Liste: Hallo Leute, ich habe mal wieder eine Kniffelige Tabelle zum Lösen bekommen. Aus einer Liste mit Mitarbeitern soll ich pro Jahr nur die mir anzeigen lassen, die einen Runden Geburtags in...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden