Office: Hilfe für Excel 2000

Guten Abend,

ich habe folgendes Problem. Ich brauche eine Excel-Tabelle, weiß aber nicht, wie ich diese erstellen muss, da meine Excel-Kenntnisse nicht so gut sind.

Es geht um Folgendes:
Bsp.: Es gibt 4 Gruppen. In jeder Gruppe befinden sich unterschiedlich viele Mitglieder.
Nun sollen diese Gruppen in Teams eingeteilt werden.
Die Teams haben unterschiedlich viele Plätze frei und wenn ein Team voll ist, dann müssen automatisch die anderen Teams aufgefüllt werden.

Die Mitglieder sollten nicht als Zahl unter den Gruppen/Teams stehen, sondern als Namensliste.



Die zentrierten Zahlen geben die Teamkapazität an.

Also, das Ganze sollte ungefähr so funktionieren, dass man die Gruppen mit den Namen hat und der PC bzw Excel dann automatisch die Namen den Teams zuordnet.


Leider habe ich keine Ahnung mit welchen Formeln ich sowas mache.
Oder ob ich gar eine Programmiersprache verwenden muss.
Das Ganze sollte Open Office und Office 2000 kompatibel sein.

Wäre dankbar, wenn mir jemand helfen könnte.

LG
Head

 

Hallo!

In Excel2000 funktioniert diese Lösung bestimmt, in OO musst du es ausprobieren (bei Matrixformeln muss man dort, soweit ich weiß, irgendwo ein Häkchen setzen, statt Strg+Shift+Enter).
Die Formel aus F2 ist nach unten kopierbar, die Formel aus H3 zusätzlich auch noch nach rechts.

	A	B	C	D	E	F	G	H	I	J	K
1	Gruppe A	Gruppe B	Gruppe C	Gruppe D		Hilfe		Team 1	Team 2	Team 3	Team 4
2	P1	P5	P8	P10		P1		4	3	5	2
3	P2	P6	P9	P11		P2		P1	P5	P8	P13
4	P3	P7		P12		P3		P2	P6	P9	P14
5	P4			P13		P4		P3	P7	P10
6				P14		P5		P4		P11
7						P6				P12
8						P7
9						P8
10						P9
11						P10
12						P11
13						P12
14						P13
15						P14
16

Zelle	Formel
F2	{=WENN(ZEILE(A1)>SUMME(N(A$2:D$9<>""));"";INDEX(A:D;REST(KKLEINSTE(WENN(A$2:D$9<>"";ZEILE($2:$9)+SPALTE(A:D)*999);ZEILE(A1));999);KÜRZEN(KKLEINSTE(WENN(A$2:D$9<>"";ZEILE($2:$9)+SPALTE(A:D)*999);ZEILE(A1))/999)))}
H3	=WENN(ZEILE($A1)>H$2;"";INDEX($F:$F;ZEILE($A2)+SUMMENPRODUKT(N($G$3:G$99<>""))))

<table><tr><td>Achtung, Matrixformel enthalten!</td></tr><tr><td><span>Die geschweiften Klammern{} werden </span><span>nicht</span><span> eingegeben.</span></td></tr><tr><td><span>Verlassen Sie den Zelleneditor mit </span><span>Strg+Shift + Enter</span><span>, statt Enter alleine.</span></td></tr></table>[/parsehtml]

 

Hm also wenn ich das Ganze in OO probiere, dann kommt in den Bereichen, in denen die Formel steht, "#NAME?".
Die Kombination Strg+Shit+Enter funktioniert bei OO auch, man kann aber auch im Funktions-Assistenten auf MAtrix unten links klicken.

In deiner Formel für H3 hattest du am Ende $G$2:G$99. Ich habe das in $F$2:F$99 weil die Spalte G ist ja leer?! Oder hat das damit nichts zu tun?

H3:{=WENN(ZEILE($A1)>H$2;"";INDEX($f:$f;ZEILE($A2)+SUMMENPRODUKT(N($F$2:F$99<Bei>summe(N(A$2:D$20<>""));"";INDEX(a:d;rest(kkleinste(wenn(A$2:D$20<>"";zeile($2:$20)+spalte(a:d)*999);zeile(A1));999);kürzen(kkleinste(wenn(A$2:D$20<>"";zeile($2:$20)+spalte(a:d)*999);zeile(A1))/999)))}

Aber bis dahin schonmal danke ;)

 

Hallo!

In Sachen OO kann ich dir leider nicht weiterhelfen, da ich das Programm nicht auf dem Rechner habe.
Der Bezug zu $G$3:G$99 ist schon korrekt; er verändert sich beim Ziehen nach rechts.

 

So mit OO scheints nicht zu klappen, aber das ist nicht so schlimm.
Ich hab das jetzt mal mit Excel versucht, da geht das ganz gut.
Das einzige Problem liegt darin, dass nur Spalte A bzw Gruppe A brücksichtigt wird und nicht alle.

Bei mir sieht das so aus:



Sorry ist ein bisschen klein geworden, aber ich denke man kanns erkennen^^.

Es werden halt immer die Mitglieder aus Gruppe A wiederholt.

Ich hab deine Formeln benutzt und die Formel aus H3:
=WENN(ZEILE($A1)>H$2;"";INDEX($F:$F;ZEILE($A2)+SUMMENPRODUKT(N($G$3:G$99<>""))))
in I3,J3,K3 kopiert, wobei ich das H mit dem Buchstaben der entsprechenden Spalte ersetzt habe.

 

Hallo!

Die Formel aus H3 kannst du nicht nur nach unten sondern auch nach rechts kopieren! (Aber das schrieb ich auch schon...)
Dann siehst du, dass sich auch das rote G verändert.
=WENN(ZEILE($A1)>H$2;"";INDEX($F:$F;ZEILE($A2)+SUMMENPRODUKT(N($G$3:G$99<>""))))

PS: Bilder sind für potentielle Helfer meist eher ungeeignet. Lade stattdessen lieber eine (anonymisierte) Beispielmappe hoch. Einen möglichen Link findest du in meiner Signatur.

 

Ha! Das funktioniert.
Sorry das hatte ich überlesen, dass man das auch nach rechts kopieren kann.

Vielen Dank nochmal ;)