Office: in Word eingefügte Tabelle anpassen

Hi,

ich möchte die in Word eingefügte Tabelle anpassen. (über Zwischenablage) Aber Excel führt einfach die
AutoFitBehavior-Funktion nicht aus. Es passiert da nix, auch keine Fehlermeldung. Was mache ich falsch?

PHP:

         With appWord.ActiveDocument
If .Bookmarks.Exists("Angebot") = True Then
.Bookmarks("Angebot").Range.PasteAndFormat (wdPasteDefault)
.Tables(1).Select
.Tables(1).AutoFitBehavior (wdAutoFitWindow)
End If
End With


:)

 

Hi,

setze entweder einen Verweis auf die Word Object Library - dann sollte er die Konstante erkennen.

Oder Du ersetzt die Konstante durch die 2:

Code:

Das funktioniert ohne Verweis.

 

ach ja stimmt. oh man, voll vergessen den Verweis zu setzen. War ein neues XLS. Logisch. Danke für den Tipp!

 

noch am Schluss mein kompletter Code, welcher eine Markierung einer ExcelTabelle direkt in Word 'Angebot.doc' an eine Textmarke 'Angebot' einfügt und formatiert. Falls jemand nach so einer Lösung suchte:

PHP:

         Public Sub Tranfer_Angebot()
On Error Resume Next
Dim WordDatei As String

Dim i As Integer
WordDatei = "Angebot.doc"

If Not (Dir(WordDatei) = "") Then

'Achtung: Word hat eine Einschränkung in der Anzahl der Spalten<=63

Selection.Copy

Dim appWord As Word.Application
Dim oTable As Table

'unterdrücken mehrerer Instanzen von Word
Set appWord = GetObject(, "Word.Application")
If Err.Number <> 0 Then
Set appWord = CreateObject("Word.Application", "localhost")
End If

appWord.Documents.Open WordDatei

'Word anzeigen
appWord.Visible = True
appWord.Activate

'Achtung Verweis auf WordAPI machen, sonst gehen diese Befehle net
'Extras->Verweise->Microsoft Word 11 Object Library

'Inhalte einfügen
With appWord
If .ActiveDocument.Bookmarks.Exists("Angebot") = True Then
'prüfen, ob bereits eine Tabelle an der Stelle eingefügt wurde
If .ActiveDocument.Bookmarks("Angebot").Range.Tables.Count > 0 Then
'löschen der alten Tabelle
Set oTable = .ActiveDocument.Bookmarks("Angebot").Range.Tables(1)
oTable.Select
oTable.Delete
Set oTable = Nothing
End If
'Zwischenablage einfügen
.ActiveDocument.Bookmarks("Angebot").Range.PasteAndFormat (wdPasteDefault)
Set oTable = .ActiveDocument.Bookmarks("Angebot").Range.Tables(1)
'komplette Tabelle selektieren
oTable.Select
'Schriftgröße auf 8
.Selection.Font.Size = 8
'Größe an Fenster anpassen
oTable.AutoFitBehavior (wdAutoFitWindow)
'Zeilenhöhe auf mind. 0 cm setzen
.Selection.Rows.HeightRule = wdRowHeightAtLeast
.Selection.Rows.Height = CentimetersToPoints(0.04)
'erste Zeile markieren, um die Überschriftzeilen zu wiederholen
.Selection.HomeKey Unit:=wdLine
.Selection.EndKey Unit:=wdLine, Extend:=wdExtend
'Überschrigtzeilen wiederholen
.Selection.Rows.HeadingFormat = wdToggle
Set oTable = Nothing
Else
MsgBox ("Konnte die Textmarke 'Angebot nicht finden")
End If
End With

Set appWord = Nothing
Else
MsgBox ("Konnte das Wordangebots-Dokument nicht finden!")
End If

End Sub