Office: Grafiken einfügen

Moin Team,

ich habe ein Formular erstellt und möchte an einer bestimmten Stelle eine Grafik einfügen, die sich nach dem Einfügen automatisch anpasst.

Mein Code-Versúch bis jetzt:

Sub InsertGraphic()
Dim Path As String
Dim pic As Picture

Path = Application.Dialogs(xlDialogInsertPicture).Show

Set pic = ActiveSheet.Pictures.Insert(Path)

With ActiveSheet.Range("V5:X11")
pic.Left = .Left
pic.Top = .Top
pic.Height = .Height
pic.Width = .Width
End With

End Sub

Zum Problem: Das Bild kann ich über das Dialogfenster auswählen, nur aber der Stelle Set Pic.... sagt er mir, dass die insert Eigenschaft nicht zugeordnet werden kann.

Für jeden Hinweis/Hilfe wäre ich sehr dankbar!

Gruß

 

auf der Seite findest Du viel Code Beispiele zu einfügen von Bildern.
http://hajo-excel.de/inhalt_vba_bild.htm

 

Hallo,

Das glaube ich Dir auf der Stelle. Nur das Problem liegt genau genommen nicht in dieser Zeile, sondern in der Zeile davor:
Path = Application.Dialogs(xlDialogInsertPicture).Show
Wenn Du in der Excel-Hilfe zur Show-Methode der Dialogs-Auflistung nachschaust, steht dort, dass Show einen Boolean-Wert zurückliefert und nicht eine String-Wert (für den Pfad):
Show liefert True, wenn das Dialogfenster mit dem 'Ok'-Button geschlossen wurde, sie liefert False, wenn das Fenster mit dem 'Abbrechen'-Button geschlossen wurde.
Wurde eine Bilddatei ausgewählt vor dem Schließen mit 'Ok', wird diese im aktiven Arbeitsblatt mit der aktiven Zelle in der linken oberen Ecke des Bildes abgelegt.

Mit einem True/False-Variableninhalt in der String-Variable kann die Pictures.Insert-Methode nichts anfangen - deshalb die Fehlermeldung.

Wenn Du im Programm Kontrolle über den ausgewählten Dateinamen haben möchtest, musst Du einen anderen Dateidialog verwenden als den aus der Standarddialogauflistung. Dieser nennt sich FileDialog:

Code:

Const msoFileDialogOpen = 1, msoFileDialogFilePicker = 3
Const msoFileDialogViewDetails = 2
With Application.FileDialog(msoFileDialogFilePicker)
  .Title = "Wählen Sie die Bilddatei aus:"
  .InitialView = msoFileDialogViewDetails 'Detailansicht
  .AllowMultiSelect = False               'Keine Mehrfachauswahl
  'Anfangsverzeichnis für die Suche (kann abgeändert werden):
  .InitialFileName = Application.Path & "\*.bmp; *.jpg"
  'Filter der angezeigten Dateitypen (kann noch ergänzt werden):
  .Filters.Add "Bilddateien", "*.bmp; *.jpg", 1
' .FilterIndex = 1
  If .Show Then
    'Der 'Ok' oder 'Öffnen'-Button wurde gedrückt
    'vor dem Schließen des Dialogfensters.
    Path = .SelectedItems(1)
  Else
    'Der 'Abbrechen'-Button wurde gedrückt
    'vor dem Schließen des Dialogfensters.
    Exit Sub  '--> Verlassen der Sub
  End If
End With
'In der String-Variable "Path" ist jetzt der Pfad
'auf die ausgewählte Datei enthalten (samt Dateinamen).

Da Du auf die Angabe einer Excel-Version verzichtet hast, kann ich nur hoffen, dass FileDialog in Deiner Version schon enthalten ist (deshalb auch die explizite Festlegung der benannten Konstanten).

 

Hi,

Code:

Sub InsertGraphic()
    Dim Path As String
    Dim pic As Picture
    Path = Application.Dialogs(xlDialogInsertPicture).Show
    If Path = True Then
        Set pic = ActiveSheet.Pictures(ActiveSheet.Pictures.Count)
        With pic
            .Left = Range("V5:X11").Left
            .Top = Range("V5:X11").Top
            .Height = Range("V5:X11").Height
            .Width = Range("V5:X11").Width
        End With
    End If
End Sub

Durch die Zeile

Code:

    Path = Application.Dialogs(xlDialogInsertPicture).Show

wird bei Klick auf den "Einfügen"-Button im Dialog das Bild bereits eingefügt, sodass ein Insert nicht mehr erforderlich ist.

Bis später,
Karin

 

Hi,

WAHNSINN!

Der FileDialog war Gold wert, aber auch die anderen Beiträge konnten mir bei der ein oder anderen Feinheit weiterhelfen.

Vielen Dank für eure Mühe!

Einen schönen Tag wünscht
Alex