Office: in Richtige Tabelle Übertragen

Hi! Kann mir Helfen!
Ich Will dass von UserForm in Bestimmte Tabelle Übertagen Soll

ich habe Probiert mit "With Worksheets("Tabelle")" aber klaps nicht

hier ist Quelltext

PHP:

Private Sub OKButton_Click()
    Dim rngZelle As Range
    'Pflicht Angabe !!!
     If NameAndernBox = "" Then
        MsgBox ("Bitte Name Eingeben")
        Exit Sub
    End If
    If vbYes = MsgBox("Wollen Sie Formular Speichen?", vbYesNo, " Speichern") Then
       Tabelle.Unprotect (123)
        'Speichern
        With Worksheets("Tabelle")
        Set rngZelle = Columns(1).Find(NameBox, lookat:=xlWhole)
        If Not rngZelle Is Nothing Then
            rngZelle = NameAndernBox
        End If
        Set rngZelle = Nothing
        End With
        ActiveWorkbook.Save
        Tabelle.Protect Password:="123"
        MsgBox "Neu Antrag ist Gespeichet"
        Unload Me
    End If
End Sub

Danke Voraus

 

Hallo,

ich bin leider aus deinen Angaben nicht ganz schlau geworden - ich habe daher deinen Code auf die für mich wahrscheinlichste Version umgestellt:

Code:

Private Sub OKButton_Click()
    Dim rngZelle As Range
    'Pflicht Angabe !!!
    If NameAndernBox.Value = "" Then
       MsgBox "Bitte Namen eingeben!"
    ElseIf MsgBox("Wollen Sie das Formular speichern?", vbYesNo, "Speichern") = vbYes Then
       With Worksheets("Tabelle")
          .Unprotect "123"
          'Speichern
          Set rngZelle = .Columns(1).Find(What:=NameBox.Value, lookat:=xlWhole)
          If Not rngZelle Is Nothing Then
              rngZelle.Value = NameAndernBox.Value
          End If
          .Protect Password:="123"
       End With
       ActiveWorkbook.Save
       MsgBox "Neuer Auftrag ist gespeichert"
       Unload Me
    End If
End Sub

Beschreibung:
1) Du hast eine Userform, in der sich 2 TextBoxen namens "NameBox" und "NameAndernBox" und 1 Button namens "OKButton" befinden.
2) Sobald du auf den OKButton klickst, wird
2a) zuerst geprüft, ob in der TextBox "NameAndernBox" kein Text enthalten ist: In diesem Fall wird die Meldung "Bitte Namen eingeben!" gebracht.
2b) falls in der TextBox "NameAndernBox" Text enthalten ist, wird zuerst gefragt, ob man das Formular speichern will; falls ja, wird das Folgende ausgeführt (Punkte 2c - 2h):
2c) Vom Arbeitsblatt "Tabelle" wird der Blattschutz unter Verwendung des Passwortes "123" entfernt.
2d) In der 1. Spalte des Arbeitsblattes "Tabelle" wird nach dem Text gesucht, der sich in der TextBox "NameBox" befindet.
2e) Wird dieser in einer Zelle gefunden, wird in dieser Zelle der Text aus der TextBox "NameAndernBox" gespeichert.
2f) Für das Arbeitsblatt "Tabelle" wird wieder der Blattschutz unter Verwendung des Passwortes "123" eingeschaltet.
2g) Schließlich wird noch die aktive Arbeitsmappe gespeichert und die Meldung "Neuer Auftrag ist gespeichert" angezeigt.
2h) Und zu allerletzt wird noch die Userform entladen.

 

"Exl121150 "
Beschreibung Stimmt Genau!!!!!!

Danke es funktioniert!