Office: (Office 2016) Hilfe VBA Formular in Excel geht nicht richtig!

Hallo zusammen!
Wer kann mir helfen?

Was mache ich falsch das in Textbox1 das erfassen eines Datums obligatorisch wird?

Hier der Code:

Code:

Private Sub cmdNeu_Click()
Dim rngTreffer As Range
Dim lngZeileFrei As Long
Dim i As Integer

'zuerst einmal alle MUSS-Felder festlegen
If Me.TextBox1.Value = "" Then
MsgBox "Im Feld " & Me.Label1.Caption & " fehlt die Eingabe!"
Me.TextBox1.SetFocus
Exit Sub
End If
If Me.TextBox2.Value = "" Then
MsgBox "Im Feld " & Me.Label2.Caption & " fehlt die Eingabe!"
Me.TextBox2.SetFocus
Exit Sub
End If
If Me.TextBox3.Value = "" Then
MsgBox "Im Feld " & Me.Label3.Caption & " fehlt die Eingabe!"
Me.TextBox3.SetFocus
Exit Sub
End If

Set rngTreffer = Freipassabfertigungen_aktuell.Range("B:B").Find(what:=Me.TextBox2.Value, lookat:=xlWhole)
If rngTreffer Is Nothing Then
lngZeileFrei = Freipassabfertigungen_aktuell.Cells(Freipassabfertigungen_aktuell.Rows.Count, 1).End(xlUp).Row + 1
For i = 1 To 13
Freipassabfertigungen_aktuell.Cells(lngZeileFrei, i).Value = Me.Controls("TextBox" & i).Value
Next i
Else
MsgBox "Der Satz mit der Freipass Nr. " & Me.TextBox2.Value & " ist bereits vorhanden!"
End If

End Sub

*************************************************************************************************************************

Wer kann mir behilflich sein ?

Danke für eure Hilfe

Assel

 

Hi,

dass nur ein Datum eingegeben werden kann und dieses zwingend eingegeben werden muss, kannst du bereits bei der Eingabe z.B. mit folgendem prinzipiellen Code realisieren:

Code:

Option Explicit
Dim blnFalsch As Boolean

Private Sub TextBox1_AfterUpdate()
    Dim arrDatum
    If Not IsDate(TextBox1) Then
        blnFalsch = True
    Else
        If InStr(TextBox1, ".") > 0 Then
            arrDatum = Split(TextBox1.Text, ".")
            If arrDatum(0) > 31 Or arrDatum(1) > 12 Then blnFalsch = True
        Else
            blnFalsch = True
        End If
    End If
End Sub

Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If TextBox1 <> "" Then
        If blnFalsch Then
            MsgBox "Bitte ein korrektes Datum eingeben"
            TextBox1 = ""
            Cancel = True
        End If
    End If
End Sub

Bis später,
Karin