Office: Gleiche Werte in separate Spalte sortieren

Guten Abend,

ich bin auf der Suche nach der richtigen Formel.
Habe schon einiges ausprobiert, aber das Richtige war noch nicht dabei.

Ich habe 4 Teilnehmer die gegeneinander antreten.
in B3:B6 stehen die Namen der Teilnehmer
in C3:C6 die erzielten Punkte
D3:D6 dient als Helfer
E3:E6 und F3:F6 werden die Namen und Punkte den Teilnehmern zugeordnet

Wenn jetzt 2 Teilnehmer oder mehr die gleiche Anzahl an Punkten erzielt haben,
sollen Sie in Spalte G3:G6 (Namen) und H3:H6 (Punkte) aussortiert werden.
Die Teilnehmer die nicht die gleiche Anzahl an Punkten haben, in I3:I6 (Name) und J3:J6 (Punkte) sortiert werden.

Ich hoffe mir kann jemand helfen und die richtige Formel nennen.
Ich bedanke mich vielmals.

 

Hallo Wilke,

Du hast Deine XL-Veersion nicht angeben, davon ist abhängig welche Formellösung am günstigsten ist. Ich hab nur eine ältere XL-Version. Da würde ich INDEX() und AGGREGAT() einsetzen. In neueren Versionen FILTER().

Allerdings gehe ich für heute auch offline.

 

Vielen Dank für deine Antwort,
verwendet wird Excel 365.

 

Weiter gehts scheinbar hier:
Gleiche Werte in separate Spalte sortieren | HERBERS Excel Forum

 

Hallo,

da du Excel365 hast, genügt Folgendes:

1) Im Zellbereich E3:J6 alle vorhandenen Formeln und Zahlen löschen

2) Nur in Zelle E3 folgende Formel eingeben bzw. kopieren:
=LET(np; $B$3:$C$6; snp; SORTIEREN(np; 2; -1); p; SPALTENWAHL(snp; 2); anzGl; SCAN(0; p; LAMBDA(akk;zl; ZEILEN(FILTER(p; p = zl; 0)))); stnpGl; FILTER(snp; anzGl >= 2); stnpUGl; FILTER(snp; anzGl = 1); WENNFEHLER(HSTAPELN(snp; stnpGl; stnpUGl); ""))

3) Die Formeln in D3:D6 sind überflüssig.

Die Formel aus Punkt 2) habe ich dir mit folgendem Microsoft-Add-In übersichtlicher dargestellt:

 

Vielen Dank für deine Antwort und die verbundene Mühe.

Habe die Formel bei mir übernommen.
Solange mindestens 2 Teilnehmer die selben Punkte haben, funktioniert es einwandfrei.
Sobald alle Teilnehmer unterschiedliche Punkte haben, verschwindet die Tabelle.

Gibt es dazu vielleicht eine Lösung ?

 

Hallo,

ich habe gerade auch diesen Fehler entdeckt, er ist ganz einfach behebbar.
In Zelle E3 folgende modifizierte Formel kopieren:
=LET(np; $B$3:$C$6; snp; SORTIEREN(np; 2; -1); p; SPALTENWAHL(snp; 2); anzGl; SCAN(0; p; LAMBDA(akk;zl; ZEILEN(FILTER(p; p = zl; 0)))); stnpGl; FILTER(snp; anzGl >= 2; {"".""}); stnpUGl; FILTER(snp; anzGl = 1; {"".""}); WENNFEHLER(HSTAPELN(snp; stnpGl; stnpUGl); ""))

Die beiden rot gekennzeichneten Stellen waren die Ursache des Problems.

 

Perfekt.
Ich bedanke mich vielmals.