Office: GetDataClosedWB ()

waldemarrrrr · 4. Dezember 2016

Guten Tag,

Ich habe hier ein Code, der Daten aus einer geschlossenen Datei kopiert.
Nur leider kann ich nicht alles ganz nachvollziehen. Könnte mir jemand zu jeder Codezeile einen kleinen Erklärungstext schreiben.

Über jede Hilfe bin ich sehr dankbar!

Code:

Option Explicit

Public Function GetDataClosedWB(SourcePath As String, _
SourceFile As String, sourceSheet As String, _
SourceRange As String, TargetRange As Range) As Boolean
'Holt einen Bereich aus einer _geschlossenen_ Arbeitsmappe
'Nur in VBA zu verwenden; nicht aus einer Tabellenzelle heraus
'© t.ramel@mvps.org
' wird durch die HoleDaten aufgerufen
Dim strQuelle As String
Dim Zeilen As Long
Dim Spalten As Byte
On Error GoTo InvalidInput
strQuelle = "'" & SourcePath & "[" & SourceFile & "]" & sourceSheet & "'!" & Range(SourceRange).Cells(1, 1).Address(0, 0)
Zeilen = Range(SourceRange).Rows.Count
Spalten = Range(SourceRange).Columns.Count
With TargetRange.Cells(1, 1).Resize(Zeilen, Spalten)
.Formula = "=IF(" & strQuelle & "="""",""""," & strQuelle & ")"
.Value = .Value
End With
GetDataClosedWB = True
Exit Function
InvalidInput:
MsgBox "Die Quelldatei oder der Quellbereich ist ungültig!", vbExclamation, "Get data from closed Workbook"
GetDataClosedWB = False
End Function

Public Sub HoleDaten()
' Die Funktion arbeitet mit der obrigen GetDataClosedWB zusammen
Dim Pfad As String
Dim Dateiname As String
Dim Blatt As String
Dim Bereich As String
Dim Ziel As Range
Pfad = "L:Eigene DateienTESTInternetTest2009"
Dateiname = "Beispiel Forum 30.xlsm"
Blatt = "Tabelle1" ' von welcher Tabelle soll er holen?
Bereich = "A1:B9" ' aus welchem Bereich soll er holen?
Set Ziel = ActiveSheet.Range("A1")
If GetDataClosedWB(Pfad, Dateiname, Blatt, Bereich, Ziel) Then
MsgBox "Daten importiert"
End If
End Sub
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

:)

rastrans · 6. Dezember 2016

Hallo waldemarrrrr,

der Code ist nicht so schwer. Aber bevor ich mir nun die Mühe mache, jede Zeile einzeln zu erläutern, solltest du mal folgendes probieren:

Erstelle eine Datei die in dem Bereich A1:B9 Daten enthält und speichere die Datei bei dir auf dem Rechner.
Erstelle eine neue Datei und kopiere deinen oben genannten Code. In der Zeile mit dem Pfad und dem Dateiname schreibst du die Daten einer ersten Datei rein.
Nun drückst du F8 und verfolgst mal Schritt für Schritt, das dann dein Rechner so mit den Daten macht.

Kleiner Hinweis: Daten aus einer geschlossenen Datei holen geht nicht! Excel öffnet diese schon und du musst darauf auch Leserechte besitzen. Die Idee, die hinter diesem Code steckt ist aber eigentlich auch ganz nett!

Viele Grüsse
rastrans

waldemarrrrr · 6. Dezember 2016

Hallo Rastrans,

Super mit der F8 Taste konnte ich das relativ gut nachvollziehen, vielen Dank *Smilie
Könntest du mir jedoch noch sagen in welche Codezeile er Die Quelldatei öffnet?

Viele Grüße

Case_Germany · 6. Dezember 2016

Hallo, *Smilie

die Datei wird nicht auf herkömmliche Weise geöffnet. *wink.gif*

In der Zeile...

Code:

.Formula = "=IF(" & strQuelle & "="""",""""," & strQuelle & ")"
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

... wird ein Kanal geöffnet und die entsprechende Info aus der Datei gezogen.

In der nächsten Zeile...

Code:

.Value = .Value
Klicke in dieses Feld, um es in vollständiger Größe anzuzeigen.

... wird die Formel durch den Wert ersetzt.

In meinem Blog habe ich einige kommentierte Beispiele dazu: *wink.gif*

Bei größeren Datenmengen wird das allerdings langsam.

Gechlossene Dateien...

Und doch, Du kannst aus geschlossenen Exceldateien lesen. Da gibt es Möglichkeiten. Excel muss auf dem System nicht mal installiert sein. *tongue.gif*

Servus
Case