Office: (Office 2013) Gesamtliste auf Monate/Reiter aufteilen

Helfe beim Thema Gesamtliste auf Monate/Reiter aufteilen in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Hallo liebe Excel-Profis! Ich sitze jetzt schon einige Zeit an einem Problem bei dem ich aber irgendwie nicht voran komme und die Hoffnung habe, hier... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von EForest, 12. Dezember 2023.

  1. EForest Neuer User

    Gesamtliste auf Monate/Reiter aufteilen


    Hallo liebe Excel-Profis!

    Ich sitze jetzt schon einige Zeit an einem Problem bei dem ich aber irgendwie nicht voran komme und die Hoffnung habe, hier Hilfe zu bekommen.

    Ich habe eine Excelliste (Reiter "Quelle"), die auf mehrere, nach Monaten aufgeteilten Reitern ausgefüllt werden muss (Vorgabe des Kostenträgers). Mein Hauptproblem ist, dass ich das mit der Monatszuordnung nicht hinbekomme. Mein Gedanke war, wenn ich in jeden Monat in Spalte A eine Liste mit der Versichertennummer reinbekomme, kann ich mir den Rest mit SVerweis aus der Quelle holen. Aber ich bekomme das nicht dynamisch hin, nur mit filtern und dann einkopieren. (Denn ich brauche nur die von der "Deutschen Rentenversicherung Rheinland" und dem jeweiligen Monat)
    Ein Folgeproblem, das mir aufgefallen ist: Beim Sverweis wird der erste gefundene Wert angezeigt. Somit bekomme ich aber z.B. nicht das Austrittsdatum rein, weil das erst im Monat des Austritts mit angezeigt wird, in den Vormonaten, was zuerst gefunden/ausgegeben wird, ist es dann aber leer.
    Hat vielleicht jemand einen Lösungsansatz?

    Vielen Dank vorab für die Mühe!

    MfG Christian

    PS: Die Ergebnisse über die Suchfunktion haben mir auch nicht weitergeholfen, falls ich doch was übersehen haben sollte, gerne verlinken. Habe auch das Gefühl, dass die alte Excelversion 2013 es nicht leichter macht...
     
  2. PIVPQ hat Ahnung
    Hallo

    Ohne mir die Datei angeschaut zu haben.
    Warum nicht mit Pivot und Datenschnitte auswerten?
    Wenn es unbedingte verteilt auf Monate sein muss könnte dies mit Power Query eventuell möglich sein.
    Aber dann bleibt noch offen ob das Addin in deiner uralt Excelversion installiert ist.
     
    1 Person gefällt das.
  3. EForest Neuer User
    Hallo,

    ja, die Form nach Monate ist leider vorgegeben. Power Query kenne ich nicht, aber lt. Internet kann man das wohl auch im 2013er Excel noch nachträglich installieren. Was macht man damit?

    Datenschnitte sagen mir auch nichts, aber Pivottabelle schau ich mir mal an, ob mir das hilft...

    Schönen Tag noch =)
     
  4. steve1da Office Guru

    Gesamtliste auf Monate/Reiter aufteilen

    Hola,
    hier mal die Formel für die Versicherungsnummer im Blatt Januar.
    =WENNFEHLER(INDEX(Quelle!$A$2:$A$1211;AGGREGAT(15;6;ZEILE(Quelle!$A$2:$A$1211)-1/((Quelle!$E$2:$E$1211="deutsche rentenversicherung rheinland")*(Quelle!$C$2:$C$1211=1));ZEILE(A1)));"")
    Gruß,
    steve1da
     
    steve1da, 13. Dezember 2023
    #4
  5. Exl121150 Erfahrener User
    Hallo,

    1) ich habe die Tabelle im Arbeitsblatt "Quelle" in eine strukturierte (=intelligente) Tabelle namens "tbQuelle" umgewandelt.
    Ferner habe ich im Namensmanager den Namen "ListeVerbände" eingefügt, den ich im Punkt 2) für das DropDown benötigte.
    Gesamtliste auf Monate/Reiter aufteilen upload_2023-12-14_13-53-36.png
    2) Im Arbeitsblatt "Januar" habe ich 2 Zellen eingefügt:
    Zelle F5: =MONAT(DATWERT("1."&D5))
    um aus der Monatsangabe "Januar 2023" die Monatsnummer zu erhalten (=1).
    Zelle G5: ein DropDown für das Versicherungsinstitut - in diesem Fall wurde dort "Deutsche Rentenversicherung Rheinland" ausgewählt.

    3) In der Zelle A10 habe ich die Formel von @steve1da eingefügt, allerdings angepasst an die strukturierte Tabelle tbQuelle.
    =WENNFEHLER(INDEX(tbQuelle[Versicherungsnummer];AGGREGAT(15;6;ZEILE(tbQuelle[Versicherungsnummer])-1/((tbQuelle[KtrName1]=$G$5)*(tbQuelle[MonatNr]=1));ZEILE(A1)));"")
    Diese Formel hinunterkopieren bis Zeile 25, um die passenden Versicherungsnummern zu ermitteln.

    4) In Zelle E10 ist die Formel für das Eintrittsdatum enthalten:
    =WENNFEHLER(SVERWEIS($A10;tbQuelle;2;0);"")
    Diese Formel hinunterkopieren bis Zeile 25, um die passenden Eintrittsdaten zu ermitteln.

    5) In Zelle F10 ist die Formel für das Austrittsdatum - sofern vorhanden - enthalten:
    =WENNFEHLER(INDEX(tbQuelle[Austritt]; AGGREGAT(15;6; ZEILE(tbQuelle[Austritt])-1/((tbQuelle[Versicherungsnummer]=$A10)*(tbQuelle[Austritt]>0));1));"")
    Diese Formel hinunterkopieren bis Zeile 25, um die passenden Austrittsdaten zu ermitteln.

    Die Formeln für die restlichen Spalten im Arbeitsblatt "Januar" musst du noch ergänzen, da ich dazu keine Information habe.
    Die Formeln für die restlichen Monatsarbeitsblätter sind in analoger Weise zu ergänzen.

    Anmerkung: Diese 3x16 Formeln in den Punkten 3), 4) und 5) könnten durch bloß 3 Formeln ersetzt werden, wenn ein Excel365 vorläge:
    In A10: =EINDEUTIG(FILTER(tbQuelle[Versicherungsnummer];(tbQuelle[MonatNr]=$F$5)*(tbQuelle[KtrName1]=$G$5);""))
    In E10: =SVERWEIS($A$10#;tbQuelle;2;0)
    In F10: =LET(a;tbQuelle[Austritt]; NACHZEILE($A$10#; LAMBDA(v; FILTER(a;(tbQuelle[Versicherungsnummer]=v)*(a>0);""))))

    Modifizierte Datei liegt bei.
     
    Exl121150, 14. Dezember 2023
    #5
  6. EForest Neuer User
    Hallo Exl121150 und Steve1da,

    vielen herzlichen Dank für die Mühe und die Antworten!
    Ich muss mir das mal ganz in Ruhe angucken, es sind einige Begriffe gefallen, die ich nachrecherchieren muss, damit ich das nachvollziehen kann, was ihr da gezaubert habt!
    Wünsche einen guten Start in die neue Woche!
     
Thema:

Gesamtliste auf Monate/Reiter aufteilen

Die Seite wird geladen...
  1. Gesamtliste auf Monate/Reiter aufteilen - Similar Threads - Gesamtliste Monate Reiter

  2. TABS für jedne Tag des Monats einfügen + Tabelle mit übernehmen

    in Microsoft Excel Hilfe
    TABS für jedne Tag des Monats einfügen + Tabelle mit übernehmen: Hallo, ich muss übergangsweise monatsweise ein Kassenbuch in Excel führen. Ich habe im 1. Reiter ein Tabellenblatt. Dieses enthält Formeln sowie in Zelle B2 das aktuelle Datum. Was ich gern...
  3. Beträge in anderem Tabellenblatt anzeigen lassen mit Bezug auf einen Monat und ohne Leerzellen

    in Microsoft Excel Hilfe
    Beträge in anderem Tabellenblatt anzeigen lassen mit Bezug auf einen Monat und ohne Leerzellen: Hello, nun habe ich noch ein kleines Problem... ich habe es schon mal versucht, aber komme nicht zum richtigen Ergebnis... Jetzt soll ein Betrag in einem anderen Tabellenblatt angezeigt...
  4. Datum fortlaufend für ein Monat automatisch erstellen

    in Microsoft Excel Hilfe
    Datum fortlaufend für ein Monat automatisch erstellen: Hallo ich muss jeden Monat mehrere dieser Blätter ausfüllen und das Datum mühselig eintragen. Das Blatt ist gesperrt, nur die Zelle neben den Wochentagen kann ausgefüllt werden und der Zeitraum...
  5. Nächtigungen eines Aufenthalts auf die jeweiligen Monate aufteilen

    in Microsoft Excel Hilfe
    Nächtigungen eines Aufenthalts auf die jeweiligen Monate aufteilen: Guten Tag Ich plage mich schon seit 2 Tagen an diesem Problem. Für meine Nächigungstaxenberechnung benötige ich folgendes: Es gibt ein Aufehthalsdatum eines Gastes, zb 01.0.2023 bis 15.02.2023...
  6. Zusammenfügen mehrerer csv.-Dateien zu einer Gesamtliste

    in Microsoft Excel Hilfe
    Zusammenfügen mehrerer csv.-Dateien zu einer Gesamtliste: Hallo zusammen, ich habe in einem Ordner mehrere csv-Dateien. Die einzelnen Dateien werden von einem Messgerät generiert. Die csv-Dateien haben immer den Dateinamen des aktuellen Datums, also z....
  7. Aus Gesamtliste autom. Zeilen in ein anderes Blatt kopieren

    in Microsoft Excel Hilfe
    Aus Gesamtliste autom. Zeilen in ein anderes Blatt kopieren: Hallo an alle die gerne helfen. Ich habe ein Problem mit dem die Kolping EDV-Lehrer nicht zurechtkommen. Ich denke aber so schlimm ist es gar nicht. Vorab schon mal besten Dank für Euere...
  8. Automatische Aufteilung einer Gesamtliste in einz. Tabelen

    in Microsoft Outlook Hilfe
    Automatische Aufteilung einer Gesamtliste in einz. Tabelen: Hallo an alle die gerne helfen. Ich habe ein Problem mit dem die Kolping EDV-Lehrer nicht zurechtkommen. Ich denke aber so schlimm ist es gar nicht. Vorab schon mal besten Dank für euere...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden