Office: (Office 365) Hilfe benötigt

Helfe beim Thema Hilfe benötigt in Microsoft Excel Hilfe um das Problem gemeinsam zu lösen; Guten Tag, Ich sitze gerade an einem Problem bei dem ich einen Zeitlichen Durchschnittswert ermitteln muss. Ich hatte schonmal ein Thema eröffnet... Dieses Thema im Forum "Microsoft Excel Hilfe" wurde erstellt von Hefezopf, 9. August 2021.

  1. Hefezopf Neuer User

    Hilfe benötigt


    Guten Tag,

    Ich sitze gerade an einem Problem bei dem ich einen Zeitlichen Durchschnittswert ermitteln muss. Ich hatte schonmal ein Thema eröffnet aber es wahrscheinlich zu kompliziert beschrieben.

    In der beiliegenden Demomappe ist in Zeile A jeweils ein Datums- und Uhrzeitstempel. In der Spalte daneben befinden sich Nullen und Einsen. Mein Ziel ist es die Dauer eines Vorgangs, d.h. zum Zeitpunkt wo die erste Eins kommt bis zum Zeitpunkt wo wieder eine Null kommt mit Hilfe der Zeitstempel in Spalte A herauszufinden. Das soll für die ganze Spalte gelten und anschließend soll eine Durchschnittszeit der beiden Vorgänge ausgegeben werden.

    Danke im Voraus.

    Liebe Grüße
    Leo
     
    Hefezopf, 9. August 2021
    #1
  2. Sorry, das klingt mir ein wenig verwirrlich. Kannst du in deinem Beispiel ein paar erwartete Ergebnisse hinzufuegen - und idealerweise die Erklaerung ueberarbeiten?
     
    WuwuMan, 9. August 2021
    #2
  3. Hefezopf Neuer User
    Hey, ja klar.
    Also im Beispiel startet der erste Vorgang in Zeile 4 und geht bis Zeile 8. Die Gesamtdauer des ersten Vorgangs ist also von 8:25:08 bis 8:29:30, insgesamt also 262 Sekunden.
    Der zweite Vorgang startet in Zeile 13 und geht bis Zeile 24 dieser geht insgesamt 75 Sekunden.
    Von diesen beiden Werten hätte ich ganz gerne den Durchschnittswert von 168,5 Sekunden ausgegeben.
     
    Hefezopf, 9. August 2021
    #3
  4. Hilfe benötigt

    In etwa so?

    Das Ergebnis ist annaehernd wie erwartet, die Differenz von 0.22sec ergibt sich aus den Millisekunden, die in den Zeitstempeln vorhanden sind - aber nicht angezeigt werden.
     
    WuwuMan, 9. August 2021
    #4
  5. Hefezopf Neuer User
    Vielen Danke erstmal für die Mühen WuwuMan. Mir tut er Leid zu sagen aber ich habe vergessen zu sagen, dass ich eigentlich geplant, hatte die Daten über ein VBA-basiertes Makro errrechnen zu lassen, um es später mit einer Schaltfläche zu steuern.
     
    Hefezopf, 10. August 2021
    #5
  6. Exl121150 Erfahrener User
    Hallo,

    man kann das mit einer einzigen Formel erledigen:
    =SUMME(($B$2:$B$27)*($A$3:$A$28-$A$2:$A$27)) / SUMME(WENN($B$2:$B$27-$B$3:$B$28=1;1;0))*24*3600
     
    Exl121150, 10. August 2021
    #6
  7. Ein schoener Ansatz - Aber:
    Hab diese Formel in D2 eingetragen: und dann zum Test B25:B27 auf 1 gesetzt - macht einen Fehler.
    Schliesslich waers natuerlich schoen, wenn die Bereichsreferenzen nicht hart kodiert waeren.
     
    WuwuMan, 10. August 2021
    #7
  8. Exl121150 Erfahrener User

    Hilfe benötigt

    Hallo @WuwuMan,

    dir ist aber schon klar, dass nach Vorgabe die letzte inkludierte Zeile (A27:B27) auf alle Fälle in A27 die letzte Uhrzeit und in B27 eine 0 enthalten muss, um eine 1-Periode korrekt zu beenden. Tut man das, dann funktioniert die Formel auch.

    Unter der Voraussetzung Excel365 und unter der Voraussetzung, dass die LET(....)-Funktion vorhanden ist, kann ich folgende Formelversionen anbieten:
    =LET(TS;$A$2:$B$27; TE;$A$3:$B$28;
    SUMME(INDEX(TS;;2)*(INDEX(TE;;1)-INDEX(TS;;1))) / SUMME(N(INDEX(TS;;2)>INDEX(TE;;2)))*24*3600)

    bzw.
    =LET(TS;$A$2:$B$27; TE;BEREICH.VERSCHIEBEN(TS;1;0);
    SUMME(INDEX(TS;;2)*(INDEX(TE;;1)-INDEX(TS;;1))) / SUMME(N(INDEX(TS;;2)>INDEX(TE;;2)))*24*3600)


    Die 2. Formel setzt nur mehr 1 hart kodierten Bereich voraus, nämlich $A$2:$B$27 - allerdings ist dann die volatile Funktion BEREICH.VERSCHIEBEN(...) enthalten.
    Bei beiden Funktionen habe ich auch den Ausdruck in der 2. SUMME-Funktion optimiert, sodass jetzt keine WENN-Funktion mehr aufscheint.
     
    Exl121150, 10. August 2021
    #8
  9. Exl121150 Erfahrener User
    Hallo,

    als Ergänzung zu Posting #8 die Formelversion ohne BEREICH.VERSCHIEBEN:
    =LET(TSE;$A$2:$B$27; ZSE;ZEILEN(TSE);
    TS;INDEX(TSE;1;1):INDEX(TSE;ZSE-1;2); TE;INDEX(TSE;2;1):INDEX(TSE;ZSE;2);
    SUMME(INDEX(TS;;2)*(INDEX(TE;;1)-INDEX(TS;;1)))/SUMME(N(INDEX(TS;;2)>INDEX(TE;;2)))*24*3600)

    Es muss in Zelle B27 eine 0 als Kennzeichen enthalten sein!

    Falls bereits die LAMBDA-Funktion verfügbar ist:
    =LAMBDA(Bereich; LET(TSE;Bereich; ZSE;ZEILEN(TSE);
    TS;INDEX(TSE;1;1):INDEX(TSE;ZSE-1;2); TE;INDEX(TSE;2;1):INDEX(TSE;ZSE;2);
    SUMME(INDEX(TS;;2)*(INDEX(TE;;1)-INDEX(TS;;1)))/SUMME(N(INDEX(TS;;2)>INDEX(TE;;2)))*24*3600))
    (A2:B27)
    mit deren Hilfe kann man benutzerdefinierte Funktionen auf Arbeitsmappenebene definieren (ohne VBA), zB.:
    =DurchschnittDauer(A2:B27) (siehe Zelle D10)
     
    Zuletzt bearbeitet: 10. August 2021
    Exl121150, 10. August 2021
    #9
Thema:

Hilfe benötigt

Die Seite wird geladen...
  1. Hilfe benötigt - Similar Threads - Hilfe benötigt

  2. Excel Hilfe benötigt (Tennisturnierauslosungsmappe)

    in Microsoft Excel Hilfe
    Excel Hilfe benötigt (Tennisturnierauslosungsmappe): Angabe in Dokument: Für ein Tennisturnier soll eine Auslosung gemacht werden. Angabe Siehe Dokument.
  3. Hilfe benötigt bei Fehler in Makro

    in Microsoft Excel Hilfe
    Hilfe benötigt bei Fehler in Makro: Guten Tag erstmal. Direkt vorweg, Excel ist absolutes Neuland für mich. Habe jetzt nur versucht mich rein zu finden um einen Fehler zu finden, da derjenige, der die Makros vor einigen Jahren...
  4. VBA Editor - Hilfe benötigt - Speichern, nur wenn Felder gefüllt

    in Microsoft Excel Hilfe
    VBA Editor - Hilfe benötigt - Speichern, nur wenn Felder gefüllt: Hallo liebes Forum, habe schon etwas rumprobiert - komme aber leider nicht mehr weiter mit VBA (Anfänger): Ich habe folgende Aufgabenstellung: Spalte A (Artikel) bekommt Werte eingepflegt Spalte...
  5. Hilfe dringend benötigt :)

    in Microsoft Excel Hilfe
    Hilfe dringend benötigt :): Hallo zusammen, ich brauche dringend eure Hilfe. Ich bin leider absolut keine Excel-Expertin und brauche für meine Arbeit dringend eine VBA Programmierung und eine Tabelle, die automatisiert...
  6. Bedingte Formatierung Hilfe benötigt

    in Microsoft Excel Hilfe
    Bedingte Formatierung Hilfe benötigt: Hallo miteinander! Ich arbeite gerade an einer Liste mit Nachnamen. Hierbei möchte ich diese in verschiedenen Arbeitsblättern einfärben. Also z.B. alle Müller, Schmidt, Schneider blau alle Stark,...
  7. Outlook 2016 Hilfe benötigt

    in Microsoft Outlook Hilfe
    Outlook 2016 Hilfe benötigt: Hallo, ich bin der Neue, das Thema ist erledigt ich habe die Lösung gerade selbst gefunden.
  8. Hilfe benötigt bei der Erstellung eines Makros zum PDF Druck

    in Microsoft Excel Hilfe
    Hilfe benötigt bei der Erstellung eines Makros zum PDF Druck: Hallo zusammen, ich bin ein absoluter Neuling was Makros angeht, ´genauer gesagt ist dieses mein erstes ever ;-) Ich habe sehr viel in sämtlichen Foren gelesen, dort findet man ja auch viel, aber...
  1. Diese Seite verwendet Cookies, um Inhalte zu personalisieren, diese deiner Erfahrung anzupassen und dich nach der Registrierung angemeldet zu halten.
    Auf dieser Website werden Cookies für die Zugriffsanalyse und Anzeigenmessung verwendet.
    Wenn du dich weiterhin auf dieser Seite aufhältst, akzeptierst du unseren Einsatz von Cookies.
    Information ausblenden